[Mat_y]

nik1967, возможно у Вас личка переполнена, Вы видели мое сообщение?

_____________________________

Вопрос знающим: как прописать для файла *.exe старт при загрузке системы?

[Nordek]

как прописать для файла *.exe старт при загрузке системы? »

Для текущего пользователя

Код:

[Registry]
Root: HKCU; SubKey: Software\Microsoft\Windows\CurrentVersion\Run; ValueType: string; ValueName: My Program; ValueData: {app}\MyProg.exe; Flags: uninsdeletevalue uninsdeletekeyifempty

Для всех пользователей

Код:

[Registry]
Root: HKLM; SubKey: SOFTWARE\Microsoft\Windows\CurrentVersion\Run; ValueType: string; ValueName: My Program; ValueData: {app}\MyProg.exe; Flags: uninsdeletevalue uninsdeletekeyifempty

Пример:

Код:

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
DefaultGroupName=My Program
OutputBaseFilename=setup

[Tasks]
Name: desktopicon; Description: {cm:CreateDesktopIcon}; GroupDescription: {cm:AdditionalIcons}; Flags: unchecked

[Files]
Source: compiler:Examples\MyProg.exe; DestDir: {app}; Flags: ignoreversion

[Icons]
Name: {group}\My Program; Filename: {app}\MyProg.exe
Name: {commondesktop}\My Program; Filename: {app}\MyProg.exe; Tasks: desktopicon

[Run]
Filename: {app}\MyProg.exe; Description: {cm:LaunchProgram,My Program}; Flags: nowait postinstall skipifsilent

[Registry]
Root: HKLM; SubKey: SOFTWARE\Microsoft\Windows\CurrentVersion\Run; ValueType: string; ValueName: My Program; ValueData: {app}\MyProg.exe; Flags: uninsdeletevalue uninsdeletekeyifempty

[Dimon585h]

Подскажите ещё, надо сделать так, чтобы инсталлятор сканировал выбранную папку на нужный файл и если он есть, то разрешал установку дальше, а если нет, то не разрешал и надо выбрать папку где есть.

[sergey3695]

Dimon585h, есть один старый пример проверки файла по md5 и путь тут берется из реестра. если файл не найден,то нужно указать его. Думаю в твоем случае это нужно.

читать дальше »

Код:

#define Key "HKLM\SOFTWARE\7-Zip" 
#define Subkey "Path" 
#define Filename "7zFM.exe" 
#define MD5 "6c14c21147452b73ddd51a1af9be0a87" 
 
[Setup] 
AppName=MyApp 
AppVerName=MyApp 
DefaultDirname={pf}\MyApp 
 
[CustomMessages] 
DirBrowseMessage=Пожалуйста, укажите расположение программы MyApp 
 
[code ] 
var 
Root: Integer; DestDir, Key, Subkey: String; 
 
function GetRegPath(): String; 
var str1, str2: string; 
begin 
str1:=Copy('{#Key}', 1, Pos('\', '{#Key}')-1); 
case AnsiUppercase(str1) of 
  'HKLM': Root:= HKLM; 'HKCU': Root:= HKCU; 
  'HKCR': Root:= HKCR; 'HKU':  Root:= HKU; 
  'HKCC': Root:= HKCC; 
end; 
Key:=Copy('{#Key}', Pos('\', '{#Key}')+1, Length('{#Key}')); 
Subkey:='{#Subkey}'; Result:=''; 
If RegQueryStringValue(Root, Key, Subkey, str2) then 
  if str2<>'' then Result:=str2 
end; 
 
Function CheckPath(Path, Filename, MD5: String): Boolean; 
begin 
Result:= False; 
If FileExists(AddBackslash(Path)+Filename) then 
  if AnsiUpperCase(GetMD5OfFile(AddBackslash(Path)+Filename))=AnsiUppercase(MD5) then Result:=True; 
end; 
 
Function GetPath(): Boolean; 
var Check, Cancel: Boolean; 
begin 
DestDir:=GetRegPath(); Check:=CheckPath(DestDir, '{#Filename}', '{#MD5}'); 
if Check = False then 
begin 
  repeat 
  Cancel:=BrowseForFolder(ExpandConstant('{cm:DirBrowseMessage}'), DestDir, False); 
  Check:=CheckPath(DestDir, '{#Filename}', '{#MD5}'); 
  until (not(Check=False))or(not Cancel); 
end; 
if (Check = True) then Result:=Check else Result:= Cancel; 
end; 
 
Function InitializeSetup(): Boolean; 
begin 
Result:= GetPath;
end; 
 
procedure InitializeWizard(); 
begin 
WizardForm.DirEdit.Text:= DestDir; 
end;

[Nordek]

sergey3695, Это перебор.

надо сделать так, чтобы инсталлятор сканировал выбранную папку на нужный файл и если он есть, то разрешал установку дальше, а если нет, то не разрешал и надо выбрать папку где есть. »

Эх, кто ищет - тот найдёт. Лишь бы желание только было.

Код:

[Code]
function NextButtonClick(CurPageID: Integer): Boolean;
begin
    Result := True;
    case CurPageID of
        wpSelectDir:
        begin
            Result := FileExists(ExpandConstant('{app}\MyProg.exe'));
            if not Result then MsgBoxEx(WizardForm.Handle, 'Ошибка! Приложение' + #32 + ExpandConstant('{#SetupSetting("AppName")}') + #32 + 'не найдено на данном компьютере', 'Ошибка', MB_OK or MB_ICONWARNING, 0, 0);
        end;
    end;
end;

Dimon585h, И удали посты #1551 и #1561, ни к чему плодить близнецов.

[tuz-veta]

Так че поможет кто или нет?

[Mat_y]

Для текущего пользователя »

Спс. Именно такой способ я и искал.
А есть ли способ заставить программу автоматом закрываться при завершении работы Windows? Просто программа записывает данные в конфиг при выходе, а при жестком завершении работы (убийство процесса) не записывает в конфиг изменения.

[Nordek]

Вот смотрю я, и удивляюсь. Писать по несколько одинаковых постов с просьбой, пальцы не устают. А нажать у пальчика силы иссякли?

Dimon585h, dima.dmitrienko.71@fb - А Johny777, а saurn-а, чего не поблагодарили? Не вижу! Подумайте, как долго бы вы ждали ответа на свой вопрос. Посты: #662, #933, #1324.
И иногда полезно читать справочку на форуме.

[tuz-veta]

Жалко что на мой вопрос нет ответа!

[Mailchik]

tuz-veta, скройте MessageBox

читать дальше »

Код:

[Code]
#ifdef UNICODE
  type
  PChar = PAnsiChar;
#endif

const
  BM_CLICK = $00F5;

function FindWindowEx(Parent, Child: Longint; ClassName, WindowName: PChar): Longint;
  external 'FindWindowExA@user32.dll stdcall';

var
  tmr: TTimer;

procedure Timer(Sender: TObject);
var
  hWnd: Longint;
begin
  hWnd := FindWindowByWindowName(SetupMessage(msgNoUninstallWarningTitle));
  if hWnd > 0 then
    PostMessage(FindWindowEx(hWnd, 0, 'Button', PChar(SetupMessage(msgButtonYes))), BM_CLICK, 0, 0);
end;

procedure InitializeWizard;
begin
  tmr := TTimer.Create(WizardForm);
  with tmr do begin
    Enabled := False;
    Interval := 5;
    OnTimer := @Timer;
 end;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  tmr.Enabled := CurPageID = wpSelectComponents;
end;