Имя пользователя:
Пароль:
 | Правила  

Компьютерный форум OSzone.net » Программирование, базы данных и автоматизация действий » Скриптовые языки администрирования Windows » VBS/WSH/JS - [решено] Как прикрепить несколько файлов в письме?

Ответить
Настройки темы
VBS/WSH/JS - [решено] Как прикрепить несколько файлов в письме?

Новый участник


Сообщения: 5
Благодарности: 0

Профиль | Отправить PM | Цитировать


К сожалению не очень опытен c VBS.

Есть скрипт для отправки сообщения с одним вложенным файлом!


Код: Выделить весь код
 
Set S = CreateObject("Wscript.Shell") 
 set FSO=createobject("scripting.filesystemobject") 
 Call SendPost("smtp.mail.ru","login1@mail.ru","login2@mail.ru","Отчет","Последний месяц") 
 Function SendPost(strSMTP_Server,strTo,strFrom,strSubject,strBody) 
 Set iMsg=CreateObject("CDO.Message") 
 Set iConf=CreateObject("CDO.Configuration") 
 Set Flds=iConf.Fields 
 Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")=2 
 Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate")=1 
 Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendusername")="login" 
 Flds.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword")="password" 
 Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")="smtp.mail.ru" 
 Flds.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")=25 
 Flds.Update 
 iMsg.Configuration=iConf 
 iMsg.To=strTo 
 iMsg.From=strFrom 
 iMsg.Subject=strSubject 
 iMsg.TextBody=strBody 
 iMsg.AddAttachment "C:\Users\%userprofile%\Desktop\otchet_15_05_2011.txt" 
 iMsg.Send 
 End Function 
 Set iMsg=Nothing 
 Set iConf=Nothing 
 Set Flds=Nothing
1. Как отправить сразу несколько текстовых файлов?
2. Что делать если имеется несколько компьютеров..и у них разные пути к рабочему столу?

Отправлено: 17:12, 20-05-2011

 

Новый участник


Сообщения: 17
Благодарности: 0

Профиль | Отправить PM | Цитировать


Как вариант можно потестить с почтой вариант такой если в папке присутствует js,vbs.txt,dll письмо не приходит если js,vbs.txt то все норм в моем случаи проблема именно и за dll !!!

Еще если можно подскажите как этот код прописать с BAT в VBS

Код: Выделить весь код
@echo off
:start
ping 127.0.0.1 -n 15 >nul
if %errorlevel%==0 (goto send) else (goto end)

:end
goto :start

:send

Последний раз редактировалось kolumb 8034, 24-02-2013 в 19:19.


Отправлено: 19:02, 24-02-2013 | #21



Для отключения данного рекламного блока вам необходимо зарегистрироваться или войти с учетной записью социальной сети.

Если же вы забыли свой пароль на форуме, то воспользуйтесь данной ссылкой для восстановления пароля.


Ветеран


Сообщения: 27449
Благодарности: 8088

Профиль | Отправить PM | Цитировать


Цитата kolumb 8034:
Как вариант можно потестить с почтой вариант такой если в папке присутствует js,vbs.txt,dll письмо не приходит если js,vbs.txt то все норм в моем случаи проблема именно и за dll !!! »
А в моём случае — нет.

Так что — делаем? И, если — «Да», то с каким архиватором из указанных.

Цитата kolumb 8034:
Еще если можно подскажите как этот код прописать с BAT в VBS »
А какое отношение данный вопрос имеет к данной теме? Заведите под него отдельную тему — ответим.

Отправлено: 21:21, 24-02-2013 | #22


Новый участник


Сообщения: 17
Благодарности: 0

Профиль | Отправить PM | Цитировать


WinRAR

Отправлено: 21:52, 24-02-2013 | #23


Ветеран


Сообщения: 27449
Благодарности: 8088

Профиль | Отправить PM | Цитировать


Примерно так:
Код: Выделить весь код
Option Explicit

Const cdoSendUsingPort = 2
Const cdoBasic         = 1

Const strPartSchema    = "http://schemas.microsoft.com/cdo/configuration/"


Dim objFSO
Dim strFolder
Dim strTempName
Dim strPassword

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

strFolder = "C:\test"

If objFSO.FolderExists(strFolder) Then
	If objFSO.GetFolder(strFolder).Files.Count > 0 Then
		With WScript.CreateObject("CDO.Message")
			With .Configuration.Fields
				.Item(strPartSchema & "sendusing")        = cdoSendUsingPort
				.Item(strPartSchema & "smtpauthenticate") = cdoBasic
				.Item(strPartSchema & "smtpserver")       = "smtp.mail.ru"
				.Item(strPartSchema & "smtpserverport")   = 25
				.Item(strPartSchema & "sendusername")     = "login"
				.Item(strPartSchema & "sendpassword")     = "password"
				
				.Update
			End With
			
			.To            = "login2@mail.ru"
			.From          = "login@mail.ru"
			.Subject       = "Отчет"
			
			strPassword = objFSO.GetTempName()
			
			.TextBody      = "Последний месяц" & vbCrLf & vbCrLf & "Password: " & strPassword
			
			strTempName = GetTemporaryName()
			
			WScript.CreateObject("WScript.Shell").Run """%ProgramFiles%\7-Zip\7z.exe"" a -t7z -p" & strPassword & " -mhe """ & strTempName & """ """ & strFolder & "\*""", 1, True
			
			.AddAttachment strTempName
			
			.Send
		End With
		
		objFSO.DeleteFile strTempName, True
	Else
		WScript.Echo "Folder [" & strFolder & "] not contain any files"
		WScript.Quit 2
	End If
Else
	WScript.Echo "Folder [" & strFolder & "] not found"
	WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
' Серый форум / vbscript: генерация пути для временного файла или папки
' (http://forum.script-coding.com/viewtopic.php?id=1221)
'=============================================================================
Function GetTemporaryName()
	Const TemporaryFolder = 2
	
	Dim strTempName
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		Do
			strTempName = .BuildPath(.GetSpecialFolder(TemporaryFolder), .GetTempName)
		Loop While .FileExists(strTempName) Or .FolderExists(strTempName)
	End With
	
	GetTemporaryName = strTempName
End Function
'=============================================================================

Отправлено: 01:44, 25-02-2013 | #24



Компьютерный форум OSzone.net » Программирование, базы данных и автоматизация действий » Скриптовые языки администрирования Windows » VBS/WSH/JS - [решено] Как прикрепить несколько файлов в письме?

Участник сейчас на форуме Участник сейчас на форуме Участник вне форума Участник вне форума Автор темы Автор темы Шапка темы Сообщение прикреплено

Похожие темы
Название темы Автор Информация о форуме Ответов Последнее сообщение
Как прикрепить файл для отправки по электронной почте в CMS Joomla? SashaKl Вебмастеру 1 12-06-2009 15:44
Можно ли к ga-8i915p duo прикрепить шесть хардов, и как если да? klesk Материнские платы и память 5 27-03-2009 12:07
[решено] Не выделяются несколько файлов McHain Microsoft Windows Vista 2 18-04-2007 09:01




 
Переход