Имя пользователя:
Пароль:
 | Правила  

Компьютерный форум OSzone.net » Автоматическая установка Windows » Автоматическая установка приложений » Скрипты Inno Setup. Помощь и советы [часть 5]

Закрытая тема
Настройки темы
Скрипты Inno Setup. Помощь и советы [часть 5]

Аватара для El Sanchez

Ветеран


Contributor


Сообщения: 1274
Благодарности: 1030


Конфигурация

Профиль | Отправить PM | Цитировать


Изменения
Автор: El Sanchez
Дата: 16-02-2015
Внимание! Данная тема предназначена только для обсуждения написания скриптов !
Остальные вопросы, а также последние версии компилятора в теме
Inno Setup. Прочие вопросы.


Показать/скрыть: Справка, руководство, примеры:
Показать/скрыть: Ссылки на примеры скриптов:
Показать/скрыть: Дополнительные программы для Inno Setup:
  • ISTool - неплохой редактор скриптов Inno Setup.
    Последняя версия: 5.3.0.1 [29.09.2009] - Скачать | зеркало;

  • Inno Script Generator - генератор скриптов Inno Setup. Обладает некоторыми полезными функциями, которых нет ни у самого Inno Setup, ни у ISTool.
    Последняя версия: 1.0.3.1 [23.03.2008] - Скачать | зеркало на русифицированную программу;
    Примечание: Родной сайт www.hisoft2000.de более недоступен, поэтому здесь расположены сторонние ссылки.

  • Inno Setup Form Designer - редактор страниц Inno Setup, можно создавать свои страницы.
    Последняя версия: 2.0.8 [12.11.2006] - Скачать;
    Примечание: Родной сайт http://isfd.kaju74.de/index.php?isfd более недоступен, поэтому здесь расположены сторонние ссылки.

  • Inno Setup GameScript Generator - программа генерирует скрипты для Inno Setup . С помощью GameScript Generator и Inno Setup вы сможете быстро создать простенький инсталляционный пакет для любой игры. В инсталлятор можно встроить музыку, слайдшоу и фоновый рисунок. Для специалистов созданный скрипт, возможно, будет неплохой заготовкой для дальнейшей модернизации;

  • ISSkin - Программа для создания и добавления в инсталлятор скинов. Инструкция.
    Последняя версия: 3.0.0.0 [19.01.2010] - Скачать;

  • ISSJoiner - Программа для объединения нескольких скриптов InnoSetup в один.
    Последняя версия: 3.0 [23.07.2009]

  • Converter - Программа конвертирует reg-файлы в формат *.iss (формат скриптов Inno Setup).
    Последняя версия: 0.1.4 [13.03.2010] - Скачать;


Предыдущие ветки обсуждения по ссылкам ниже и в прикреплённых архивах:
Inno Setup [все вопросы] часть 1
Inno Setup [все вопросы] часть 2
Скрипты Inno Setup. Помощь и советы [часть 3]
Скрипты Inno Setup. Помощь и советы [часть 4]

Отправлено: 03:49, 21-05-2012

 

Забанен


Сообщения: 158
Благодарности: 58

Профиль | Цитировать


Цитата woland0789:
Доброго времени суток, подскажите, где найти скрипт, который проверяет при удалении не запущена ли программа, и если да, то убивает этот процесс. »
Вот код
Код: Выделить весь код
[Setup]
AppName=ISTask UnInstall
AppVersion=1.5
DefaultDirName={pf}\ISTask UnInstall
DefaultGroupName=ISTask UnInstall
OutputDir=.
OutputBaseFilename=setupuninstallkill

[Languages]
Name: "russian"; MessagesFile: "compiler:Languages\Russian.isl"

[Files]
Source: ISTask.dll; DestDir: {app}; Flags: ignoreversion

[Code]
function RunTask(FileName: string; bFullpath: Boolean): Boolean;
external 'RunTask@{app}\ISTask.dll stdcall delayload uninstallonly';
function KillTask(ExeFileName: string): Integer;
external 'KillTask@{app}\ISTask.dll stdcall delayload uninstallonly';

procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
begin
  if CurUninstallStep = usUninstall then
  if RunTask('notepad.exe', False) then
    begin
      // прячем форму
      UninstallProgressForm.Visible:= False;
      if MsgBox('Программа Блокнот используется. Закрыть и продолжить удаление?', mbConfirmation, MB_YESNO) = IDYES then
        begin
          KillTask('notepad.exe');
          UnloadDll(ExpandConstant('{app}\ISTask.dll'));
          // показываем форму
          UninstallProgressForm.Visible:= True;
        end
      else
        begin
          MsgBox('Завершите работу Блокнот, затем снова запустите программу удаления.', mbInformation, MB_OK);
          UnloadDll(ExpandConstant('{app}\ISTask.dll'));
          Abort;
        end;
    end;
end;
Это сообщение посчитали полезным следующие участники:

Отправлено: 21:45, 11-11-2012 | #1251



Для отключения данного рекламного блока вам необходимо зарегистрироваться или войти с учетной записью социальной сети.

Если же вы забыли свой пароль на форуме, то воспользуйтесь данной ссылкой для восстановления пароля.


Аватара для Mailchik

Пользователь


Сообщения: 78
Благодарности: 63

Профиль | Отправить PM | Цитировать


nik1967, компилится, но при запуске ошибка.
решение: закоментируйте WizardForm.Brush.Style := bsSolid;. работает, не знаю правильно или нет, так как на юникоде сижу.
Это сообщение посчитали полезным следующие участники:

Отправлено: 22:28, 11-11-2012 | #1252


Аватара для nik1967

Старожил


Сообщения: 440
Благодарности: 251

Профиль | Сайт | Отправить PM | Цитировать


Цитата Mailchik:
компилится, но при запуске ошибка.»
Да, всё так. Неправильно выразился.

-------
Если сообщение оказалось полезным для Вас, то помимо спасибо, можно нажать на "Полезное сообщение".


Отправлено: 23:03, 11-11-2012 | #1253


Новый участник


Сообщения: 1
Благодарности: 0

Профиль | Отправить PM | Цитировать


Устал читать... Просто спрошу.
Инсталлятор распаковывает некоторые файлы и после этого надо установить две софтинки (инсталятора) с ожиданием установки.
Как ?
Пробовал ExecAndWait.iss ни чего не выходит.
И можно ли установить с помощью Inno Setup шрифты?

Последний раз редактировалось alexkush, 12-11-2012 в 18:54.


Отправлено: 18:33, 12-11-2012 | #1254


Аватара для Gnom_aka_Lexander

Ветеран


Сообщения: 978
Благодарности: 564

Профиль | Сайт | Отправить PM | Цитировать


Цитата Johny777:
можно, читай »
Гораздо проще - flags : fontinstall; Этот флаг черт-те знает с какой версии есть. и никакой левой хрени не нужно, когда инно сама может сделать.

-------
Я люблю помогать. Но не путайте: "Помогите мне" и "Сделайте за меня" - это совершенно разные понятия.

Это сообщение посчитали полезным следующие участники:

Отправлено: 22:10, 12-11-2012 | #1255


Аватара для Mailchik

Пользователь


Сообщения: 78
Благодарности: 63

Профиль | Отправить PM | Цитировать


Цитата Johny777:
Как вариант можно нарисовать круг вручную
просто задать координаты круга
но что-то у меня функция CreatePolygonRgn не работает.
в оригинале она такая
function CreatePolygonRgn(const Points; Count, FillMode: Integer): HRGN; stdcall;
где Points это массив TPoint
короче массив координат x, y
заполнить массив можно функцией рисования круга из геометрии
таким макаром можно создавать формы любой формы
из вашего кода звезда получается)
читать дальше »
Код: Выделить весь код
[Setup]
AppName=My Application
AppVersion=1.5
DefaultDirName={pf}\My Application

[Code]
type
  HRGN = LongWord;

const
  WINDING = $2;

function SetWindowRgn(hWnd: HWND; hRgn: HRGN; bRedraw: BOOL): Integer; external 'SetWindowRgn@user32.dll stdcall';
function CreatePolygonRgn(const Points: array of TPoint; Count, FillMode: Integer): HRGN; external 'CreatePolygonRgn@gdi32.dll stdcall';
function DeleteObject(hObject : HRGN): BOOL; external 'DeleteObject@gdi32.dll stdcall';

procedure InitializeWizard;
var
 ap: array of TPoint;
 r: hRGN;
begin
  with WizardForm do
  begin
    SetArrayLength(ap, 5);
    ap[0].x := Width div 2;
    ap[0].y := 0;

    ap[1].x := Width div 3 * 2;
    ap[1].y := Height;

    ap[2].x := 0;
    ap[2].y := Height div 3;

    ap[3].x := Width;
    ap[3].y := Height div 3

    ap[4].x := Width div 3;
    ap[4].y := Height;

    r := CreatePolygonRgn(ap, 5, WINDING);
    try
      SetWindowRgn(WizardForm.Handle, r, TRUE);
    finally
      DeleteObject(r);
    end;
  end;
end;
на юникоде тестил.

Отправлено: 22:25, 12-11-2012 | #1256


Аватара для YURSHAT

Старожил


Сообщения: 163
Благодарности: 78

Профиль | Отправить PM | Цитировать


Цитата Johny777:
юникодной инно не пользуюсь как исправить не знаю »
Скрипт
Код: Выделить весь код
[Setup]
AppName=My Program
AppVerName=My Program v.1.2
DefaultDirName={pf}\My Program

[Code_]
function CreateRoundRectRgn(p1, p2, p3, p4, p5, p6: Integer): THandle; external 'CreateRoundRectRgn@gdi32 stdcall';
function SetWindowRgn(hWnd: HWND; hRgn: THandle; bRedraw: Boolean): Integer; external 'SetWindowRgn@user32 stdcall';

procedure InitializeWizard;
var
  FormRegion: LongWord;
begin
  WizardForm.Height := WizardForm.Width;
  
  FormRegion := CreateRoundRectRgn(1, 1, WizardForm.Width - 1, WizardForm.Height - 1, WizardForm.Width, WizardForm.Height);
  SetWindowRgn(WizardForm.Handle, FormRegion, True);
end;

-------
Если я знаю, что знаю мало, я добьюсь того, чтобы знать больше... В.И. Ленин
Krinkels.org - сжатие данных и создание инсталляторов

Это сообщение посчитали полезным следующие участники:

Отправлено: 04:23, 13-11-2012 | #1257


Аватара для Gnom_aka_Lexander

Ветеран


Сообщения: 978
Благодарности: 564

Профиль | Сайт | Отправить PM | Цитировать


Цитата Mailchik:
из вашего кода звезда получается) »
Дык, раскинь массив на координаты - там звезда и есть

-------
Я люблю помогать. Но не путайте: "Помогите мне" и "Сделайте за меня" - это совершенно разные понятия.


Отправлено: 15:18, 13-11-2012 | #1258


Аватара для ChVL

Старожил


Сообщения: 254
Благодарности: 38

Профиль | Отправить PM | Цитировать


Как прописать путь к папке System32 в Win 7 х64?
Любой способ записи через секцию [Files] приводит к тому, что файлы попадают в папку SysWOW64, а надо именно System32.

Отправлено: 23:54, 13-11-2012 | #1259


Аватара для Johny777

Ветеран


Сообщения: 649
Благодарности: 444

Профиль | Отправить PM | Цитировать


раньше под свои нужды использовал код ...\Inno Setup 5\Scripts\Dobrov\DisksInfoBox.iss
а именно:
читать дальше »
Код: Выделить весь код
[Setup]
AppName=DisksInfo
VersionInfoVersion=5.0
AppVerName=DisksInfo
DefaultDirName={pf}\My program
EnableDirDoesntExistWarning=true

[CustomMessages]
Ru.SysDirSelect=Выбранный путь включает в себя системную папку!%nВы уверены, что необходимо продолжать установку?

[Languages]
Name: Ru; MessagesFile: compiler:Languages\Russian.isl

[Icons]
Name: {group}\Notepad; Filename: notepad.exe

[code]
var n: Integer; FreeMB, TotalMB: Cardinal; VolumeName, FileSystemName: String; VolumeSerialNo, MaxComponentLength, FileSystemFlags: Longint; ListBox: TListBox; StartMenuTreeView: TStartMenuFolderTreeView;

const oneMB= 1024*1024;
function GetLogicalDrives: DWord; external 'GetLogicalDrives@kernel32.dll stdcall';
function GetDriveType(nDrive: String): Longint; external 'GetDriveTypeA@kernel32.dll stdcall';
function GetVolumeInformation(PathName,VolumeName: PChar; VolumeNameSize,VolumeSerialNumber,MaxComponentLength,FileSystemFlags: Longint; FileSystemName: PChar; FileSystemNameSize: Longint): Longint; external 'GetVolumeInformationA@kernel32.dll stdcall';
function MessageBox(hWnd: Integer; lpText, lpCaption: String; uType: Cardinal): Integer; external 'MessageBoxA@user32.dll stdcall';

Function ByteOrTB(Bytes: Extended; noMB: Boolean): String; { Перевод числа в значение бт/Кб/Мб/Гб/Тб (до 3х знаков после запятой)}
Begin
	if not noMB then Result:= FloatToStr(Int(Bytes)) +' Мб' else
		if Bytes < 1024 then Result:= FloatToStr(Int(Bytes)) +' Бт' else
			if Bytes/1024 < 1024 then Result:= FloatToStr(round((Bytes/1024)*10)/10) +' Кб' else
				If Bytes/oneMB < 1024 then Result:= FloatToStr(round(Bytes/oneMB*100)/100) +' Мб' else
					If Bytes/oneMB/1000 < 1024 then Result:= FloatToStr(round(Bytes/oneMB/1024*1000)/1000) +' Гб' else
						Result:= FloatToStr(round(Bytes/oneMB/oneMB*1000)/1000) +' Тб'
	StringChange(Result, ',', '.')
End;

Function DelSP(String: String): String; { Удаление начальных, конечных и повторных пробелов }
	Begin	while (Pos('  ', String) > 0) do Delete(String, Pos('  ', String), 1); Result:= Trim(String); End;

Function CutString(String: String; MaxLength: Longint): String; { Обрезать строку до заданного кол-ва символов}
	Begin
		if Length(String) > MaxLength then Result:= Copy(String, 1, 6) +'...'+ Copy(String, Length(String) - MaxLength +9, MaxLength)
		else Result:= String;
	End;

Procedure GetDiskInfo(Disk: String);
	Begin
		FileSystemName:= StringOfChar(' ', 32); VolumeName:= StringOfChar(' ', 256);
			GetVolumeInformation(Disk, VolumeName, 255, VolumeSerialNo, MaxComponentLength, FileSystemFlags, FileSystemName, 31);
		FileSystemName:= DelSp(FileSystemName); VolumeName:= DelSp(VolumeName); if VolumeName='' then VolumeName:='без метки';
	End;

Procedure ListBoxRefresh;	var FreeB, TotalB: Cardinal; Path, String: string; Begin
	ListBox.Items.Clear
for n:= 1 to 31 do	// диск 'А' пропустить
	if (GetLogicalDrives and (1 shl n)) > 0 then
		if (GetDriveType(Chr(ord('A') + n) +':\') = 2) or (GetDriveType(Chr(ord('A') + n) +':\') = 3) then
			if GetSpaceOnDisk(Chr(ord('A') + n) +':\', True, FreeMB, TotalMB) then ListBox.Items.Add(Chr(ord('A') + n) +':');
for n:= 0 to ListBox.Items.Count -1 do begin
	Path:= Copy(ListBox.Items[n],1,2) +'\'		{ если в накопителе нет диска, пропустить обновление }
	if GetSpaceOnDisk(Path, False, FreeB, TotalB) and GetSpaceOnDisk(Path, True, FreeMB, TotalMB) then begin GetDiskInfo(Path);
		if FreeB >= $7FFFFFFF then String:= PadL(ByteOrTB(FreeMB*oneMB, true),10) else String:= PadL(ByteOrTB(FreeB, true),10);
		if TotalB >= $7FFFFFFF then begin TotalB:= TotalMB; FreeB:= FreeMB; String:= PadL(ByteOrTB(TotalMB*oneMB, true),11) +' всего| '+ String end else String:= PadL(ByteOrTB(TotalB, true),11) +' всего| '+ String;
	ListBox.Items[n]:= Copy(Path,1,2) + String + PadL(FloatToStr(round(FreeB/TotalB*100)),3)+ '% своб|'+ PadL(FileSystemName,5)+ '| '+ CutString(VolumeName,9); end; end;
End;

Procedure ObjectOnClick(Sender: TObject); Begin
Case TObject(Sender) of
	ListBox:	for n:= 0 to ListBox.Items.Count-1 do if ListBox.Selected[n] then WizardForm.DirEdit.Text:= Copy(ListBox.Items[n],1,1) +Copy(WizardForm.DirEdit.Text, 2, Length(WizardForm.DirEdit.Text))
	StartMenuTreeView:	if StartMenuTreeView.Directory <> '' then WizardForm.GroupEdit.Text:= StartMenuTreeView.Directory else WizardForm.GroupEdit.Text:= '{#SetupSetting("DefaultGroupName")}'
	WizardForm.NoIconsCheck:	begin WizardForm.GroupEdit.Enabled:= not(WizardForm.GroupEdit.Enabled); StartMenuTreeView.Enabled:= WizardForm.GroupEdit.Enabled; WizardForm.GroupBrowseButton.Enabled:= WizardForm.GroupEdit.Enabled end;
end; End;

Function NextButtonClick(CurPageID: Integer): Boolean; Begin
	Result:= True
	if (CurPageID = wpSelectDir) and (Pos(Uppercase(ExpandConstant('{win}')), Uppercase(ExpandConstant('{app}'))) > 0) then Result:= MessageBox(StrToInt(ExpandConstant('{wizardhwnd}')), ExpandConstant('{cm:SysDirSelect}'), 'Установка в системную папку', MB_YESNO or $30) = idYes;
End;

Procedure CurPageChanged(CurPageID: Integer);
Begin
	if CurPageID = wpSelectDir then ListBoxRefresh
End;

Procedure InitializeWizard;
Begin
	ListBox:= TListBox.Create(WizardForm)
		ListBox.SetBounds(WizardForm.DirEdit.Left, WizardForm.DirEdit.Top + WizardForm.DirEdit.Height + 8, WizardForm.DirBrowseButton.Left + WizardForm.DirBrowseButton.Width - WizardForm.DirEdit.Left, WizardForm.DiskSpaceLabel.Top - (WizardForm.DirEdit.Top + WizardForm.DirEdit.Height + 12))
		ListBox.Font.Size:= 9
		ListBox.Font.Style:= [fsBold]
		ListBox.Font.Name:= 'Courier New';
		ListBox.OnClick:= @ObjectOnClick;
		ListBox.Parent:= WizardForm.SelectDirPage;
	WizardForm.NoIconsCheck.SetBounds(WizardForm.DiskSpaceLabel.Left + 96, WizardForm.DiskSpaceLabel.Top + 1, WizardForm.NoIconsCheck.Width, WizardForm.NoIconsCheck.Height)
		WizardForm.NoIconsCheck.OnClick:= @ObjectOnClick
		WizardForm.NoIconsCheck.Parent:= WizardForm.SelectProgramGroupPage
		WizardForm.NoIconsCheck.Show
	StartMenuTreeView:= TStartMenuFolderTreeView.Create(WizardForm)
		StartMenuTreeView.SetPaths(ExpandConstant('{userprograms}'), ExpandConstant('{commonprograms}'), ExpandConstant('{userstartup}'), ExpandConstant('{commonstartup}'));
		StartMenuTreeView.SetBounds(ListBox.Left, ListBox.Top, ListBox.Width, ListBox.Height)
		StartMenuTreeView.Parent:= WizardForm.SelectProgramGroupPage
		StartMenuTreeView.Cursor:= crHand
		StartMenuTreeView.OnChange:=@ObjectOnClick
End;

но вот намутил свою версию (пол дня убил на код). В отличии от кода выше мой код работает на юникодной инно, но почему-то на ней криво определяет размер и свободное пространство хардов. На ANSI всё в порядке

Добрые люди, у меня 3 просьбы:
1: Поздравить меня
2: Проверить код (да да как в школе училка проверяла) и по возможности исправить/улучшить
3: хоть оно мне и не нужно, но если получится исправить косяк с юникодной инно, то скрипт может пригодиться ещё кое-кому (хотя там при желании можно заюзать родной GetSpaceOnDisk)

вот ранняя версия (только заполнение листбокса):
читать дальше »
Код: Выделить весь код
[Setup]
AppName=My Program
AppVerName=My Program v.1.2
DefaultDirName={pf}\My Program

[code]
#ifdef UNICODE
    #define A "W"
#else
    #define A "A"
#endif
type
  PDWORD = DWORD;
  
const
  DRIVE_REMOVABLE = $2;
  DRIVE_FIXED = $3;
  DRIVE_REMOTE = $4;
  DRIVE_CDROM = $5;
  DRIVE_RAMDISK = $6;
  MAX_PATH = 260;
    
function StrFormatByteSize64(qdw: Currency; var pszBuf: Char; cchBuf: UINT): PAnsiChar; external 'StrFormatByteSize64A@shlwapi.dll stdcall';
function GetVolumeInformation(lpRootPathName: String; lpVolumeNameBuffer: String; nVolumeNameSize: DWORD; lpVolumeSerialNumber: PDWORD; var lpMaximumComponentLength, lpFileSystemFlags: DWORD; lpFileSystemNameBuffer: String; nFileSystemNameSize: DWORD): BOOL; external 'GetVolumeInformation{#A}@kernel32.dll stdcall';
function GetDriveType(lpRootPathName: String): UINT; external 'GetDriveType{#A}@kernel32.dll stdcall';
function GetDiskFreeSpace(lpRootPathName: String; var lpSectorsPerCluster, lpBytesPerSector, lpNumberOfFreeClusters, lpTotalNumberOfClusters: DWORD): BOOL; external 'GetDiskFreeSpace{#A}@kernel32.dll stdcall';
//function GetLogicalDriveStrings(nBufferLength: DWORD; lpBuffer: String): DWORD; external 'GetLogicalDriveStrings{#A}@kernel32.dll stdcall';


function BytesToSize(Bytes: Extended): String;
var
    pszBuf: array [0..15] of Char;
begin
    try
        Result := StrFormatByteSize64(Abs(Bytes div 1E4), pszBuf[0], sizeof(pszBuf));
    except end;
end;

function GetDrivesInfo: array of string;
var
  i: Integer;
  UndefDriveLetter: String;
  DriveType: UINT;
  DriveSpecFullString: String;
  DrivePath: string;
  VolumeName, FileSystemName : string;
  ComponentLength, SerialNumber, FileSystemFlags: DWORD;
  Sec_Cluster, Bytes_Sec, Free_Clusters, Total_Clusters : DWORD;
begin
  for i := 65 to 90 do // Loop from A..Z to determine available drives
  begin
    UndefDriveLetter := chr(i) + ':\';
    DriveType := GetDriveType(UndefDriveLetter);
    case DriveType of
//      0: DriveSpecFullString := UndefDriveLetter + ' Тип накопителя не может быть определен.';
//      1: DriveSpecFullString := UndefDriveLetter + ' Корневая директория не существует.';
      DRIVE_REMOVABLE:
      begin
        VolumeName := StringOfChar(#32, MAX_PATH);
        FileSystemName := StringOfChar(#32, MAX_PATH);
        GetVolumeInformation(UndefDriveLetter, VolumeName, MAX_PATH, SerialNumber, ComponentLength, FileSystemFlags, FileSystemName, MAX_PATH);
        GetDiskFreeSpace(UndefDriveLetter, Sec_Cluster, Bytes_Sec, Free_Clusters, Total_Clusters);
        if Trim(VolumeName) = '' then VolumeName := 'Без имени';
        DriveSpecFullString :=
          'Внешний диск: ' + UndefDriveLetter + ' // ' +
          'Имя: ' + Trim(VolumeName) + ' // ' +
          'Файловая система: ' + Trim(FileSystemName) + ' // ' +
          'Общий размер: ' + BytesToSize(Bytes_Sec * Sec_Cluster * Total_Clusters) + ' // ' +
          'Доступно: ' + BytesToSize(Bytes_Sec * Sec_Cluster * Free_Clusters);
        SetArrayLength(Result, GetArrayLength(Result)+1);
        Result[GetArrayLength(Result)-1] := DriveSpecFullString;
      end;
      DRIVE_FIXED:                                          
      begin
        VolumeName := StringOfChar(#32, MAX_PATH);
        FileSystemName := StringOfChar(#32, MAX_PATH);
        GetVolumeInformation(UndefDriveLetter, VolumeName, MAX_PATH, SerialNumber, ComponentLength, FileSystemFlags, FileSystemName, MAX_PATH);
        GetDiskFreeSpace(UndefDriveLetter, Sec_Cluster, Bytes_Sec, Free_Clusters, Total_Clusters);
        if Trim(VolumeName) = '' then VolumeName := 'Без имени';
        DriveSpecFullString := 
          'Внутренний диск: ' + UndefDriveLetter + ' // ' +
          'Имя: ' + Trim(VolumeName) + ' // ' +
          'Файловая система: ' + Trim(FileSystemName) + ' // ' +
          'Общий размер: ' + BytesToSize(Bytes_Sec * Sec_Cluster * Total_Clusters) + ' // ' +
          'Доступно: ' + BytesToSize(Bytes_Sec * Sec_Cluster * Free_Clusters);
        SetArrayLength(Result, GetArrayLength(Result)+1);
        Result[GetArrayLength(Result)-1] := DriveSpecFullString;
      end;
//      DRIVE_REMOTE: DriveSpecFullString := UndefDriveLetter+ ' Удаленный (сетевой) диск: ';
//      DRIVE_CDROM: DriveSpecFullString := UndefDriveLetter + ' Устройство - CD-ROM: ';
//      DRIVE_RAMDISK: DriveSpecFullString := UndefDriveLetter + ' Устройство - RAM диск: ';
    end;
  end;
end;


procedure InitializeWizard;
var
  ReadyArray: array of string;
  DriveListBox: TListBox;
  i: Integer;
begin
  ReadyArray := GetDrivesInfo;
  WizardForm.OuterNotebook.Hide;
  WizardForm.Width := 600;
  DriveListBox := TListBox.Create(nil)
  with DriveListBox do
  begin
    Parent := WizardForm;
    SetBounds(0, 0, WizardForm.Width, WizardForm.Height - 100);
    for i := 0 to GetArrayLength(ReadyArray)-1 do Items.Add(ReadyArray[i]);
  end;
end;


PS: и меня смущает как я поступил с указателем
Код: Выделить весь код
 
type
  PDWORD = DWORD;
Это сообщение посчитали полезным следующие участники:

Отправлено: 02:51, 14-11-2012 | #1260



Компьютерный форум OSzone.net » Автоматическая установка Windows » Автоматическая установка приложений » Скрипты Inno Setup. Помощь и советы [часть 5]

Участник сейчас на форуме Участник сейчас на форуме Участник вне форума Участник вне форума Автор темы Автор темы Шапка темы Сообщение прикреплено

Похожие темы
Название темы Автор Информация о форуме Ответов Последнее сообщение
Скрипты Inno Setup. Помощь и советы [часть 4] El Sanchez Автоматическая установка приложений 2099 22-05-2012 23:16
Скрипты Inno Setup. Помощь и советы [часть 3] Serega Автоматическая установка приложений 3755 26-10-2011 17:58
[архив] Скрипты Inno Setup. Помощь и советы [часть 2] Serega Автоматическая установка приложений 2651 08-11-2010 18:34
Скрипты Inno Setup Compiler QAZAK Автоматическая установка приложений 7 15-01-2007 17:59
Inno Setup tradeukraine Вебмастеру 3 13-06-2006 20:39




 
Переход