Цитата MKN:
|
Пытался использовать для этого WS_BORDER и WS_DLGFRAME - без результата.. »
|
Код:
!define WS_BORDER 0x00800000
Function fnc_Create
nsDialogs::Create 1018
Pop $dlg
System::Call 'user32::CreateWindowEx(i0,t "EDIT",t "Текст Текст Текст Текст",\
i${DEFAULT_STYLES}|${WS_VSCROLL}|${ES_MULTILINE}|${ES_WANTRETURN}|${ES_AUTOVSCROLL}|${WS_BORDER},\
i50,i100,i200,i60,i$dlg,i222,i0,i0) i.R2'
SendMessage $dlg ${WM_GETFONT} 0 0 $R9
SendMessage $R2 ${WM_SETFONT} $R9 0
nsDialogs::Show
FunctionEnd
константа
WS_BORDER нигде не объявлена поэтому объявляем..
http://msdn.microsoft.com/ru-ru/libr...(v=vs.85).aspx
константа
DEFAULT_STYLES объявлена в
nsDialogs.nsh, т.е достаточно прописать
!include MUI2.nsh
---
FindWindow $0 "#32770" "" $HWNDPARENT - абсолютно ненужная здесь команда, дескриптор родительского окна в переменной
$dlg
---
Цитата MKN:
|
возможно ли поместить на странице отображение реального времени, т.е. попросту часы ? »
|
вполне... через таймер..
обновление..
к примеру в одну секунду...
читать дальше »
Код:
!include MUI2.nsh
!include "FileFunc.nsh"
Page custom fnc_Create
!insertmacro MUI_LANGUAGE "English"
OutFile "test_time-timer.exe"
Var dlg
!define WS_BORDER 0x00800000
Function fnc_Create
nsDialogs::Create 1018
Pop $dlg
${GetTime} "" "L" $0 $1 $2 $3 $4 $5 $6
System::Call 'user32::CreateWindowEx(i0,t "EDIT",t "$3 $4:$5:$6",\
i${DEFAULT_STYLES}|${WS_VSCROLL}|${ES_MULTILINE}|${ES_WANTRETURN}|${ES_AUTOVSCROLL}|${WS_BORDER},\
i50,i100,i200,i60,i$dlg,i222,i0,i0) i.R2'
SendMessage $dlg ${WM_GETFONT} 0 0 $R9
SendMessage $R2 ${WM_SETFONT} $R9 0
${NSD_CreateTimer} OnTimer 1000
nsDialogs::Show
${NSD_KillTimer} OnTimer
FunctionEnd
Function OnTimer
${GetTime} "" "L" $0 $1 $2 $3 $4 $5 $6
${NSD_SetText} $R2 "$3 $4:$5:$6"
FunctionEnd
Section
SectionEnd
Так как, созданному элементу таким способом присваивается системный шрифт - не очень красиво...
установим элементу шрифт родительского окна, сразу после создания диалога:
Код:
SendMessage $dlg ${WM_GETFONT} 0 0 $R9
SendMessage $R2 ${WM_SETFONT} $R9 0
