CMD/BAT - Скриншот панели управления и вставка в WORD

Iska · Отправлено: **23:13, 12-03-2014** | #2

Цитата upward:

Не могу понять,почему не открывает word »

Открывает. Посмотрите процессы в Диспетчере задач. Но лучше:

Код:

Set WB = CreateObject("Word.Basic")
Set objWord = WScript.CreateObject("Word.Application")

Если Вам нужно Word увидеть:

Код:

objWord.Visible = True

Ну, и, закрывать:

Код:

objWord.Quit
Set objWord = Nothing

А так — мутное задание со странным выбором в качестве исполнителя WSH.

upward · Отправлено: **10:14, 13-03-2014** | #3

Iska, я не так выразился. Вроде скрипт и переходит по вкладкам и ворд в процессах висит,но скринов скрипт не делает

Iska · Отправлено: **11:32, 13-03-2014** | #4

upward, гарантировать корректную работу «SendKeys()» практически невозможно. Пробуйте:

Код:

Option Explicit

Const wdCollapseEnd = 0

Dim objWshShell
Dim objWord
Dim objDocument
Dim objWB

Dim i
Dim strPath


Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWord     = WScript.CreateObject("Word.Application")
Set objWB       = WScript.CreateObject("Word.Basic")

Set objDocument = objWord.Documents.Add()

For i = 0 To 4
	With objWshShell.Exec("""%SystemRoot%\System32\rundll32.exe"" SHELL32.DLL,Control_RunDLL SYSDM.cpl,@0," & CStr(i))
		WScript.Sleep 1000
		objWshShell.AppActivate .ProcessID
		WScript.Sleep 300
		objWB.SendKeys "%{PRTSC}", True
		WScript.Sleep 1000
		
		.Terminate()
	End With
	
	With objWord.Selection
		.Paste
		.Collapse wdCollapseEnd
		.InsertParagraphAfter
		.Collapse wdCollapseEnd
		.TypeText "Рисунок " & CStr(i + 1)
		.InsertParagraphAfter
		.Collapse wdCollapseEnd
	End With
Next

objDocument.SaveAs "c:\My Screenshots.doc"
objDocument.Close

objWord.Quit

Set objWord     = Nothing
Set objWB       = Nothing
Set objWshShell = Nothing

WScript.Quit

upward · Отправлено: **11:46, 13-03-2014** | #5

если вас не затруднит,можете пояснить что где и как и про

Цитата Iska:

«SendKeys()» »

прочитать где.
Спасибо заранее.

-----------------
при запуске скрипта sysdm.cpl открывает в свернутом режиме и автоматом должно по вкладкам переходить верно?

Iska · Отправлено: **11:56, 13-03-2014** | #6

Цитата upward:

если вас не затруднит,можете пояснить что где и как и про
Цитата Iska:
«SendKeys()» »
прочитать где. »

Переведите, пожалуйста, на русский.

Цитата upward:

при запуске скрипта sysdm.cpl открывает в свернутом режиме и автоматом должно по вкладкам переходить верно? »

Нет, не верно.

upward · Отправлено: **11:59, 13-03-2014** | #7

Iska, скрипт который вы написали как он работает?

Iska · Отправлено: **12:02, 13-03-2014** | #8

Так, как Вы заказывали:

Цитата upward:

Запустить модуль панели управления (см. таблицу). Сделать копию экрана для каждой страницы окна модуля в документ WORD и вставить поясняющий текст … . Сохранить файл. Закрыть все окна. »

upward · Отправлено: **12:04, 13-03-2014** | #9

Iska, а вы его запускали?просто что-то не то он делает. в плане скриншотов.
скрипт не переходит по вкладкам

Iska · Отправлено: **12:35, 13-03-2014** | #10

Цитата upward:

Iska, а вы его запускали? »

Угу. Вот примерный результат:

Когда нет возможности, я обычно так и пишу в скобках — «не проверялось».

Цитата upward:

просто что-то не то он делает. в плане скриншотов. »

Среда исполнения: Windows XP SP3, Microsoft Office 2003.

Цитата upward:

скрипт не переходит по вкладкам »

Скрипт и не «ходит по вкладкам». Каждый раз открывается окно свойств системы с заданной вкладкой:

Код:

"%SystemRoot%\System32\rundll32.exe" SHELL32.DLL,Control_RunDLL SYSDM.cpl,@0,0
"%SystemRoot%\System32\rundll32.exe" SHELL32.DLL,Control_RunDLL SYSDM.cpl,@0,1
"%SystemRoot%\System32\rundll32.exe" SHELL32.DLL,Control_RunDLL SYSDM.cpl,@0,2
"%SystemRoot%\System32\rundll32.exe" SHELL32.DLL,Control_RunDLL SYSDM.cpl,@0,3
"%SystemRoot%\System32\rundll32.exe" SHELL32.DLL,Control_RunDLL SYSDM.cpl,@0,4

после отсылки «Alt-PrintScreen» и паузы процесс принудительно «снимается».