[Georgio]

Код:

@echo off

set "logs_dir=D:\Logs"
set "files_dir=D:\Files"
set "copies_dir=D:\Copies"

for /f "delims=" %%i in ('findstr /irc:"error [0-9][0-9]* [0-9][0-9]*" "%logs_dir%\*"') do (
 set var=%%i
 for /f "tokens=1,2 delims=$" %%j in ('call set /p"=%%var:error =$%%"^<nul') do (
  for /f "tokens=1,2" %%l in ("%%k") do (
   for /f "delims=" %%n in ('findstr /mc:"%%l %%m" "%files_dir%\*"') do (
    echo f| xcopy "%%n" "%copies_dir%\%%l %%m\%%~nxn">nul
    for /f "tokens=1,2 delims=:" %%o in ("%%j") do (
     copy "%%o:%%p" "%copies_dir%\%%l %%m">nul
     )
    )
   )
  )
 )

exit /b

[muqanna]

щя проверю, но все равно спасибо за внимания!

[muqanna]

Georgio извиняюсь я вас чуть-чуть обманул признак выглядит так:
error(пробел)12.15.4.6(пробел)0121 Когда я удалил там точки класс все работает! Хотел сам решит эту проблему но не как не получается! Но вам Спасибо!

[Georgio]

Когда я удалил там точки класс все работает! »

muqanna, не надо удалять точки. Просто тогда так:

Код:

for /f "delims=" %%i in ('findstr /irc:"error [0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]* [0-9][0-9]*" "%logs_dir%\*"') do (

.

[muqanna]

понял щя проверим! ...

[muqanna]

спасибо все работает!
Georgio Вопрос с того же сценарии если Variant=asda234e4sdaasd; типа такого мне надо взять код после = до ; а код может всегда меняться может 1 однозначной или 30 или 50 значения не ограниченно по количеству. Или такой вариант ищу слова Variant когда нахожу его
надо считать слова My Variant тут место my variant может быт любой слова! А Variant не меняется!
<input type="Variant" name="ie" value="windows-1251" >My Variant</>
Потом все это залит в тхт файл!
Спасибо за внимания!

[muqanna]

Georgio Вопрос по первому примеру. Как можно сделать так что когда копирует файл из Logs, primer.log заберал primer_00.log копировал его тоже, ну типа как primer*.*! Сам тоже ковыряюсь боюсь испортит код сделано очень умно! Я в шоки что bat ники творят чудеса!

[Georgio]

если Variant=asda234e4sdaasd; типа такого мне надо взять код после = до ; а код может всегда меняться может 1 однозначной или 30 или 50 значения не ограниченно по количеству. »

Код:

for /f "tokens=2 delims==;" %%i in ('findstr /irc:".*Variant=..*;.*" "example.txt"') do echo %%i>>"Variant.txt"

[Georgio]

ищу слова Variant когда нахожу его надо считать слова My Variant тут место my variant может быт любой слова! А Variant не меняется! <input type="Variant" name="ie" value="windows-1251" >My Variant</> »

Код:

for /f "tokens=2 delims=<>" %%i in ('findstr /irc:"^\<input type=\"Variant\" name=\"ie\" value=\"windows\-1251\" \>..*\<\/\>$" "example.txt"') do echo %%i>>"Variant.txt"