Ветеран
Сообщения: 1274
Благодарности: 1030
|
Профиль
|
Отправить PM
| Цитировать
Цитата Kashtan007:
|
Возможно ли сделать так как было раньше (через секцию run), только расставить последовательность действий? »
|
Kashtan007, и будет так же как и в #1845
Цитата Kashtan007:
|
Так как тут просто очистка res_mods, а хотелось бы очистку res_mods\0.9.3 и удаление xvm. »
|
Kashtan007, т.е. бекапить нужно уже не всю папку res_mods, а res_mods\0.9.3 ?
Цитата Kashtan007:
|
ясно, но к сожалению не удаляет. »
|
Kashtan007, пример-то хоть пробовали? Или в другой скрипт перенесли и под себя правили? Начните с примера:
Пример
Код:  #expr Exec("cmd", "/c md D:\test\res_mods\0.9.3\test", "", 1, SW_HIDE)
#expr Exec("cmd", "/c md D:\test\res_mods\xvm", "", 1, SW_HIDE)
#expr Exec("cmd", "/c cd.>D:\test\path.file", "", 1, SW_HIDE)
#expr Exec("cmd", "/c cd.>D:\test\res_mods\0.9.3\0.9.3.txt", "", 1, SW_HIDE)
#expr Exec("cmd", "/c cd.>D:\test\res_mods\0.9.3\test\test.txt", "", 1, SW_HIDE)
#expr Exec("cmd", "/c cd.>D:\test\res_mods\xvm\xvm.txt", "", 1, SW_HIDE)
[Setup]
AppName=test2
AppVerName=test2
DefaultDirName=D:\test
[Languages]
Name: ru; MessagesFile: compiler:Languages\russian.isl
[CustomMessages]
ru.DeleteOldMods=Удалить все старые моды
ru.CreateBackupOldMods=Сохранить бекап старых модов
ru.DeletingOldMods=Удаление старых модов...
ru.RestoringOldMods=Восстановление старых модов...
[Files]
Source: {app}\res_mods\0.9.3\*; DestDir: {app}\ModPack\BackUp\res_mods\0.9.3; Flags: external createallsubdirs recursesubdirs skipifsourcedoesntexist; AfterInstall: DeleteFiles(ExpandConstant('{app}\res_mods\0.9.3\*'), True); Check: IsOldMods('CreateBackupOldMods')
Source: {app}\path.file; DestDir: {app}\ModPack\OriginalFiles; Flags: external skipifsourcedoesntexist; AfterInstall: DeleteFiles(ExpandConstant('{app}\path.file'), False)
[InstallDelete]
Type: filesandordirs; Name: {app}\res_mods\xvm\*; Check: IsOldMods('DeleteOldMods')
[UninstallRun]
Filename: {cmd}; Parameters: "/c xcopy /ecihry ""{app}\ModPack\BackUp\res_mods\0.9.3"" ""{app}\res_mods\0.9.3\"""; StatusMsg: {cm:DeletingOldMods}; Flags: runhidden; Check: IsOldMods('CreateBackupOldMods')
Filename: {cmd}; Parameters: "/c xcopy /ecihry ""{app}\ModPack\OriginalFiles\path.file"" ""{app}\"""; Flags: runhidden
[code]
var
OldModsListBox: TNewCheckListBox;
///////////////////////////////////////////////
function IsOldMods(const Msg: String): Boolean;
begin
with OldModsListBox do
Result := Checked[Items.IndexOf(CustomMessage(Msg))]
end;
//////////////////////////////
procedure CreateSelectDirPage;
var
rt: TRect;
begin
OldModsListBox := TNewCheckListBox.Create(WizardForm);
with OldModsListBox do
begin
Parent := WizardForm.SelectDirPage;
Top := WizardForm.DirEdit.Top + WizardForm.DirEdit.Height + ScaleY(10);
Width := Parent.ClientWidth;
BorderStyle := bsNone;
ParentColor := True;
ShowLines := False;
WantTabs := True;
AddCheckBox(CustomMessage('DeleteOldMods'), '', 0, True, True, True, False, nil);
AddCheckBox(CustomMessage('CreateBackupOldMods'), '', 1, True, True, False, True, nil);
rt := ItemRect(ItemCount-1);
Height := rt.Bottom;
end;
end;
////////////////////////////////////////////////////////////////////////////
procedure DeleteFiles(const Path: String; const DeleteSubdirsAlso: Boolean);
begin
DelTree(Path, False, True, DeleteSubdirsAlso);
end;
/////////////////////////////
procedure InitializeWizard();
begin
CreateSelectDirPage;
end;
- В примере препроцессором создаются тестовые папки с файлами по пути D:\test. В ней находятся файл path.file для проверки сохранения в OriginalFiles, папка res_mods для проверки сохранения в BackUp. В res_mods 2 папки: xvm и 0.9.3 (плюс подпапка test), в каждой из папок по файлу с именем папки, в которой находится файл. Все готово к экспериментам.
- В IDE ставим брейкпоинты (F5 или мышкой) на 2-х строках из секции Files и на строке из секции InstallDelete.
- Запускаем скрипт на выполнение - F9.
- После кнопки "Установить" сработает первый брейк на InstallDelete. Жмем на F9, чтобы исполнение пошло дальше до второго брейка, это будет первая сторока из секции Files. Между этими 2-мя брейками выполнилась строка из InstallDelete. Смотрим что там. Там идет удаление папок и файлов из res_mods\xvm. Смотрим, так ли это. Открываем папку res_mods\xvm и видим, что она пуста, лежащего в ней файла xvm.txt нет.
- Жмем на F9, чтобы исполнение пошло дальше до третьего брейка, это будет вторая сторока из секции Files. Смотрим, что случилось за это время. В первой выполнившейся строке из Files написано скопировать из res_mods\0.9.3 все файлы и папки в папку ModPack\BackUp\res_mods\0.9.3, после этого удалить из res_mods\0.9.3 все файлы и папки. Смотрим, так ли это. Открываем папку ModPack\BackUp\res_mods\0.9.3 и видим, что в ней файл 0.9.3.txt и папка test с файлом test.txt. Открываем res_mods\0.9.3 и видим, что она пуста.
- Жмем на F9, заканчиваем установку. Смотрим, что случилось за это время. Отработала вторая строка из Files, в которой написано файл path.file скопировать в ModPack\OriginalFiles, а после удалить. Смотрим, так ли это. Открываем папку ModPack\OriginalFiles, видим в ней файл path.file, в D:\test его нет.
- Запускаем деинсталлятор unins000.exe. В секции UninstallRun строки, возвращающие файлы из ModPack\BackUp\res_mods\0.9.3 и ModPack\OriginalFiles в D:\test\res_mods\0.9.3 и D:\test соответственно. По окончании видим, что сохраненные файлы и папки вернулись назад.
- Что я делаю не так, что у вас не выходит?
|
