VBS/WSH/JS - [решено] Перемещение файлов. Условие поиск слова в файле.

Iska · Отправлено: **18:52, 30-05-2013** | #2

Цитата Hixi:

и т.д. »

Какова кодировка текстовых файлов (если в и т.д. попадёт кириллица)?

Цитата Hixi:

Необходимая задача уже решалась когда-то на CMD/BAT http://forum.oszone.net/nextnewesttothread-242495.html »

Почему не устраивает то решение?

Hixi · Отправлено: **19:00, 30-05-2013** | #3

Прошу прощения, кириллица присутствует. Кодировка Dos-866
Нет возможности истользовать BAT. Необходимо решение на VBS.

Iska · Отправлено: **19:07, 30-05-2013** | #4

Цитата Hixi:

Прошу прощения, кириллица присутствует. »

Цитата Iska:

Какова кодировка текстовых файлов (если в и т.д. попадёт кириллица)? »

?

Цитата Hixi:

Если в файле найден текст "QWERTY" , то перенести этот файл в C:\QWERTY\"текущая дата"
Если в файле найден текст "ASDFGР" , то перенести этот файл в C:\ASDFGР\"текущая дата"
и т.д. »

Перечень «QWERTY», «ASDFGР» и «и т.д.» определён? Где будет находиться/задаваться — в самом скрипте, в параметрах скрипта, во внешнем текстовом файле (при большом количестве)?

Hixi · Отправлено: **19:13, 30-05-2013** | #5

Цитата Iska:

Какова кодировка текстовых файлов (если в и т.д. попадёт кириллица)? »
? »

DOS-866

Цитата Iska:

Перечень «QWERTY», «ASDFGР» и «и т.д.» определён? Где будет находиться/задаваться — в самом скрипте, в параметрах скрипта, во внешнем текстовом файле (при большом количестве)? »

Перечень не определен, может дополняться/изменяться. Указывать лучше в параметрах скрипта (зачений не более 20)

Iska · Отправлено: **06:53, 31-05-2013** | #6

Hixi, пробуйте:

Код:

Option Explicit

Dim strSourceFolder
Dim strDestFolder

Dim objFile

Dim strText
Dim strPhrase

Dim strDate
Dim strDestPath


If WScript.Arguments.Count >= 1 Then
	strSourceFolder = WScript.CreateObject("WScript.Shell").CurrentDirectory
	strDestFolder   = "c:\"
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		If .FolderExists(strDestFolder) Then
			WScript.Echo "Source folder:      [" & strSourceFolder & "]"
			WScript.Echo "Destination folder: [" & strDestFolder & "]"
			WScript.Echo "--------------------------------------------"
			
			strDate = GetLocalDate()
			
			For Each objFile In .GetFolder(strSourceFolder).Files
				If LCase(.GetExtensionName(objFile.Name)) = "txt" Then
					WScript.Echo "File: " & objFile.Path
					
					With objFile.OpenAsTextStream()
						strText = StrConvert(.ReadAll(), "windows-1251", "cp866")
						.Close
					End With
					
					For Each strPhrase In WScript.Arguments
						If InStr(1, strText, strPhrase, vbTextCompare) > 0 Then
							WScript.Echo Space(4) & "Phrase found: " & strPhrase
							
							strDestPath = .BuildPath(.BuildPath(strDestFolder, strPhrase), strDate)
							
							CreateFolderEx strDestPath
							objFile.Move .BuildPath(strDestPath, "\")
							
							WScript.Echo Space(4) & "Moved to folder [" & strDestPath & "]"
						End If
					Next
				End If
			Next
		Else
			WScript.Echo "Can't find destination folder [" & strDestFolder & "]"
		End If
	End With
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Phrase 1> <Phrase 2> ... <Phrase N>"
End If

WScript.Quit 0
'=============================================================================

'=============================================================================
Function GetLocalDate()
	Dim objSWbemObjectEx
	
	With GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
		For Each objSWbemObjectEx In .ExecQuery("SELECT LocalDateTime FROM Win32_OperatingSystem")
			GetLocalDate = Left(objSWbemObjectEx.LocalDateTime, 8)
			Exit For
		Next
	End With
End Function
'=============================================================================

'=============================================================================
Sub CreateFolderEx(strPath)
	With WScript.CreateObject("Scripting.FileSystemObject")
		If Not .FolderExists(strPath) Then
			CreateFolderEx .GetParentFolderName(strPath)
			.CreateFolder strPath
		End If
	End With
End Sub
'=============================================================================

'=============================================================================
' HKEY_CLASSES_ROOT\MIME\Database\Charset
' cp866, windows-1251, koi8-r, unicode, utf-8, _autodetect
'=============================================================================
Function StrConvert(ByVal strText, ByVal strSourceCharset, ByVal strDestCharset)
	Const adTypeText      = 2
	Const adModeReadWrite = 3
	
	
	With WScript.CreateObject("ADODB.Stream")
		.Type      = adTypeText
		.Mode      = adModeReadWrite
		
		.Open
		
		.Charset   = strSourceCharset
		.WriteText strText
		
		.Position  = 0
		.Charset   = strDestCharset
		StrConvert = .ReadText
		
		.Close
	End With
End Function
'=============================================================================

Пример вызова скрипта:

Код:

cscript.exe //nologo "Script.vbs" "рабы не" Мама

Возможный результат:

Hixi · Отправлено: **10:36, 31-05-2013** | #7

Спасибо! а если требуется вывод данных из файла (текста для поиска и при совпадении перемещение в указанную заранее дирректорию, нужна привязка текст\путь (текст для поиска "привет" при совпадении переместить в C:\dsa\123, файлы с текстом "Пока" при совпадении переместить в D:\фыва\908 ))?

Iska · Отправлено: **11:04, 31-05-2013** | #8

Hixi, пожалуйста, ещё раз и по-русски: не могу выудить смысл из Вашего поста.

Hixi · Отправлено: **11:40, 31-05-2013** | #9

Предположим есть список искомого текста и при нахождение одного из слов в файлах переместить в привязанную к слову дирректорию.

Родина = C:\try\"год"\"месяц"\"год_месяц_день"\прием
Горы = E:\asd\"год"\"месяц"\"год_месяц_вчерашний день"\прием
Привет = D:\789
Тополь-М = F:\14\тру

Iska · Отправлено: **20:29, 31-05-2013** | #10

"год", "месяц", "год_месяц_день" — это, я так понял, шаблоны? В которые при обработке должны подставляться значения текущей даты?