[Iska]

батник висит в автозагрузке »

Следующим вопросом будет как скрыть чёрное окно консоли.

то батник удаляется »

Что есть «удаляется»? Завершает свою работу? Удаляет ярлык на себя из папки «Автозагрузка»? Удаляет сам себя с диска?

а файл шлет на север(внутри сети) »

Куда именно? Копирует? Перемещает? Посылает письмом?


На WSH, пробуйте:

читать дальше »

Код:

Option Explicit

Dim strSourceFolder
Dim strDestFolder

Dim objFSO
Dim objFile

Dim boolFound


strSourceFolder = "с:\000"
strDestFolder   = "\\Server\Share"


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

boolFound = False

Do
	If objFSO.FolderExists(strSourceFolder) Then
		If objFSO.FolderExists(strDestFolder) Then
			For Each objFile In objFSO.GetFolder(strSourceFolder).Files
				If StrComp(objFSO.GetExtensionName(objFile.Name), "txt", vbTextCompare) = 0 Then
					boolFound = True
					
					objFile.Copy strDestFolder & "\", True
					objFile.Delete True
				End If
			Next
			
			If boolFound Then
				Exit Do
			End If
			
			WScript.CreateObject("WScript.Shell").Popup "Надоедаю пользователю сообщением-напоминалкой", 30, "Заголовок", vbOKOnly + vbInformation + vbSystemModal
			
			WScript.Sleep 3 * 60 * 1000 ' 5 * 60 * 1000, 10 * 60 * 1000
		Else
			WScript.Echo "Destination folder [" & strDestFolder & "] not found."
			WScript.Quit 2
		End If
	Else
		WScript.Echo "Source folder [" & strSourceFolder & "] not found."
		WScript.Quit 1
	End If
Loop

WScript.Quit 0