Имя пользователя:
Пароль:
 

Показать сообщение отдельно

Забанен


Сообщения: 793
Благодарности: 260

Профиль | Цитировать


Elven, если список айпишников статический, то есть не генерируется автоматически и\или не изменяется, лучше хранить его прямо в бате, а вывод пинга лучше пихать в csv:
Код: Выделить весь код
@echo off
  setlocal
    for /f "delims=:" %%i in (
      'findstr /nirc:"exit /b" "%~f0"'
    ) do set "i=%%i"
    
    set "res=%~dp0ping.csv"
    
    if not exist "%res%" (
      echo:Time,IPAddress,Status>"%res%"
    )
    for /f %%i in ('more +%i% "%~f0"') do (
      ping -n 1 %%i | findstr /irc:"ttl"
      if not errorlevel 1 (
        for /f "tokens=1 delims=," %%j in (
          "%time%"
        ) do echo:%%j,%%i,Success>>"%res%"
      ) else (
        del /f /q "%res%"
        taskkill /im some.exe
        ping -n 5 0.0.0.0 -w 1000>nul
        start some.exe
      )
    )
  endlocal
exit /b

213.180.193.3
93.158.134.3
213.180.204.3
212.188.10.99
212.188.10.104
212.188.10.94
212.188.10.89
Это сообщение посчитали полезным следующие участники:

Отправлено: 14:06, 02-11-2015 | #3