[saurn]

т.е ты имеешь виду перевести info.rtf »

читать дальше »

Ага, именно это имею ввиду, и не только. Эти вопросы подробно описаны в справке, сотни раз пережеванны на форумах и есть в стандартных примерах. Большинство ответов у вас под рукой. Я начал свое знакомство с Inno с разбора буржуйских каракулей в справке и анализа коробочных примеров. Советую вам поступить так же - большинство вопросов отпадут сами, да и кругозор расширится. Дело не в том, что кто-то не хочет вам помогать, но в том, что порой совсем не хочется тратить время, на объяснение азов, человеку, который не впервый раз открыл Inno Setup. В названии данного форума нет слов "Сделайте за меня", здесь лишь помогают, на безвоздмездной основе, по мере своих возможностей. И помогут, если вы не будете каждый раз задавать вопросы, ответы на которые вам были даны ранее.

[habib2302]

переводился в зависимости от выбраного языка» Как обычно самым простым способом, при помощи секции CustomMessages Код: [Languages] Name: Russian; MessagesFile: compiler:Languages\Russian.isl Name: English; MessagesFile: compiler:Languages\English.isl [CustomMessages] Russian.MsgUnins=Текст сообщения на русском English.MsgUnins=Текст сообщения на буржуйском »

не работает.как было

так и осталось!!!

[saurn]

не работает »

И не будет, если просто воткнуть строчки в скрипт и ждать, что они сами волшебным образом пропишутся везде, где нужно))

читать дальше »

Код:

[Setup]
AppName=My Application
AppVersion=1.5
DefaultDirName={pf}\My Application
AppId=wwwwwwwwwwwwww

[Languages]
Name: Russian; MessagesFile: compiler:Languages\Russian.isl
Name: English; MessagesFile: compiler:Languages\English.isl

[CustomMessages]
Russian.MsgUnins=Перед установкой необходимо удалить предыдущую версию приложения. Продолжить?
English.MsgUnins=Before installation it is necessary to remove the previous version of the app. Continue?

Russian.Failed=Удаление завершилось неудачей. Бывай!
English.Failed=Removal came to the end with failure. Happen!

[code]
function UninstallMyApp(): Boolean;
var
    Buff: String;
    i: Integer;
begin
    Result := not RegQueryStringValue( HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{#SetupSetting("AppID")}_is1', 'UninstallString', Buff );
    if not Result then Result := not FileExists(RemoveQuotes(Buff));
    if not Result then if MsgBox(CustomMessage('MsgUnins'), mbError, MB_YESNO) = IDYES then
    try
        Exec(RemoveQuotes(Buff), '', ExtractFilePath(RemoveQuotes(Buff)), SW_SHOW, ewWaitUntilTerminated, i);
    finally
        Result := not RegQueryStringValue( HKLM, 'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{#SetupSetting("AppID")}_is1', 'UninstallString', Buff );
        if not Result then MsgBox(CustomMessage('Failed'), mbError, MB_OK);
    end;
end;



function InitializeSetup(): Boolean;
begin
    Result := UninstallMyApp();
end;

[saurn]

Johny777, вариант с таймером оказался не жизнеспособен: память утекает, как в трубу.

[Dinvin4ester]

Ребята сильно не пинайте, но у меня опять возник вопрос - имею вот такое

Код:

[Files]
Source: iconka.ico; DestDir: {app}; Flags: ignoreversion recursesubdirs createallsubdirs
Source: InstallFiles\*; Flags: dontcopy
Source: "E:\Приколы\Игры\Flaming Ball\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdir

Вот эта папка - InstallFiles ставится вместе с игрой . Не подскажите как убрать ?

[saurn]

Dinvin4ester

Код:

Source: InstallFiles\*; DestDir: {tmp}; Flags: deleteafterinstall;

Хотя она и с флагом dontcopy не должна копироватся в папку установки...

[vint56]

Dinvin4ester
Source: InstallFiles\*; Flags: dontcopy
это временные файлы установщика они не как не могут устанавливаться в app каталог

[Johny777]

saurn,

вариант с таймером оказался не жизнеспособен: память утекает, как в трубу. »

Вот код. Что с работающим таймером, что без под конец установки процесс занимает 2700+ кб. Дело не в таймере:
Под себя при создании он берёт 1 раз 14 кб

читать дальше »

Код:

[Setup]
AppName=My Application
AppVersion=1.5
DefaultDirName={pf}\My Application



[Files]
Source: {fonts}\*; DestDir: {app}; Flags: external
Source: {fonts}\*; DestDir: {app}; Flags: external
Source: {fonts}\*; DestDir: {app}; Flags: external

[code  ]
type
    TFNTimerProc = Longint;
    
const
    TIMER_ID = 777;

function SetTimer(hWnd: HWND; nIDEvent, uElapse: UINT; lpTimerFunc: TFNTimerProc): UINT; external 'SetTimer@user32.dll stdcall';
function KillTimer(hWnd: HWND; uIDEvent: UINT): BOOL; external 'KillTimer@user32.dll stdcall';



procedure TimerProc(hwnd: HWND; uMsg: UINT; idEvent: UINT_PTR; dwTime: DWORD);
begin
    WizardForm.CancelButton.Enabled := FileExists('C:\msdia80.dll');
end;


procedure CurStepChanged(CurStep: TSetupStep);
begin
    case CurStep of
        ssInstall: SetTimer(WizardForm.Handle, TIMER_ID, 30, CallbackAddr('TimerProc'));

        ssPreInstall: KillTimer(WizardForm.Handle, TIMER_ID);
    end;
end;


procedure DeinitializeSetup();
begin
    KillTimer(WizardForm.Handle, TIMER_ID);
end;

И я не знаю какой таймер ты используешь. Я стандартным TTimer-м не пользуюсь
Кстати есть ещё высокоскоростной таймер MMTimer (мультимедийный), который работает в отдельном потоке без задержки, но он в твоём случае думаю неуместен

[saurn]

Johny777, спасибо. Дело было именно в таймере, просто я реализовал его не верно.Точнее не так.

читать дальше »

Код:

procedure Timer(Sender: TObject);
        begin
        ...
        end;
        
        ...
        Timer := TTimer.Create(nil);
        with Timer do
        begin
            Enabled := True;
            Interval := 5;
            OnTimer := @Timer;
        end;
        ...

Вот, как раз стандартный TTimer я и пользовал))

UPD:
А виноват действительно был не таймер. Нашел причину утечки памяти.

[Dinvin4ester]

Теперь такая ошибка - http://i46.fastpic.ru/big/2013/0701/...6ebac13f77.png
сам архив - http://sendfile.su/833359 . В том то и дело что вместе с игрой устанавливаются папки , но в них ничего нет .