[Iska]

которые появились за прошедший 1 час »

Кто или что будет отслеживать или определять этот час? По каким принципам?

[alek2012]

нужно отследить файлы pdf которые появились за прошедший час времени и их отправить

[Iska]

alek2012, я тоже умею повторять, смотрите: кто или что будет отслеживать или определять этот час? По каким принципам?

[alek2012]

можно по дате модификации каталога например каждый час проверять условием

If DatePart("yyyy",Now)=DatePart("yyyy",objDIR.DateLastModified) And _
DatePart("m",Now) =DatePart("m",objDIR.DateLastModified) And _
DatePart("d",Now) =DatePart("d",objDIR.DateLastModified) And _
DatePart("h",Now) =DatePart("h",objDIR.DateLastModified) Then

Set oMyMail = CreateObject("CDO.Message")

и в таком случае отправить файлы из каталога

а если изменений не было то отправить что файлов нет

например
Else
Set oMyMail = CreateObject("CDO.Message")
ну и отправить что файлов нет

главная суть вопроса как вытягивать файлы по маске из всех внутренних подкаталогов в том числе и скрытых

[Iska]

можно по дате модификации каталога например каждый час проверять условием »

Создали/удалили. Дата модификации каталога изменилась. А по сути — всё осталось как было.

Вы сразу начинаете решать, а я спрашиваю про принципы определения.

главная суть вопроса как вытягивать файлы по маске из всех внутренних подкаталогов в том числе и скрытых »

С этим проблем нет. Если Вас интересует — могу привести код.

[alek2012]

приведите пожалуйста код

[alek2012]

Создали/удалили. - ручками специально никто в этом каталоге создавать/удалять не будет, по этому мое условие по дате модификации подходит

[Iska]

приведите пожалуйста код »

Например, так:

Код:

Option Explicit

Dim arrFiles
Dim strFile

arrFiles = GetFilesByMask("E:\Песочница", "*.pdf")

For Each strFile In arrFiles
	WScript.Echo strFile
Next

WScript.Quit 0
'=============================================================================

'=============================================================================
Function GetFilesByMask(strSourceFolder, strMask)
	Const WshRunning  = 0
	Const WshFinished = 1
	Const WshFailed   = 2
	
	Dim strContent
	
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FolderExists(strSourceFolder) Then
			With WScript.CreateObject("WScript.Shell").Exec("""%comspec%"" /c ""dir /a:-d /b /s """ & strSourceFolder & "\" & strMask & """""")
				If .Status <> WshFailed Then
					strContent = ""
					
					Do
						strContent = strContent & .StdOut.ReadAll()
					Loop Until .Status = WshFinished
				End If
			End With
			
			GetFilesByMask = Split(StrConvert(strContent, "windows-1251", "cp866"), vbCrLf)
		Else
			WScript.Echo "Source folder [" & strSourceFolder & "] not found."
			WScript.Quit 1
		End If
	End With
End Function
'=============================================================================

'=============================================================================
' HKEY_CLASSES_ROOT\MIME\Database\Charset
' cp866, windows-1251, koi8-r, unicode, utf-8, _autodetect
'=============================================================================
Function StrConvert(ByVal strText, ByVal strSourceCharset, ByVal strDestCharset)
	Const adTypeText      = 2
	Const adModeReadWrite = 3
	
	
	With WScript.CreateObject("ADODB.Stream")
		.Type      = adTypeText
		.Mode      = adModeReadWrite
		
		.Open
		
		.Charset   = strSourceCharset
		.WriteText strText
		
		.Position  = 0
		.Charset   = strDestCharset
		StrConvert = .ReadText
		
		.Close
	End With
End Function
'=============================================================================

по этому мое условие по дате модификации подходит »

Делайте!