[Iska]

как добавить вывод автора последних изменений ? »

firstarey, нет такого свойства. Может быть просто «Автор».

Если а) данное свойство поддерживается документом и б) если Проводник имеет доступ к этому свойству, то можно попробовать.

Вот пример получения значения свойства:

читать дальше »

Код:

Option Explicit

WScript.Echo GetProperty("E:\Песочница\0264\марк.xlsx", "Автор")

WScript.Quit 0
'=============================================================================

'=============================================================================
Function GetProperty(strPath, strProperty)
	Dim objFile
	
	Dim objFolder
	Dim objFolderItem
	
	Dim intPropertyNumber
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If Not .FileExists(strPath) Then
			WScript.Echo "Can't find file [" & strPath & "]."
			
			Exit Function
		End If
		
		Set objFile = .GetFile(strPath)
	End With
		
	With WScript.CreateObject("Shell.Application")
		Set objFolder = .NameSpace(objFile.ParentFolder.Path)
		
		If Not objFolder Is Nothing Then
			Set objFolderItem = objFolder.ParseName(objFile.Name)
			
			If Not objFolderItem Is Nothing Then
				intPropertyNumber = GetPropertyNumberByName(strProperty)
				
				If IsEmpty(intPropertyNumber) Then
					WScript.Echo "Can't find property name [" & strProperty & "]."
					
					Exit Function
				End If
				
				GetProperty = objFolder.GetDetailsOf(objFolderItem, intPropertyNumber)
			Else
				WScript.Echo "Can't parse file name [" & objFile.Name & "]."
			End If
		Else
			WScript.Echo "Can't get folder [" & objFile.ParentFolder.Path & "]."
		End If
	End With
End Function
'=============================================================================

'=============================================================================
Function GetPropertyNumberByName(strProperty)
	Dim objFolder
	Dim i
	
	With WScript.CreateObject("Shell.Application")
		Set objFolder = .NameSpace("shell:System")
		
		If Not objFolder Is Nothing Then
			For i = 0 To 2^8 - 1
				If LCase(objFolder.GetDetailsOf(, i)) = LCase(strProperty) Then
					GetPropertyNumberByName = i
					
					Exit For
				End If
			Next
		End If
	End With
End Function
'=============================================================================

[firstarey]

Iska, благодарю за ответ.
отчего то думал что авторство последних изменений сохраняется *pardon*

[Iska]

firstarey, всё возможно — я этого попросту не знаю, поскольку у меня нет ни развёрнутого AutoCad'а, ни его «тёзок» (если речь по прежнему о документах формата dwg; если найдёте. что-таки есть — дайте знать, попробую почитать документацию на предмет доступа посредством Automation). Потому я привёл пример из доступных мне.

[Sta1917]

Есть такое свойство, %<\AcVar LastSavedBy>% это данные для вставки в текст AutoCad
Как получить к нему доступ не знаю, но есть решения экспорта данных из открытого AutoCAD. Также это может быть полезным.

[Iska]

Sta1917, понятно.

Теоретически, сделать можно. Но желания заниматься подсчётом смещений нет ни малейшего.

У Вас вообще что? Какой продукт установлен?

[Sta1917]

Думаю лучше воспользоваться готовым решением экспорта в эксель с dwg.ru

[Iska]

Воспользуйтесь.

[firstarey]

Изначально полагалось что это расположено в свойствах файла, как например дата последнего изменения документа и, соответственно, возможно доработать предложенный в этой теме скрипт.

На данный момент остановился на том, что изменил предложенный Iska шаблон под свои нужды (полный путь до файла, имя, дата последнего изменения, последнего доступа, размер. не хватает лишь автора последнего изменения).

Раз уж все не так просто, то на том и остановимся, спасибо откликнувшимся.

[Iska]

Изначально полагалось что это расположено в свойствах файла, как например дата последнего изменения документа и, соответственно, возможно доработать предложенный в этой теме скрипт. »

Увы, нет. Это внутреннее свойство документа, и, судя по общедоступной информации, не транслируется Проводнику (кое-кто предлагает купить библиотеку, которая будет это делать).