[Iska]

561c8ee1358d8fd1e90046b0b61cfd23cfd8f47bbdb093a60453fff4ce93c527 с виду MD5 но как я не пытался его расшифровать не выходит все проги перепробовал , и ничего расшифрованный он выглядит так : 13-xWUI31HY4d »

v_adu_est_mesto_dlia_tebia@vk, это не MD5, это Secure Hash Algorithm Version 2 (SHA-2 — Википедия), конкретно — «SHA-256».

но как и где это сделать самому не могу понять »

«Как». Например, так:

Скрытый текст

Код:

Option Explicit

Const CAPICOM_HASH_ALGORITHM_SHA1    = 0
Const CAPICOM_HASH_ALGORITHM_MD2     = 1
Const CAPICOM_HASH_ALGORITHM_MD4     = 2
Const CAPICOM_HASH_ALGORITHM_MD5     = 3
Const CAPICOM_HASH_ALGORITHM_SHA_256 = 4
Const CAPICOM_HASH_ALGORITHM_SHA_384 = 5
Const CAPICOM_HASH_ALGORITHM_SHA_512 = 6

Dim strText
Dim objHashedData


strText = "13-xWUI31HY4d"

Set objHashedData = WScript.CreateObject("CAPICOM.HashedData")

With objHashedData
	.Algorithm = CAPICOM_HASH_ALGORITHM_SHA_256
	.Hash UStr2BStr(strText)
	
	WScript.Echo "String:   [" & strText & "]"
	WScript.Echo "MD5 Hash: [" & .Value & "]"
End With

Set objHashedData = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
' Based on «md5test.vbs.txt» (http://www.daleanderson.ca/code/wsh/md5test%2Evbs.txt)
'
' Unicode string to Byte string conversion
'=============================================================================
Function UStr2BStr(strText)
	Dim i
	Dim strResult
	
	
	strResult = ""
	
	For i = 1 To Len(strText)
		strResult = strResult & ChrB(Asc(Mid(strText, i, 1)))
	Next
	
	UStr2BStr = strResult
End Function 
'=============================================================================

Код: String: [13-xWUI31HY4d] MD5 Hash: [561C8EE1358D8FD1E90046B0B61CFD23CFD8F47BBDB093A60453FFF4CE93C527]

«Где». Ежели «ручками» — в любом приложении/утилите, поддерживающей данный метод. Программно, как в примере выше, в любом клиенте Automation: WSH, PoSH, AutoIt, AutoHotKey, VB/VBA/VB.Net, Pascal'и и C всяческие, и т.д, и т.п.