[Iska]

Ваше изложение заставляет задать вопрос.

для запуска нескольких программ. »

— например?

[mwz]

есть ли возможность так же запускать службы? »

Главный вопрос: зачем?

[Thender]

Например запустить 4 облака(Гугл-диск, яндекс диск, Майл облако) 1 кликом.
К примеру связку автокад+солидворкс (что нибудь экспортировать).
К примеру Фотошоп и иллюстратор.
про службы это скорее для того что бы знать.
к примеру я отвязываюсь от интернета на неделю зачем мне запускать приложения связанные с ним?,
через неделю я подключаю интернет и если бы была возможность сделать это в 1 клик то у меня бы запустились необходимые для этого службы и приложения, - это самый банальный пример.

[charon]

Проще всего написать bat файл. В ком.строке набери start /?. http://support.microsoft.com/kb/126410 почитайте.

[Thender]

Это первое что пришло мне в голову но по моему я сразу наткнулся на ограничение длинны строки в бат файле.

[Iska]

но по моему я сразу наткнулся на ограничение длинны строки в бат файле. »

Например?

[Amigos]

и запускать их по мере необходимости но не через пуск а как то более автоматизированно, в 2 клика. »

пишите батник типа

Код:

Echo off
:punto
echo запуск PS
echo проверка на наличие памяти
tasklist | find "punto.exe" > NUL 
if %errorlevel%==0 goto mcheck
start c:\progra~1\yandex\puntos~1\punto.exe
timeout /t 2

:mcheck
echo запуск mCheck
echo проверка на наличие памяти
tasklist | find "MailCheck.exe" > NUL 
if %errorlevel%==0 goto opera
start c:\Progra~1\Applet\mailch~1.exe
timeout /t 2

:opera
echo запуск opera
echo проверка на наличие памяти
tasklist | find "opera.exe" > NUL 
if %errorlevel%==0 goto tcmd
rem "c:\Program Files\Opera_AC\OperaAC.exe"
timeout /t 5

:tcmd
echo запуск Tc
echo проверка на наличие памяти
tasklist | find "TOTALCMD" > NUL 
if %errorlevel%==0 goto quip
start c:\Progra~1\TotalC~2\TOTALCMD.EXE
timeout /t 4

:quip
echo запуск QIP
echo проверка на наличие памяти
tasklist | find "qip" > NUL 
if %errorlevel%==0 goto calend
start c:\progra~1\qip\qip.exe
timeout /t 4

:calend
echo запуск Rainlendar
echo проверка на наличие памяти
tasklist | find "Rainlendar2" > NUL 
if %errorlevel%==0 goto appp6
rem start c:\progra~1\applet\railen~1\rainle~1.exe
timeout /t 3

:appp6
echo запуск rclient
echo проверка на наличие памяти
tasklist | find "RClient" > NUL 
if %errorlevel%==0 goto appp7
start c:\progra~1\radmin\rclient.exe
timeout /t 2

:appp7
goto appp9

echo запуск fbx
echo проверка на наличие памяти
tasklist | find "FileBX" > NUL 
if %errorlevel%==0 goto appp8
rem start c:\progra~1\Applet\FileBX\FileBX.exe
timeout /t 3


:appp8
echo запуск USBSafelyRemove
echo проверка на наличие памяти
tasklist | find "USBSafelyRemove" > NUL 
if %errorlevel%==0 goto appp9
start "USBSafelyRemove" "c:\PROGRAM FILES\USB Safely Remove\USBSafelyRemove.exe"

timeout /t 1

:appp9
echo запуск SysInfoMyWork
echo проверка на наличие памяти
tasklist | find "SysInfoMyWork.exe" > NUL 
if %errorlevel%==0 goto appp10
start "SysInfoMyWork" "c:\Program Files\SysInfoMW\SysInfoMW.exe"

timeout /t 1

:appp10

Ярлык для батника кидаете на рабочий стол

есть ли возможность так же запускать службы? »

net start

через неделю я подключаю интернет и если бы была возможность сделать это в 1 клик то »

Как следует потрахаться, чтобы один раз в неделю сэкономить несколько кликов?
Очень сомнительно.

[Iska]

На основе кода коллеги Amigos сделал по единому образцу:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for %%i in (
	"Punto Switcher|punto.exe|C:\Program Files\Yandex\Punto Switcher\punto.exe" ^
	"Калькулятор|calc.exe|C:\WINDOWS\system32\calc.exe" ^
	"Блокнот|notepad.exe|C:\WINDOWS\system32\notepad.exe" ^
	"Far Manager|Far.exe|C:\Program Files\Far Manager\Far.exe"
) do (
	for /f "usebackq tokens=1-3 delims=|" %%j in ('%%~i') do (
		title Запуск [%%j]
		tasklist /fi "ImageName eq %%k" | find.exe /i "%%k" || (
			start "" "%%l"
			timeout /t 2
		)
	)
)

timeout /t 4

endlocal
exit /b 0

[charon]

Это первое что пришло мне в голову но по моему я сразу наткнулся на ограничение длинны строки в бат файле. »

http://support.microsoft.com/kb/830473/ru - В пакетном файле общая длина следующую командную строку, которая используется в пакетных файлах не может содержать более 8191 либо 2047 знаков (в зависимости от операционной системы).
Имхо: вроде достаточно. Но в статье есть способ обхода ограничения.