[sergesneg]

id.worg@vk, Создай где-то в каталоге, доступном для системы и администраторов текстовый файл. Переименуй его в "IconRest.cmd", скачай SubInACL.exe. Создай файл IconRest.cmd Открой его блокнотом скопируй туда этот текст:

Код:

@Echo off
Echo Starting Sergesneg Icon Restore...
chcp 1251

Set KeyPath=HKEY_CLASSES_ROOT\CLSID\{42aedc87-2188-41fd-b9a3-0c966feabec1}\InProcServer32
Set KeyParm="%%SystemRoot%%\system32\windows.storage.dll"

"%~dp0subinacl" /subkeyreg %KeyPath% /grant=Администраторы=f
reg add %KeyPath% /v "" /t REG_EXPAND_SZ /d %KeyParm% /f
"%~dp0subinacl" /subkeyreg %KeyPath% /grant=Администраторы=r

Set KeyPath=HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{42aedc87-2188-41fd-b9a3-0c966feabec1}\InProcServer32
Set KeyParm="%%SystemRoot%%\SysWOW64\windows.storage.dll"

"%~dp0subinacl" /subkeyreg %KeyPath% /grant=Администраторы=f
reg add %KeyPath% /v "" /t REG_EXPAND_SZ /d %KeyParm% /f
"%~dp0subinacl" /subkeyreg %KeyPath% /grant=Администраторы=r

Set KeyPath=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run
Set KeyParm="%~dp0IconRest.cmd"

reg add %KeyPath% /v "IconRest" /t REG_SZ /d %KeyParm% /f

Set KeyPath=
Set KeyParm=
Echo.
Echo Ready!

Запусти и перезагрузись.

Если не хош, чтоб у тебя он постоянно выполнялся при загрузке Виндовса удали строку reg add %KeyPath% /v "IconRest" /t REG_SZ /d %KeyParm% /f
Батник можешь получить готовый в архиве. Файл 129609

[sergesneg]

Vadikan, ну не получается у меня без сторонних программ скриптами сделать, пришлось использовать SubInACL.exe

[Vadikan]

ну не получается у меня без сторонних программ скриптами сделать, пришлось использовать SubInACL.exe »

Это не страшно, но... у вас в коде:

1. Пути в реестре неправильные - без \
2. Не предусмотрено восстановление иходных разрешений на разделы реестра
3. Не учтена работа в английской ОС. Надо использовать SID групп / учетных записей, чтобы решение не зависело от языка

[sergesneg]

Ну извините, у меня для русских ОС, так наглядней. Для вражеских нужно "Администраторы" заменить на S-1-5-32-544

[Vadikan]

sergesneg, если вы взялись писать код, будьте любезны его поддерживать с учетом замечаний (вы проигнорировали одно). Если вы не хотите использовать SID, пишите комментарии в коде.

В любом случае используйте тег [code][/code]

[sergesneg]

По требованию модератора пришлось переписать батник для вражеских Червонцев, спасибо ему за подсказку, зато научился батники писать:

Код:

@Echo off

Echo Starting Sergesneg Icon Restore...
If Exist SubinACL.exe GoTo NextStart
  Echo Файл SubinACL.exe должен присутствовать в текущм каталоге (%~dp0) или пути 
  Echo SubinACL.exe file must be present in the current directory (%~dp0) or path
  pause
  Exit /b
:NextStart
SetLocal
 
Rem When used in the operating system without the Russian language, you can comment out the bottom line
chcp 1251
 
Rem SID S-1-5-32-544 to the Administrators group
Rem The Russian-language OS for clarity SID can be replaced by the Администраторы
Set MyUser=S-1-5-32-544
 
Set KeyPath=HKEY_CLASSES_ROOT\CLSID\{42aedc87-2188-41fd-b9a3-0c966feabec1}\InProcServer32
Call :SetReg \system32\windows.storage.dll
 
Set KeyPath=HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{42aedc87-2188-41fd-b9a3-0c966feabec1}\InProcServer32
Call :SetReg \SysWOW64\windows.storage.dll

Set KeyPath=HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run
Rem You can remove the line from the bottom, if you do not need to insert the OS startup

reg delete %KeyPath% /v "%~n0" /f >null
reg add %KeyPath% /v "%~n0" /t REG_SZ /d "\"%~df0\"" /f
 
Echo.
Echo Ready
Echo.
Echo Для удаления из автозапуска выполните следующую команую строку:
Echo To remove from startup, use the command line:
Echo echo y ^| reg delete HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run /v "%~f0"

EndLocal
rem echo y | reg delete HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run /v "IconRest" 
Exit /b

Rem Subroutine
:SetReg
"%~dp0subinacl" /subkeyreg %KeyPath% /grant=%MyUser%=f
reg add %KeyPath% /ve /t REG_EXPAND_SZ /d %%SystemRoot%%%1 /f
"%~dp0subinacl" /subkeyreg %KeyPath% /grant=%MyUser%=r
Exit /b

Не забудьте перед перезагрузкой запустить, и оба файла SubInACL.exe и IconRest.cmd должны лежать в одном каталоге.

[djpoozo]

ESET в письме написали, что тему закрывают и она исчерпана.
ОБНОВЛЯЕМ базы антивируса и не должно больше слетать

для себя тему закрываю, не знаю чего вы до сих пор копошитесь
всем спасибо за внимание и советы

[sergesneg]

djpoozo, да потому, что слето не только у кого ЕСЕТ стоял, да и думали они долго. Здесь быстрее залатали их дырки.

[Calita]

В центре уведомлений появляются сообщения о том, что защитные программы отключены. Может помочь отключение защитника, однако как только вы удалите ESET, то останетесь без антивирусной защиты, пока не включите защитника обратно или не установите другой антивирус.

Отключил штатный Дефендер, а уведомления все равно приходят. Не знаю уже что делать!

Отключите в "Параметры -> Защитник Windows"

[Иван_Белоусов@vk]

Спасибо большое!!! Помогло решение 2. Но как сделать, чтобы при каждой загрузке винды значение по умолчанию не переделывать с %SystemRoot%\SysWow64\shell32.dll на %SystemRoot%\system32\windows.storage.dll???