[K.A.V.]

Теперь осталось эту кодировку оформить в скрипте. Вы не знаете как это сделать? »

Что сделать то? Поменять кодировку файла или записать корректно строку в файл с не ANSI кодировкой?
Если поменять кодировку файла - не знаю (и гуглить особо не ок с мобильного инета, поэтому как-нибудь сами), я вообще по теме кодировок "не бум бум"
Судя по запросу гугла на сайте NSIS есть какой-то плаг "Unicode", у меня в архиве на жд его нет (опять же, потому что темой кодировок не интересовался), поэтому не могу сказать, что это за плаг и какие в нём есть функции - возможно в нём как раз есть полезные функции

Поиском в гугле по-быстрому наткнулся на код от kotkovets, в нём есть макрос преобразования ANSI строки в UTF8, что позволяет писать корректно в файл с кодировкой UTF8 (насчет других - не в курсе)

Код:

!include "StrFunc.nsh"
${StrRep}

!define ANSIToUTF8 "!insertmacro ANSIToUTF8"
!macro ANSIToUTF8 SOURCE_STRING OUTPUT_STRING
      Push `${SOURCE_STRING}`
      System::Store SR2
      System::Call "kernel32::MultiByteToWideChar(i0,i0,tR2,i-1,i0,i0)i.R1"
      IntOp $R1 $R1 * 2
      System::Alloc $R1
      Pop $R0
      System::Call "kernel32::MultiByteToWideChar(i0,i0,tR2,i-1,iR0,iR1)"
      System::Call "kernel32::WideCharToMultiByte(i65001,i0,iR0,i-1,t.s,iR1,i0,i0)"
      System::Free $R0
      System::Store L
      Pop `${OUTPUT_STRING}`
!macroend 

OutFile "test.exe"

Section 
     ${StrRep} $0 "$EXEDIR\acity_temp" "\" "\\"
     ${ANSIToUTF8} "$0" "$0"
     WriteINIStr "$EXEDIR\TEST.ini" "Directories" "TempDir" "$0"
quit
SectionEnd

[tony1990]

Всем привет!

Возникла такая задача. В зависимости от выбора типа установки (32-бит или 64-бит) выводить в списке компонентов только нужные элементы (именно выводить, а не отмечать галочкой). Есть ли какой-нибудь флаг типа установки InstType чтобы знать какой выбран в данный момент или же тут только через кастомную страницу с радиобатонами придётся решать?

Заранее благодарен.

[K.A.V.]

Есть ли какой-нибудь флаг типа установки InstType чтобы знать какой выбран в данный момент »

Если справочник не читали - рекомендую это сделать, флаг типа установки (как ни странно) хранит только то, какой тип установки выбран, прочитайте про команду GetCurInstType

В зависимости от выбора типа установки (32-бит или 64-бит) выводить в списке компонентов только нужные элементы (именно выводить, а не отмечать галочкой) »

Ну так, проще простого, ведь NSIS не отображает секции без имён - этим и нужно пользоваться
А разрядность ОСи определяется буквально парой строк

В зависимости от выбора типа установки (32-бит или 64-бит)

Пользователю ещё и тыкать нужно? Сделайте всё на автомате...

Код:

Section /o "Эта секция скрывается при 64-bit ОС" SEC_64BIT 
SectionEnd
             
Section /o "Эта секция скрывается при 32-bit ОС" SEC_32BIT 
SectionEnd


Function .onInit
Var /Global IsWow64Process
  System::Call kernel32::GetCurrentProcess()i.s
  System::Call kernel32::IsWow64Process(is,*i.s)
  Pop $IsWow64Process ; 0 = 32-bit ОС, 1 = 64-bit ОС
  
 ${If} $IsWow64Process == "1"
   SectionSetText ${SEC_64BIT} "" ; Секции с пустыми именами не отображаются
 ${Else}
   SectionSetText ${SEC_32BIT} "" ; Секции с пустыми именами не отображаются
 ${EndIf}  
FunctionEnd

[Dodakaedr]

Можно такое реализовать?: надо дождаться завершения процесса, но этот процесс запускается в другом процессе. То есть использую запуск

Код:

Exec '"$INSTDIR\someprogram.exe"'

, но эта someprogram.exe запускает OtherProg.exe. Надо дождаться завершения работы этой самой OtherProg.exe. Сразу запуск с ожиданием OtherProg.exe не катит.

[kotkovets]

Dodakaedr, в шапке: Работа с процессами (ProcessFunc.nsh)
P.s
Скоро выложу обновленный, адаптированный по win10 winver2.nsh

[Dodakaedr]

Хотел уже писать что не нашел там нужного, а потом решил еще раз посмотреть по внимательней и увидел))

time - указанное время в миллисекундах, если указать константу ${INFINITE} или -1 установщик будет ждать завершения процесса.

Спасибо!

[BuZzOFF]

Код:

Function test
  StrCpy $R0 1
  loop:
  ${LineRead} "$EXEDIR\test.csv" "$R0" $R1
  StrCmp $R1 "" exit 0
  ${WordFind2X} "$R1" "{" "}" "+1" $R1
  StrCpy $PayloadID $R1
  IntOp $R0 $R0 + 1
  Goto loop
  exit:
FunctionEnd

Есть примерно такой код. Подскажите, пожалуйста, как в $PayloadID поместить все перечисленные значения из текстового файла, а не одно значение поочерёдно.
Что-то сообразить не могу...

[K.A.V.]

Код:

StrCpy $PayloadID "$PayloadID $R1"

Что-то сообразить не могу... »

Заработались наверное, отдохните

[tony1990]

Спасибо за GetCurInstType!

Пользователю ещё и тыкать нужно? Сделайте всё на автомате...

Задача несколько иная. Я наверно не совсем точно выразился. На 64 системе должен быть выбор установки 32-битной или 64-битной версии программы. С флагом типа установки теперь легко всё реализую.

Спасибо!

[kotkovets]

Адаптировал WinVer2.nsh под Windows 10.
Добавлены значения:

1. Определение названия ОС:
   Win10
   Server 2015 (пока так)
   
2. Определение редакции ОС:
   Windows 10 N
   Windows 10 China
   Home Single Language
   Home

---
На серверных ОС не тестировал, просьба потестировать.