[sov44]

Удалите во всех строках выделенное цветом. »

удалил, результат:

Код:

%c
%b
%a

расчитывал получить

Код:

Microsoft Windows XP
Service Pack 3
2600.xpsp_sp3_qfe.100216-1510

[gora]

А так?

Код:

For /F "UseBackQ Tokens=2*" %%I In (`Reg Query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"^|Find /I "BuildLab"`) Do set Build=%%J
For /F "UseBackQ Tokens=2*" %%I In (`Reg Query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"^|Find /I "CSDVersion"`) Do set Version=%%J
For /F "UseBackQ Tokens=2*" %%I In (`Reg Query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"^|Find /I "ProductName"`) Do set Product=%%J
CHCP 1251 >Nul
echo %Product%>>txt.txt
echo %Version%>>txt.txt
echo %Build%>>txt.txt

[sov44]

А так? »

Скрипт заработал. Пишет первую и последнюю переменную, среднюю %Version% писать не хочет:

Код:

Microsoft Windows XP
2600.xpsp_sp3_qfe.100216-1510

[gora]

среднюю %Version% писать не хочет: »

Там в конце "3" стоит, вот об нее и спотыкается. Исправьте последние строки так:

Код:

>>txt.txt echo %Product%
>>txt.txt echo %Version%
>>txt.txt echo %Build%

[SharkyEXE]

2 all
Подниму тему

Есть 100%но рабочий вариант, файл 1.cmd

Скрытый текст

Код:

@Echo Off

Rem http://forum.oszone.net/post-1132000-6.html

For /F "Tokens=2* Delims=	 " %%A In ('Reg Query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /V ProductName^|Find "REG_SZ"') Do Set OS1=%%B
@Echo %OS1%
Pause
Exit

Но этот вариант не работает на Windows 2000, потому что в Windows 2000 отсутствует файл reg.exe

Пожалуйста, напишите мне 100%но рабочий вариант файла 1.cmd, чтобы работало в Windows 2000

[gora]

в Windows 2000 отсутствует файл reg.exe »

А команда ver там работает или ее результат тоже не устраивает?

Код:

Microsoft Windows XP [Версия 5.1.2600]
-----------------------------------------
Microsoft Windows [Version 6.1.7601]
-----------------------------------------
Microsoft Windows [Version 10.0.9926]

[SharkyEXE]

команда ver там работает »

В Windows 2000 команда ver работает.

Скрытый текст

Код:

Microsoft Windows 2000 [Версия 5.00.2195]

Но моя затея, если это возможно, чтобы вывести содержимое параметра ProductName из ключа HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion в Windows 2000

[Iska]

SharkyEXE, используйте WSH.

[SharkyEXE]

используйте WSH »

Мне надо, чтобы работало от Windows 2000 (можно даже более ранние выпуски Windows) до Windows 8.1

Если WSH удовлетворяет этому требованию - пожалуйста, напишите мне готовый код, чтобы вывести содержимое параметра ProductName из ключа HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion

Спасибо.

[Iska]

Мне надо, чтобы работало от Windows 2000 … до Windows 8.1 Если WSH удовлетворяет этому требованию »

Удовлетворяет.

можно даже более ранние выпуски Windows »

У Вас ещё есть где-то NT 4.0?!

Код:

WScript.Echo WScript.CreateObject("WScript.Shell").RegRead("HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProductName")

Можете попробовать использовать напрямую в пакетных файлах посредством «mshta.exe» в виде:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=" %%i in (
	`@"%systemroot%\system32\mshta.exe" "javascript:try {new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write(new ActiveXObject('WScript.Shell').RegRead('HKLM\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\ProductName'))};catch (e){};close();"`
) do set sProductName=%%i

if defined sProductName (
	echo [%sProductName%]
) else (
	echo Can't find [ProductName] parameter in [HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion].
)

endlocal
exit /b 0

но могут быть проблемы в новых ОС в случае, если там были заблокированы использованные объекты Automation в IE для зоны Локальный компьютер — это проверяйте на практике.