Имя пользователя:
Пароль:
 

Показать сообщение отдельно

Ветеран


Сообщения: 27449
Благодарности: 8088

Профиль | Отправить PM | Цитировать


Например, так:
читать дальше »
Код: Выделить весь код
Option Explicit

Dim strSourceFile
Dim objFSO
Dim objTS

Dim lngCount

If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FileExists(strSourceFile) Then
		Set objTS = objFSO.CreateTextFile(strSourceFile & ".export.txt", True)
		
		With objFSO.OpenTextFile(strSourceFile)
			lngCount = 0
			
			Do Until .AtEndOfStream
				lngCount = lngCount + 1
				
				If lngCount = 3 Then
					objTS.WriteLine .ReadLine()
					
					lngCount = 0
				Else
					.SkipLine
				End If
			Loop
			
			.Close
		End With
		
		objTS.Close
		
		Set objTS = Nothing
	Else
		WScript.Echo "Source file [" & strSourceFile & "] not found"
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: " & WScript.ScriptName & " <Source file>"
End If

WScript.Quit
Это сообщение посчитали полезным следующие участники:

Отправлено: 09:08, 04-03-2013 | #2