[kotkovets]

использую ${GetParent}, чтобы отсечь Uninstall.exe »

ну и нахрен это делать, если потом по коду дописывается Uninstall.exe... тупо...
Lex_from_Belarus, че за хрень, а не нормальный код..

Код:

IfFileExists $prog\Uninstall.exe 0 +2
 Goto ok

че так не написать, что означает, если есть Uninstall.exe, то пропустить ниже по коду 4 команды, относительно процедуры IfFileExists

Код:

IfFileExists $prog\Uninstall.exe +4
 SetOutPath $INSTDIR
 File /r "${pkgdir}\Program.exe"
 ExecWait "$INSTDIR\Program.exe /S"

Заодно, для отладки кода, проверяется, а какой путь, содержимое переменной: "$0"

Код:

MessageBox MB_OK "$$0 = $0" IDOK

Справку читайте на русском языке, где все расписано..

[Lex_from_Belarus]

IfFileExists $prog\Uninstall.exe +4
ну и как вы себе это представляете?
я же написал что в uninstallstring в реестре хранится путь с фалом, т.е, например c:\program files\program\uninstall.exe.

MessageBox вставляю для проверки везде пишет всё ОК, т.е. и реестр правильно читает и отсекает в пути имя файла, т.е. оставляет просто путь, но вот после ifFileExists идёт дальше а не перескакивает на ОК, как буд-то ifFileExists не срабатывает, т.е. всё остальное проходит, а на ifFileExists косяк.

[MKN]

Возвращаясь к таймеру...
Время исполнения кода можно подсчитывать и таким способом, с помощью функции GetTickCount :

Код:

OutFile "Elapsed Time.exe"

Section
System::Call 'kernel32::GetTickCount(v)i.r0'
; код
Sleep 1200
System::Call 'kernel32::GetTickCount(v)i.r1'
IntOp $0 $1 - $0
	IntOp $1 $0 / 1000
	IntOp $0 $0 % 1000
	IntOp $2 $1 / 60
	IntOp $1 $1 % 60
	IntOp $3 $2 / 60
	IntOp $2 $2 % 60
MessageBox MB_OK "Elapsed Time $3 hours $2 min $1 sec $0 ms"
SectionEnd

Миллисекунды могут "гулять" в мизерном диапазоне...
Вопрос : возможно ли при этом способе визуализировать отсчёт времени в процессе выполнения кода ?

[K.A.V.]

Время исполнения кода можно подсчитывать и таким способом, с помощью функции GetTickCount »

У меня при таком раскладе показывает сколько Windows работает с момента запуска

[profcom]

Вопрос : возможно ли при этом способе визуализировать отсчёт времени в процессе выполнения кода ? »

Для кастомных страниц конечно легко визуализировать или необходимо на стандартных?

У меня при таком раскладе показывает сколько Windows работает с момента запуска »

Так не должно быть, ведь в начале берется время работы windows и потом после паузы снова берется время работы. После чего из второго вычитается первое и преобразовывается в формат часы, минуты, секунды.
У меня так работает с маленьким расхождением в миллисекундах.

[MKN]

Для кастомных страниц конечно легко визуализировать »

Для кастомных. Как это будет выглядеть ?

показывает сколько Windows работает с момента запуска »

Странно...
А если с выделением-очисткой памяти :

Код:

System::Alloc 400 
pop $2 
System::Call 'kernel32::GetTickCount()i .r0' 
System::Free $2

[K.A.V.]

Странно... »

У меня команда была забита в onInit функции (забивал в предыдущий пример с отображением времени в заголовке)
Если в секции с паузой, то всё норм

[profcom]

Для кастомных. Как это будет выглядеть ? »

Ну как то так на мой взгляд, дальше по воображению можно поставить значение куда угодно. Это лишь пример как использовать.

Код:

!include nsDialogs.nsh
OutFile "Time.exe"

Var Stime
Var Ttime
Var DIALOG
Var TEXT

Page custom Time TimeEnd

Function .onInit
System::Call 'kernel32::GetTickCount(v)i.r0'
StrCpy $Stime $0 
FunctionEnd

Function Time
nsDialogs::Create 1018
	Pop $DIALOG
	
	${NSD_CreateLabel} 10u 10u 100% 10u "Прошло $3 часов $2 минут $1 секунд"
	Pop $TEXT
	
	${NSD_CreateTimer} ChekTime 100
	
nsDialogs::Show
FunctionEnd

Function TimeEnd
${NSD_KillTimer} ChekTime
FunctionEnd

Function ChekTime
System::Call 'kernel32::GetTickCount(v)i.r1'
IntOp $0 $1 - $Stime
	IntOp $1 $0 / 1000
	IntOp $0 $0 % 1000
	IntOp $2 $1 / 60
	IntOp $1 $1 % 60
	IntOp $3 $2 / 60
	IntOp $2 $2 % 60
StrCpy $Ttime "Прошло $3 часов $2 минут $1 секунд"

${NSD_SetText} $TEXT "$Ttime"
FunctionEnd

Section
SectionEnd

[profcom]

Вот еще набросал примерчик для стандартной функций установки используя плагин ThreadTimer для создания параллельного потока . В принципе куда угодно можно отобразить время.

Код:

OutFile "Time2.exe"
!include "MUI.nsh"

Var Stime
Var Ttime

!insertmacro MUI_PAGE_INSTFILES

Function .onInit
System::Call 'kernel32::GetTickCount(v)i.r0'
StrCpy $Stime $0 
GetFunctionAddress $1 ChekTime
ThreadTimer::Start 100 -1 $1
FunctionEnd

Section
DetailPrint "Команда 1"
Sleep 10000
DetailPrint "Команда 2"
Sleep 10000
DetailPrint "Команда 3"
Sleep 10000
DetailPrint "Команда 4"
Sleep 10000
ThreadTimer::Stop
SectionEnd

Function ChekTime
System::Call 'kernel32::GetTickCount(v)i.r1'
IntOp $0 $1 - $Stime
	IntOp $1 $0 / 1000
	IntOp $0 $0 % 1000
	IntOp $2 $1 / 60
	IntOp $1 $1 % 60
	IntOp $3 $2 / 60
	IntOp $2 $2 % 60
StrCpy $Ttime "Прошло $3 часов $2 минут $1 секунд"
!insertmacro MUI_HEADER_TEXT "Установка" "$Ttime"
FunctionEnd

[profcom]

Подскажите что я делаю не так. Есть код: »

Правильно вам делали замечания, пишите проще что бы самому не запутаться. И желательно изучите логические конструкции в русском справочнике, пригодиться еще не раз.

Код:

!include LogicLib.nsh

Section "Program"
SectionIn 1
ReadRegStr $0 HKLM "Software\microsoft\windows\currentversion\uninstall\Program" "UninstallString"
ReadRegStr $1 HKLM "Software\wow6432node\microsoft\windows\currentversion\uninstall\Program" "UninstallString"
${IfNot} ${FileExists} "$0"
${AndIfNot} ${FileExists} "$1"
	SetOutPath $INSTDIR
	File /r "${pkgdir}\Program.exe"
	ExecWait "$INSTDIR\Program.exe /S"
${EndIf}
SectionEnd