[Dodakaedr]

Не подскажите как брать путь установки из реестра. »

Приблизительно так

Скрытый текст

Код:

[setup]
appname=app
appvername=1.0 app
defaultdirname={code:GetDir}

[Code]
function GetDir(S: string): string;
var
d,r: string;
begin
  S := ExpandConstant('{pf}\app');
 if RegKeyExists(HKLM, 'Software\1') then begin
  if RegQueryStringValue(HKLM, 'Software\1', 'Dir', d) then
  S := d;
  end;
  if RegKeyExists(HKLM, 'Software\2') then begin
  if RegQueryStringValue(HKLM, 'Software\2', 'Dir', r) then
  S := r;
  end;
  if RegValueExists(HKLM, 'Software\1', 'Dir') and RegValueExists(HKLM, 'Software\2', 'Dir') then
  s := r;
  Result := S;
end;

[Okta_333]

Доброго времени суток!
Помогите пожалуйста сделать панельку (не логотип), как на втором скрине:

Скрины

Панель представлена в виде PNG-картинки. Открывается с нажатием на кнопку. В активном режиме панели деактивируются CancelButton и NextButton.
MusicButton и VolPB не интересуют.

[Николай_Николаич@vk]

Здравствуйте.
Подскажите, как такое реализовать.
Путь установки C:\Prog
в папке Prog есть папка Prog1
И в этой папке куча папок.
Так вот, как сделать чтобы один файл file.hof раскидать по папкам которые находятся в папке Prog1

[ekspoint]

как сделать чтобы один файл file.hof раскидать по папкам которые находятся в папке Prog1 »

Код:

FileCopy(ExpandConstant('{app}\Prog\Prog1\file.hof'), ExpandConstant('{app}\Prog\Prog1\Prog1_1\file.hof'),false);
FileCopy(ExpandConstant('{app}\Prog\Prog1\file.hof'), ExpandConstant('{app}\Prog\Prog1\Prog1_2\file.hof'),false);

[kotyarko@fb]

ekspoint, для индусов такой вариант в самый раз подходит (это я про тот случай, если вложенных папок, например, 30). И не факт, что имеющиеся папки имеют не уникальные имена.

Путь установки C:\Prog в папке Prog есть папка Prog1 И в этой папке куча папок. Так вот, как сделать чтобы один файл file.hof раскидать по папкам которые находятся в папке Prog1 »

Например так:

Код:

var
 TFR: TFindRec;
begin
 if FindFirst(ExpandConstant('{app}\Prog\Prog1\') + '*', TFR) then
  try
   repeat
    if (TFR.Name <> '.') and (TFR.Name <> '..') then
     if TFR.Attributes and FILE_ATTRIBUTE_DIRECTORY > 0 then
      FileCopy(ExpandConstant('{app}\file.hof'), ExpandConstant('{app}\Prog\Prog1\') + TFR.Name + '\file.hof', False);
   until not FindNext(TFR);
  finally
   FindClose(TFR);
  end;
end;

[Dodakaedr]

Так вот, как сделать чтобы один файл file.hof раскидать по папкам которые находятся в папке Prog1 »

Наглядный пример использования))

Скрытый текст

Код:

[setup]
appname=test
appvername=test 1.0
defaultdirname={sd}\test

[files]
source: file.hof; destdir: {app};

[dirs]
name: {app}\Prog\Prog1\1;
name: {app}\Prog\Prog1\2g;
name: {app}\Prog\Prog1\3k;
name: {app}\Prog\Prog1\4i;

[code]
procedure SendFileToSubFolders;
var
 TFR: TFindRec;
begin
 if FindFirst(ExpandConstant('{app}\Prog\Prog1\') + '*', TFR) then
  try
   repeat
    if (TFR.Name <> '.') and (TFR.Name <> '..') then
     if TFR.Attributes and FILE_ATTRIBUTE_DIRECTORY > 0 then
      FileCopy(ExpandConstant('{app}\file.hof'), ExpandConstant('{app}\Prog\Prog1\') + TFR.Name + '\file.hof', False);
   until not FindNext(TFR);
  finally
   FindClose(TFR);
  end;
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssPostInstall then SendFileToSubFolders;
end;

[Николай_Николаич@vk]

Наглядный пример использования)) Скрытый текст Код: [setup] appname=test appvername=test 1.0 defaultdirname={sd}\test [files] source: file.hof; destdir: {app}; [dirs] name: {app}\Prog\Prog1\1; name: {app}\Prog\Prog1\2g; name: {app}\Prog\Prog1\3k; name: {app}\Prog\Prog1\4i; [code] procedure SendFileToSubFolders; var TFR: TFindRec; begin if FindFirst(ExpandConstant('{app}\Prog\Prog1\') + '*', TFR) then try repeat if (TFR.Name <> '.') and (TFR.Name <> '..') then if TFR.Attributes and FILE_ATTRIBUTE_DIRECTORY > 0 then FileCopy(ExpandConstant('{app}\file.hof'), ExpandConstant('{app}\Prog\Prog1\') + TFR.Name + '\file.hof', False); until not FindNext(TFR); finally FindClose(TFR); end; end; procedure CurStepChanged(CurStep: TSetupStep); begin if CurStep = ssPostInstall then SendFileToSubFolders; end; »

Спасибо, а не подскажете, как по такому же принципу раскидать папку

[kotyarko@fb]

Спасибо, а не подскажете, как по такому же принципу раскидать папку »

Используйте SHFileOperation, в нём есть функция CopyDir.

[Николай_Николаич@vk]

Используйте SHFileOperation, в нём есть функция CopyDir. »

А вы не могли бы привести пример копирования в папки, как с файлом.
а то кроме как просто копировать, ничего не получается.

[kotyarko@fb]

А вы не могли бы привести пример копирования в папки, как с файлом. а то кроме как просто копировать, ничего не получается. »

Код:

#include "SHFileOperation.iss"
.....
var
 TFR: TFindRec;
begin
 if FindFirst(ExpandConstant('{app}\Prog\Prog1\') + '*', TFR) then
  try
   repeat
    if (TFR.Name <> '.') and (TFR.Name <> '..') then
     if TFR.Attributes and FILE_ATTRIBUTE_DIRECTORY > 0 then
      CopyDir(ExpandConstant('{app}\Folder'), ExpandConstant('{app}\Prog\Prog1\') + TFR.Name);      
   until not FindNext(TFR);
  finally
   FindClose(TFR);
  end;
end;

Сам SHFileOperation можете спокойно найти в сети.