[Tco 03]

Цитата sergey3695:
зачем тебе сворачивать его? »

В общем задача такая: В инсталляторе используется: WinTB.dll. Для отображения таскбара WinTB.dll использует: WizardForm.Handle. В инсталляторе, во время установки, есть возможность поиграть в мини-игру (так сказать для развлечения (если больше делать нечего)). Для этого дела есть естественно кнопка. Нажав на кнопку, инсталлятор сворачивается (так сказать, чтобы не мешал) и начинается игра. Сворачивается с помощью кода: SendMessage(WizardForm.Handle, WM_SYSCOMMAND, 61472, 0); Этот код и WinTB.dll используют: WizardForm.Handle. Так вот, нажав на кнопку, инсталлятор сворачивается и перестаёт работать таскбар, вместо таскбара там белое окно, так как при сворачивании, код: SendMessage(WizardForm.Handle, WM_SYSCOMMAND, 61472, 0); перехватил WizardForm.Handle. Дело в том, что если свернуть инсталлятор обычным способом (с помощью системного меню (там где сверху, справа, кнопки «Свернуть», «Закрыть»)) всё работает прекрасно. Вот поэтому и спрашиваю: -Как свернуть инсталлятор через секцию код, не использующий: WizardForm.Handle, или использующий тот же принцип, что и кнопка «Свернуть»?

[ROMKA-1977]

Подскажите пожалуйста код чекбокса "Не создавать папку в меню Пуск"

[habib2302]

ROMKA-1977,

Код:

[Setup]
AllowNoIcons=true

Код:

[Setup]
DefaultGroupName={#MyAppName}
DisableProgramGroupPage=yes

[Tasks]
Name: group; Description: {cm:CreateGroupeIcon};

[Icons]
Name: {group}\имя ярлыка; Filename: {app}\{#MyAppExeName}; Tasks: group;

Код:

[Setup]
DefaultGroupName={#MyAppName}
AllowNoIcons=false

[Tasks]
Name: group; Description: {cm:CreateGroupeIcon};

[Icons]
Name: {group}\имя ярлыка; Filename: {app}\{#MyAppExeName}; Tasks: group;

[ROMKA-1977]

habib2302, мне нужен код кастомного чекбокса через [code].

[sergey3695]

Tco 03, никак больше не свернуть. Проще изменить положение формы, типо скрыть. а на форму где проигрывается игра сделать кнопку на показ. к обратному положению формы. только так наверное.

[Dodakaedr]

мне нужен код кастомного чекбокса через [code]. »

читать дальше »

Код:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
DisableProgramGroupPage=yes

[Languages]
Name: "default"; MessagesFile: "compiler:Default.isl"

[Files]
Source: "C:\Program Files\Inno Setup 5 Ultra\Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion

[Icons]
Name: "{commonprograms}\My Program\My programm"; Filename: "{app}\MyProg.exe"; Check: "IconCheck";
Name: "{commondesktop}\My Program"; Filename: "{app}\MyProg.exe";

[Code]
var
  Pusk: TNewCheckBox;

function IconCheck: Boolean;
begin
Result:= Pusk.Checked;
end;

procedure InitializeWizard();
begin
  Pusk := TNewCheckBox.Create(WizardForm);
   with Pusk do
   begin
    Parent := WizardForm.SelectDirPage;
    Left := ScaleX(1);
    Top := ScaleY(110);
    Width := ScaleX(200);
    Height := ScaleY(17);
    Caption := 'Ярлык в меню «Пуск»';
    Checked := True;
   end;
end;

[Nordek]

ROMKA-1977, Если при пробном воспроизведении примера возникнет остановка на месте [Files] и вызовет ошибку: Source file "C:\Program Files\Inno Setup 5 Ultra\Examples\MyProg.exe" does not exist, то замените:

Код:

Source: "C:\Program Files\Inno Setup 5 Ultra\Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion

на

Код:

Source: "compiler:Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion

Dodakaedr, Inno Ultra установлена не у всех.

[El Sanchez]

Как свернуть инсталлятор через секцию код, не использующий: WizardForm.Handle, или использующий тот же принцип, что и кнопка «Свернуть»? »

Tco 03,

Код:

PostMessage(WizardForm.Handle, WM_SYSCOMMAND, SC_MINIMIZE, 0);

[ROMKA-1977]

Dodakaedr, не то. Своей функции не выполняет. Гдето встречал на просторах форума но забыл сохранить.

[Dodakaedr]

Своей функции не выполняет. »

А какая должна быть функция? Может так?

читать дальше »

Код:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
DisableProgramGroupPage=yes

[Languages]
Name: "default"; MessagesFile: "compiler:Default.isl"

[Files]
Source: "C:\Program Files\Inno Setup 5 Ultra\Examples\MyProg.exe"; DestDir: "{app}"; Flags: ignoreversion

[Icons]
Name: "{commonprograms}\My Program\My programm"; Filename: "{app}\MyProg.exe"; Check: "IconCheck";
Name: "{commondesktop}\My Program"; Filename: "{app}\MyProg.exe";

[Code]
var
  Pusk: TNewCheckBox;

function IconCheck: Boolean;
begin
Result:= not Pusk.Checked;
end;

procedure InitializeWizard();
begin
  Pusk := TNewCheckBox.Create(WizardForm);
   with Pusk do
   begin
    Parent := WizardForm.SelectDirPage;
    Left := ScaleX(1);
    Top := ScaleY(110);
    Width := ScaleX(220);
    Height := ScaleY(17);
    Caption := 'Не создавать папку в меню Пуск';
    Checked := True;
   end;
end;