Имя пользователя:
Пароль:  
Помощь | Регистрация | Забыли пароль?  

Название темы: [addon] 7-Zip
Показать сообщение отдельно

Аватара для gora

Ушёл из жизни


Сообщения: 6021
Благодарности: 3491

Профиль | Отправить PM | Цитировать


Цитата *OM*:
Есть ли способ экспорта настроек с уже установленного 7zip в аддон? »
Цитата Noveon:
экспортированием соответствующей ветки реестра после настройки программы. »
Подскажите пожалуйста, как это сделать. »
Сделал скрипт для экспорта ассоциаций и настроек архиватора в reg файл:
Код: Выделить весь код
@Echo Off
Set "ext=001 7z arj bz2 bzip2 cab cpio deb dmg fat gz gzip hfs iso lha lzh lzma ntfs rar rpm squashfs swm tar taz tbz tbz2 tgz tpz txz vhd wim xar xz z zip"
RD "tmp" /S /Q 2>Nul
MD "tmp" 2>Nul

(Echo Windows Registry Editor Version 5.00
Echo.
For %%a In (%ext%) Do (
	Reg Export "HKCR\.%%a" "tmp\%%a.reg" 2>Nul >Nul
	Find /i "7-Zip." "tmp\%%a.reg" 2>Nul >Nul &&(
		For /F "skip=2 tokens=*" %%i In ('Type "tmp\%%a.reg"') Do Echo %%i
		Echo.
	)
)
For %%a In (%ext%) Do (
	Reg Export "HKCR\7-Zip.%%a" "tmp\7-Zip.%%a.reg" 2>Nul >Nul
	Find /i "7-Zip." "tmp\7-Zip.%%a.reg" 2>Nul >Nul &&(
		For /F "skip=2 tokens=*" %%i In ('Type "tmp\7-Zip.%%a.reg"') Do Echo %%i
		Echo.
	)
)
Reg Export "HKCU\Software\7-Zip" "tmp\7-ZipOpt.reg" 2>Nul >Nul
For /F "skip=2 tokens=*" %%i In ('Type "tmp\7-ZipOpt.reg"') Do Echo %%i
)>7zipArch.reg
RD "tmp" /S /Q 2>Nul
Pause
После запуска рядом со скриптом появится файл 7zipArch.reg, который и нужно положить рядом с SFX архивом, перед запуском SFX.

Последний раз редактировалось gora, 06-04-2014 в 21:12.

Это сообщение посчитали полезным следующие участники:

Отправлено: 09:15, 01-04-2014 | #108

Название темы: [addon] 7-Zip