[MKN]

kotkovets,
Когда то мы обсуждали тормоза обработки WMI запросов... В частности для NSIS есть http://nsis.sourceforge.net/WMI_header.
Без этого хедера многие вещи в NSIS сделать просто не возможно... Но вот скорость работы...
Недавно натолкнулся на обсуждение и преодоление тормозов при использовании WMI - http://bbs.vbstreets.ru/viewtopic.php?f=1&t=43269
Возможно ли как то "подправить" WMI.nsh для ускорения работы ?

[tony1990]

Всё - таки легко не получилось Нужно при тыканье на тип установки на странице компонентов вызывать функцию .onInit, так как в ней определяются компоненты которые нужно или не нужно выводить. Где это можно прописать?
Спасибо

[MKN]

tony1990,

Для стандартных страниц, когда требуется установка x32 компонентов в x64 ОС (ну и само собой х32 в х32 ОС и х64 в х64 ОС) проще манипулировать чекбоксами выбора вариантов установки на странице MUI_PAGE_COMPONENTS

Пользователю предлагается :
в x64 ОС выбрать чекбокс - либо "установка х32 компонентов" либо "установка х64 компонентов". Очень наглядно и удобно.

При установке в х32 ОС эти чекбоксы скрыты. А ещё лучше скрыть только "х64" чекбокс, а чекбокс "х32" оставить не активным.

Для отметки/скрытия чекбоксов используем в Function .onInit , (к примеру, для секции с ID х32 и секции с ID x64) :

SectionSetFlags ${x32} 17 ; не активный ОТМЕЧЕННЫЙ чекбокс секции x32
SectionSetFlags ${x64} 16 ; не активный НЕ отмеченный чекбокс секции x64
SectionSetText ${x64} "" ; скрыть чекбокс секции x64


В зависимости от состояния чекбоксов, устанавливаются флаги отметки секций (к примеру, для секции с ID х32 и секции с ID x64) используем :
!insertmacro UnselectSection ${x64}
!insertmacro SelectSection ${x32}
Ессно совместно с Function .onSelChange

И ещё такой момент. Как правило, пользователю по умолчанию предлагается путь установки ($INSTDIR) - в $PROGRAMFILES. Этот путь ($INSTDIR)
пользователь видит на странице MUI_PAGE_DIRECTORY (там же ессно может и изменить)

Так вот, при установке x32 компонентов в х32 ОС и при установке x64 компонентов в х64 ОС - каталог $PROGRAMFILES одинаков ,т.е. Program Files

А при установке x32 компонентов в х64 ОС, каталог $PROGRAMFILES - Program Files (x86)

Это надо учитывать для правильного отображения $PROGRAMFILES на стандартной странице MUI_PAGE_DIRECTORY.
Т.е. придётся добавить свою MUI_PAGE_CUSTOMFUNCTION_SHOW , в которой в зависимости от состояния чекбоксов выбора разрядности, устанавливаем $INSTDIR с правильным каталогом $PROGRAMFILES

[kotkovets]

Возможно ли как то "подправить" WMI.nsh для ускорения работы ? »

без понятия, будет желание гляну...

[Dodakaedr]

Подскажите как добавить текст в буфер обмена?

[MKN]

как добавить текст в буфер обмена? »

http://nsis.sourceforge.net/Copy_to,...dows_Clipboard

[tony1990]

Для стандартных страниц, когда требуется установка x32 компонентов в x64 ОС (ну и само собой х32 в х32 ОС и х64 в х64 ОС) проще манипулировать чекбоксами выбора вариантов установки на странице MUI_PAGE_COMPONENTS

Проблема в том что у меня в зависимости от версии программы куча компонентов, которые пользователь может включать/выключать. Поэтому я хотел сделать кастомную страницу с выбором до страницы компонентов. Но столкнулся со сложностями. Похоже что определение видимости/невидимости секций работает только в .onInit. И определяется это только в первый проход. При повторном запуске .onInit ничего не меняется. Короче, уже отчаялся я. Либо делать месседж бокс с выбором в начале .onInit (установка 32 или 64 версии программы) что по дизайну конечно не очень, либо делать 2 разных установщика.

[K.A.V.]

Похоже что определение видимости/невидимости секций работает только в .onInit »

Если пункт в элементе уже существует - его нельзя скрыть, можно только удалить
Если хотите именно скрывать пункты - вам нужно писать свою кастомную страничку, на ней уже будете обрабатывать, какой пункт выбрал пользователь (x32/x64) и в зависимости от выбора заполнять элемент нужными пунктами, очищая перед заполнением, всё это придётся прописывать вручную.
Набрасывать такой код не буду по одной простой причине - не знаю, какой вы хотите видеть кастомную страничку, такой же, как и дефолтная с выпадающим списком - или с выбором типа установки по принципу радиобаттонов и вообще, с помощью чего собираетесь делать кастомную страничку, IO или nsDialogs

Если не браться за кастомную страничку и попытаться реализовать это, то можно сделать с помощью костылей, т.е. код будет не очень красивый и удобный, вот пример этого ужасного кода (не пишите такой код никогда ):

Код:

!define PRODUCT_NAME "Моя программа"

!include "MUI.nsh"    

page custom ClickNext ; автоматически жмём кнопку "Далее", чтобы список элементов перестроился автоматически в зависимости от выбора - нам нужно перезагрузить страничку с компонентами, нажав "Назад" и потом "Далее"
!define MUI_PAGE_CUSTOMFUNCTION_SHOW hideBackButton ; Скрываем кнопку "Назад" от пользователя
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY   

!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_LANGUAGE "Russian"   

Name "${PRODUCT_NAME}"
OutFile "setup.exe"
InstallDir "$TEMP"
ShowInstDetails show

InstType /NOCUSTOM
InstType x32  
InstType x64  

Section /o "Эта секция для 32-bit ОС" SEC_32BIT 
SectionIn 1
SectionEnd   

Section /o "Эта секция для 64-bit ОС" SEC_64BIT 
SectionIn 2
SectionEnd  
             
Function ClickNext ; Жмём кнопку Далее
   GetDlgItem $0 $HWNDPARENT 1
   SendMessage $0 ${BM_CLICK} 0 0
FunctionEnd             
             
Function hideBackButton ; Скрываем кнопку Назад
   GetDlgItem $0 $HWNDPARENT 3
   ShowWindow $0 0 
FunctionEnd          
                          
Function .onSelChange   
   GetCurInstType $R0 ; Получаем статус выбранного типа установки
    ${If} $R0 == "0" ; Если первый (x32) - присваиваем текст секциям для x32 системы и скрываем секции с x64 системой
    SectionSetText ${SEC_32BIT} "SEC_32BIT"
    SectionSetText ${SEC_64BIT} ""
    ${ElseIf} $R0 == "1"
    SectionSetText ${SEC_32BIT} ""
    SectionSetText ${SEC_64BIT} "SEC_64BIT"
    ${EndIf} 
   GetDlgItem $0 $HWNDPARENT 3
   SendMessage $0 ${BM_CLICK} 0 0
FunctionEnd

Function .onInit
Var /Global IsWow64Process
  System::Call kernel32::GetCurrentProcess()i.s
  System::Call kernel32::IsWow64Process(is,*i.s)
  Pop $IsWow64Process ; 0 = 32-bit ОС, 1 = 64-bit ОС
  
 ${If} $IsWow64Process == "0" ; первоначальный выбор типа установки в зависимости от системы пользователя
   SetCurInstType 0
   SectionSetText ${SEC_32BIT} "SEC_32BIT"
   SectionSetText ${SEC_64BIT} ""
 ${Else}
   SetCurInstType 1
   SectionSetText ${SEC_32BIT} ""
   SectionSetText ${SEC_64BIT} "SEC_64BIT"
 ${EndIf}  
FunctionEnd

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC_64BIT} ""
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC_32BIT} ""
!insertmacro MUI_FUNCTION_DESCRIPTION_END

И при всей своей конструкции - он будет работать только при условии, что до странички компонентов у вас ничего не отображается...
С кастомной страничкой это будет выглядеть красивее и удобнее, да и правильнее

[MKN]

у меня в зависимости от версии программы куча компонентов, которые пользователь может включать/выключать. »

Т.е. , кроме разных разрядностей самих приложений ещё и разные компоненты для каждой разрядности ? Никогда не встречал такого бардака... Обычно, выбираемые компоненты - общие для разных разрядностей.
Ну, ежели у тебя именно так, то тогда лучший (если не единственный) вариант, как уже сказал K.A.V. - кастомная страница.

[K.A.V.]

Обычно, выбираемые компоненты - общие для разных разрядностей »

Вот вот...При таком раскладе можно просто в секции закинуть проверку на разрядность и распаковывать нужные файлы/записывать данные в реестр основываясь на этом

Либо можно по-другому, без кастомной странички с компонентами: создаём кастомную страничку с двумя радиобаттонами с предложением выбрать, какой тип приложения устанавливать (x32/x64) и уже после этого выбора задействовать тот кусок кода из .onInit, который скрывает "лишние" компоненты