[Irenis]

Подскажите пожалуйста, как сделать, чтобы приложение по умолчанию устанавливалось на диск C в Program Files.
Например, в этом случае, я так понимаю, установка будет происходить туда, куда укажет пользователь:

[Files]
Source: "D:\Games\Launcher\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs

Что поменять, чтоб установилось в Program Files по умолчанию? Может вместо "{app}" что то поменять? Или как? Подскажите пожалуйста

[saurn]

Irenis, Параметр DefaultDirName в секции Setup определяет каталог установки по умолчанию. Константа {pf} = ProgramFiles и ProgramFiles(x86) на 64-х разрядных системах.

• DefaultDir={pf}\MyApp - создание папки приложения в корне папки ProgramFiles.

Если необходимо, чтобы программа всегда устанавливалась только в ProgramFiles, имеет смысл запретить пользователю выбор папки установки.

Скрытый текст

Код:

[Setup]
AppName=MyApp
AppVerName=MyApp
DefaultDirname={pf}\MyApp

;отключить страницу выбора папки.
DisableDirPage=yes

[Files]
Source: "D:\Games\Launcher\*"; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs

[Dodakaedr]

Что поменять, чтоб установилось в Program Files по умолчанию? Может вместо "{app}" что то поменять? Или как? Подскажите пожалуйста »

Или же запретить изменять путь установки

Скрытый текст

Код:

[Setup]
AppName=MyApp
AppVerName=MyApp
DefaultDirname={pf}\MyApp

[Files]
Source: "D:\Games\Launcher\*"; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs

[Code]
procedure InitializeWizard();
begin
  with WizardForm.DirEdit do
  begin
    Enabled := False;
  end;

  with WizardForm.DirBrowseButton do
  begin
    Enabled := False;
  end;
end;

[Irenis]

Спасибо Тут еще вот в чем дело. Игра состоит из лаунчера (который собственно и нужно было установить в Program Files), и из файлов самой игры. Так вот файлы эти должны устанавливаться в папку, которую укажет пользователь. В общем то разделить это все получилось и все устанавливается, куда надо. Единственное, что не так получается. На рабочем столе должен создаться ярлык, который запускает лаунчер, находящийся на диске С. Ярлык то создается, но находится файлик .exe не на диске С, а в папке с файлами игры и рабочая папка соответственно тоже та, в которую устанавливаются файлы игры. И ярлыком естественно ничего не запускается, так как он должен находиться на С. Вернее на диске С тоже есть этот .exe, но ярлык создается не из него. В общем ладно, сама уже запуталась, не знаю, как объяснить правильно

Решила в итоге не мудрить дальше, а поместить файлы игры и лаунчера в одну папку. Но вот думаю, будет ли это работать на виндовс 8. Просто это сам разработчик игры пишет, что лаунчер лучше устанавливать на диск С (особенно на виндовс 8). У меня виндовс 7, я этот лаунчер уже куда только не перемещала, все работает. А восьмерка никогда не стояла, вот и не знаю, отличаются ли они чем то существенно или нет. Но почему то кажется, если на семерке все работает, то и восьмерке должно работать?

[saurn]

Irenis

Скрытый текст

Код:

[Setup]
AppName=MyApp
AppVerName=MyApp
DefaultDirname={pf}\MyApp


[Files]
;лаунчер ставим в x:\Program Files, независимо от выбора папки пользователем
Source: "путь_к_лаунчеру"; DestDir: {pf}\папка программы; Flags: ignoreversion

;остальные файлы устанавливаем в папку по выбору пользователя
Source: "D:\Games\Launcher\*"; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs


[Icons]
;создаем ярлык для лаунчера
Name: {group}\имя; Filename: {pf}\папка программы\файл; WorkingDir: {pf}\папка программы;
Name: {commondesktop}\имя; Filename: {pf}\папка программы\файл; WorkingDir: {pf}\папка программы;

будет ли это работать на виндовс 8 »

Разницы нет. Ну если только не считать индивидуальные глюки каждой новой системы за особенность.

[Lex_from_Belarus]

Подскажите пожалуйста может кто сталкивался, что при использовании UninsHs (анинсталлер с возможностью модифицирования, а не просто удаления), когда количество компонентов много, то запоминание выбранных не происходит, если выбрать несколько компонентов, то всё ОК. Может кто сталкивался и вылечил либо вооще альтернативный вариант знает?

[Nordek]

не знаю, как объяснить правильно »

Есть игра которая отличается от обычной установки. Одна часть представляет из себя большую часть файлов игры. Вторая часть представляет из себя исполняющий файл Launcher.exe или исполняющий файл Launcher.exe и необходимые для его запуска компоненты. Нужно, чтоб: Одна часть установилась по умолчанию, т.е другими словами туда, куда укажет пользователь (в данном случае ярлык на рабочем столе не нужен). Вторая часть была жёстко привязана к пути (путь примерной установки: "C:\Program Files\Launcher\"), затем на рабочем столе создавался ярлык для запуска Launcher.exe из этой же папки.

как сделать »

Пример 1

Код:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputDir=.

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[Files]
Source: Game\Files\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs
Source: Game\Launcher\Launcher.exe; DestDir: {pf}\Launcher; Flags: ignoreversion

[Icons]
Name: {group}\My Program; Filename: {pf}\Launcher\Launcher.exe
Name: {group}\{cm:UninstallProgram,My Program}; Filename: {uninstallexe}
Name: {commondesktop}\My Program; Filename: {pf}\Launcher\Launcher.exe; Tasks: desktopicon

[Run]
Filename: {app}\Launcher\Launcher.exe; Description: {cm:LaunchProgram,My Program}; Flags: nowait postinstall skipifsilent

Пример 2

Код:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputDir=.

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[Files]
Source: Game\Files\*; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs
Source: Game\Launcher\*; DestDir: {pf}\Launcher; Flags: ignoreversion recursesubdirs createallsubdirs

[Icons]
Name: {group}\My Program; Filename: {pf}\Launcher\Launcher.exe
Name: {group}\{cm:UninstallProgram,My Program}; Filename: {uninstallexe}
Name: {commondesktop}\My Program; Filename: {pf}\Launcher\Launcher.exe; Tasks: desktopicon

[Run]
Filename: {app}\Launcher\Launcher.exe; Description: {cm:LaunchProgram,My Program}; Flags: nowait postinstall skipifsilent

[Юрій_Окропірідзе@vk]

Здравствуйте. Как мне сделать такую же кнопку(info) в своем инсталляторе https://yadi.sk/i/sJ_2-at3divCk

[saurn]

сделать такую же кнопку(info) »

Скрытый текст

Код:

[Setup]
AppName=MyApp
AppVerName=MyApp
DefaultDirname={pf}\MyApp


[code]
procedure TButtonOnClick( Sender: TObject );
var
    MainForm: TSetupForm;
begin
    begin
        MainForm := CreateCustomForm();
        with MainForm do
        try
            BorderIcons := [];
            ClientWidth := ScaleX( 300 );
            ClientHeight := ScaleY( 300 );
            Caption := 'Информация';
            Position := poScreenCenter;

            with TBevel.Create( nil ) do
            begin
                Parent := MainForm;
                SetBounds( ScaleX( 8 ), ScaleY( 8 ), ScaleX( 284 ), ScaleY( 249 ) );
                Shape := bsFrame;
            end;

            with TNewStaticText.Create( nil ) do
            begin
                Parent := MainForm;
                SetBounds( ScaleX( 12 ), ScaleY( 12 ), ScaleX( 276 ), ScaleY( 241 ) );
                AutoSize := False;
                Caption := 'Информация:' + #13#10 +
                            'Версия:'     + #13#10 +
                            'И т.д.';
                WordWrap := True;
            end;

            with TButton.Create( nil ) do
            begin
                Parent := MainForm;
                SetBounds( ScaleX( 112 ), ScaleY( 266 ), ScaleX( 76 ), ScaleY( 25 ) );
                ModalResult := mrOk;
                Caption := 'Закрыть';
            end;

            ShowModal();
        finally

            Free;
        end;
    end;
end;


procedure InitializeWizard();
begin
    with TButton.Create( nil ) do
    begin
        Parent := WizardForm;
        Left := ScaleX( 12 );
        Top := ScaleY( 327 );
        Caption := 'Info';
        OnClick := @TButtonOnClick;
    end;
end;

[Юрій_Окропірідзе@vk]

https://yadi.sk/i/vtpmpXtLdj2qU , тут вот какая то ошибка