[Iska]

Алексей_Мокшанов@vk, поместите следующий код:

читать дальше »

Код:

Option Explicit

Dim objDictionary
Dim objFSO
Dim objWshShell

Dim strPath2DefSound


Set objDictionary = WScript.CreateObject("Scripting.Dictionary")
Set objFSO        = WScript.CreateObject("Scripting.FileSystemObject")
Set objWshShell   = WScript.CreateObject("WScript.Shell")

With objDictionary
	.Add 0, "C:\Мои иконки\Icon0.ico"
	.Add 1, "C:\Мои иконки\Icon1.ico"
End With

strPath2DefSound = objFSO.BuildPath(objFSO.GetParentFolderName(WScript.ScriptFullName), "DefSound-x32.exe")

If objFSO.FileExists(strPath2DefSound) Then
	If WScript.Arguments.Count = 1 Then
		Select Case WScript.Arguments.Item(0)
			Case "0", "1"
				objWshShell.Run """" & strPath2DefSound & """ " & WScript.Arguments.Item(0), 0, True
				CreateShortcutOnDesktop Abs(Not CBool(WScript.Arguments.Item(0)))
			Case Else
				CreateShortcutOnDesktop 0
		End Select
	Else
		CreateShortcutOnDesktop 0
	End If
Else
	WScript.Echo "Can't find [" & strPath2DefSound & "]"
End If

Set objWshShell   = Nothing
Set objFSO        = Nothing
Set objDictionary = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub CreateShortcutOnDesktop(lngArgument)
	With objWshShell.CreateShortcut(objFSO.BuildPath(objWshShell.SpecialFolders("Desktop"), objFSO.GetBaseName(WScript.ScriptName) & ".lnk"))
		.TargetPath       = WScript.ScriptFullName
		.WorkingDirectory = objFSO.GetParentFolderName(WScript.ScriptFullName)
		.Arguments        = CStr(lngArgument)
		
		.WindowStyle      = 0
		'.Hotkey           = "CTRL+SHIFT+S"
		.IconLocation     = objDictionary.Item(lngArgument)
		.Description      = "Shortcut to quick change default sound"
		
		.Save
	End With
End Sub
'=============================================================================

в файл с расширением «.vbs», заменив пути к файлам иконок на Ваши собственные. Поместите этот файл в любое потребное место. Поместите рядом с этим файлом файл «DefSound-x32.exe» (работа с утилитой основана на этой статье: EreTIk's Box » Утилиты » DefSound: установка аудио устройства по умолчанию). В случае ОС соответствующей разрядности, используйте «DefSound-x64.exe», одновременно заменив и в скрипте имя исполняемого файла на «DefSound-x64.exe» (я не стал усложнять скрипт определением разрядности ОС и выбором соответствующего исполняемого файла).

Cозданный скрипт *.vbs при первом своём запуске создаст на Рабочем столе текущего пользователя одноимённый себе ярлык. Далее Вы можете просто пользоваться созданным ярлыком.