[Vadikan]

nikolajbunin, создайте структуру папок вручную и скопируйте содержимое DVD вручную. Это быстрее, чем писать вопрос на форуме

[morozoff]

Я на досуге оптимизировал данный скрипт под Windows 7, решил выложить в данной теме. Может быть кому-то пригодится.

Код:

@echo off
:Start
ECHO.
ECHO Этот командный файл создает структуру папок для
ECHO работы над автоматической установкой Windows Seven.
ECHO.
ECHO Во время этого процесса можно скопировать установочный
ECHO DVD Windows Seven на жесткий диск.
ECHO Вставьте DVD в привод и нажмите любую клавишу.
ECHO.
ECHO Если вы хотите скопировать DVD вручную позже,
ECHO просто нажмите любую клавишу.
PAUSE > NUL


::Все папки создаются командой mkdir
:CreateFolders
CLS
ECHO.
ECHO Создание папок . . .
SET work=%CD%\SevenWork
IF NOT EXIST %work%\NUL MKDIR %work%
IF NOT EXIST %work%\DVD\NUL MKDIR %work%\DVD
IF NOT EXIST %work%\DVD\Drivers\NUL MKDIR %work%\DVD\Drivers
IF NOT EXIST %work%\ISO\NUL MKDIR %work%\ISO
IF NOT EXIST %work%\Logs\NUL MKDIR %work%\Logs
IF NOT EXIST %work%\Mount\NUL MKDIR %work%\Mount
IF NOT EXIST %work%\Distribution\NUL MKDIR %work%\Distribution
IF NOT EXIST %work%\wim\NUL MKDIR %work%\wim
IF NOT EXIST %work%\Sandbox\NUL MKDIR %work%\Sandbox
IF NOT EXIST %work%\Updates\NUL MKDIR %work%\Updates
IF NOT EXIST %work%\xml\NUL MKDIR %work%\xml
IF NOT EXIST %work%\IE9\NUL MKDIR %work%\IE9
ECHO.
ECHO Работа с папками завершена.
pause


:: Копирование DVD
SET DVDDrive=NULL
FOR %%i IN (C D E F G H I J K L M N O P Q R S T U V W X Y Z) DO IF EXIST %%i:\sources\install.wim SET DVDDrive=%%i:\
IF "%DVDDrive%"=="NULL" GOTO :NoDVDDrive
ECHO.
ECHO Копирование установочного DVD Windows Seven...
START /WAIT /min "Копирование DVD Seven" XCOPY %DVDDrive%*.* "%work%\DVD\" /cheriy
ECHO.
ECHO Копирование завершено.

ECHO Процесс создания структуры папок завершен!
pause
exit

:NoDVDDrive
ECHO.
ECHO Установочный DVD Windows Seven не найден!
ECHO Позже скопируйте его содержимое вручную в папку:
ECHO %CD%\SevenWork\DVD
ECHO.
pause

Также прикрепляю готовый для использования bat файл.
Выражаю огромную благодарность Vadikan - автору первоначального скрипта.

[maslinaV]

У меня Windows 7 при запуске бат файла , почему то при выполнении команды для набора букв дисков в системе, происходит поиск только по C , D , E , F , а дальше не ищет и соотвественно выдает ошибку что в устройстве F нет диска , что диск не найден, почему не происходит поиск и по остальным.

Код:

FOR %%i IN (C D E F G H I J K L M N O P Q R S T U V W X Y Z)

Может есть какой то запрет в системе или ограничение, которое говорит о том что команда for может обработать только первые 4 буквы в системе

[maslinaV]

Запустил все построчно прекрасно отработалось....Буду искать ошибку...

[FreshMen85]

maslinaV

у вас в системе стоит кардридер, если да, то сценарий данного батника у вас работать не будет.

[maslinaV]

У меня нет картридера
Не понял в чем ошибка , только увидел одно, файл который создавал в Notepad++ отрабатывает все только до пункта копирования, а затем все закрывается .
Подгрузил файл в notepad ++ взятый с сайт, здесь на странице , немного подправил , он заработал, прошелся по строкам сравнил оба файла не нашел ошибок.
Тогда создал начисто файл в AkelPad все отработалось

Код:

@echo off
echo Создание структуры папок для настройки образа Windows 7.
echo.
echo Сядьте поудобней.
echo.
echo Начинаем нашу работу.
echo.
echo Для начала нажмите любую клавишу.
pause >nul
:CreateFolders
echo.
Echo Создадим переменную. 
set work=%~dp0windows7x64
echo проверим существование директории в заданной переменной .
echo если директории нет, тогдо создадим ее.
echo.
pause
if not exist "%work%" md "%work%"
echo.
echo сохраним имя текущего каталога и перейдем в директорию "%work%", и назначим ее текущей.
pushd "%work%"
echo.
pause
echo Используем команду For для создания папок внутри директории.
echo.
for %%A in (DVD ISO Logs Mount wim Sandbox Updates xml bootwim\lp bootwim\mount mui) do md "%%A"
echo.
echo Создание структуры папок завершено!
echo.
pause
::Копирование файлов установки Windows 7
echo.
echo Назначим переменную и присвоим ей значение.
echo.
set DVDDrive=NULL
echo.
echo Вставьте установочный диск в привод DVD.
echo или смонтируйте образ на виртуальный привод.
echo или вставьте USB flash в USB разъем.
echo с установочными файлами Windows 7.
echo.
pause
echo.
echo Произведем поиск установочных файлов по именам дисков в системе
echo в случае успеха, присвоим переменной  другое значение
echo и начнем копирование.
for %%i in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist %%i:\sources\install.wim set DVDDrive=%%i:\
echo.
if "%DVDDrive%"=="NULL" goto :NoDVDDrive
echo Если проверка неудачна, переход на заданную программой метку.
echo При запуске копирования, откроется другое окно, окно закроется автоматически.
pause
echo.
start /wait /max "Копирование установочных файлов Windows 7" xcopy "%DVDdrive%"*.* "%work%\DVD\" /heriy
echo Копирование завершено. 
pause
exit

:NoDVDDrive
ECHO.
ECHO Установочный DVD Windows Seven не найден!
ECHO Позже скопируйте его содержимое вручную в папку:.
ECHO "%work%\DVD".
ECHO.
pause 
exit

Спасибо Dragokas за подсказку и разъяснение некоторых моментов,
а вот в чем ошибка так и не понял , прикрепляю 2 файла Windows_7_64_not_work.bat и Windows_7_64_work.bat.
Файл Windows_7_64_not_work.bat отрабатывает копирование если вместо переменных указать полный путь из источника в приемник.