[Creat0R]

Код:

$sFullName = _GetUserName()

If @error Then
    ConsoleWrite('Not in domain' & @LF)
Else
    ConsoleWrite($sFullName & @LF)
EndIf

Func _GetUserName($sDomain = @ComputerName, $sUserName = @UserName)
    Local $objWMIService = ObjGet('winmgmts:\\' & @ComputerName & '\root\CIMV2')
    Local $colItems = $objWMIService.ExecQuery('SELECT * FROM Win32_UserAccount WHERE Name = "' & $sUserName & '"', 'WQL', 0x10 + 0x20)

    If IsObj($colItems) Then
        For $objItem In $colItems
            If $objItem.Domain = $sDomain Then
                $sFullName = $objItem.FullName

                If $sFullName <> '' Then
                    Return $sFullName & ' (' & $sUserName & ')'
                EndIf
            EndIf
        Next
    EndIf

    Return SetError(1, 0, $sUserName)
EndFunc

[Angel_19]

Скрипт все время выдает:

Код:

Not in domain

Хотя я в доменной учетке сейчас.
Пробовал при вызове функции явно указывать домен, результат тот же:

Код:

$sFullName = _GetUserName('mydomain')

, также пробовал:

Код:

$sFullName = _GetUserName('mydomain.local')

[Creat0R]

Скрипт все время выдает »

А что если закомментировать условие:

Код:

If $objItem.Domain = $sDomain Then

?

[Angel_19]

То же самое...

[madmasles]

Angel_19,
У меня не возвращается $objItem.FullName ни для кого.
У меня только так работает:

Код:

;...
If $objItem.Domain = $sDomain Then
	Local $sRet = $objItem.FullName
	If $sRet Then Return $sRet
	$sRet = $objItem.Caption
	If $sRet Then Return $sRet
EndIf
;...

[Angel_19]

Помогло изменение:

Код:

$sFullName = $objItem.FullName

на

Код:

$sFullName = $objItem.Name

[Iska]

Код:

AutoItSetOption("MustDeclareVars", 1)

Local $oADSystemInfo = ObjCreate("ADSystemInfo")
Local $oIADsUser     = ObjGet("LDAP://" & $oADSystemInfo.UserName)

ConsoleWrite($oIADsUser.sAMAccountName & @CRLF)
ConsoleWrite($oIADsUser.FullName & @CRLF)

[madmasles]

Iska,
У меня Ваш код с такой ошибкой вылетает:

Код:

... .au3 (15) : ==> The requested action with this object has failed.:
Local $oIADsUser     = ObjGet("LDAP://" & $oADSystemInfo.UserName)
Local $oIADsUser     = ObjGet("LDAP://" & $oADSystemInfo.UserName^ ERROR
->18:31:03 AutoIt3.exe ended.rc:1

[Iska]

madmasles, а AD у Вас развёрнута?