[Iska]

bugmenot3, получил. Пробуйте:

Код:

Option Explicit

Dim strSourceFile

Dim objFSO
Dim strContent
Dim strValue


strSourceFile = "E:\Песочница\0401\Full.log"

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If objFSO.FileExists(strSourceFile) Then
	With objFSO.OpenTextFile(strSourceFile)
		strContent = .ReadAll()
		.Close
	End With
	
	With WScript.CreateObject("VBScript.RegExp")
		.Pattern = "\(\)#4(.*?)\r\n"
		
		If .Test(strContent) Then
			strValue = .Execute(strContent).Item(0).Submatches.Item(0)
			
			WScript.Echo "Found value [" & strValue & "]."
			' Здесь Ваш код по отправке найденного текста
		Else
			WScript.Echo "Can't find pattern [" & .Pattern & "] in content of [" & strSourceFile & "]."
		End If
	End With
Else
	WScript.Echo "Can't find source file [" & strSourceFile & "]."
	WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0

Учтите — в выложенном файле найденное значение содержит в начале пробел:

Код:

Found value [ 39383196].

Он значим для Вас, или убрать возможные пробелы с начала/конца найденного текста?