[Iska]

Некоторые пути «жёстко» прописаны:

Код:

command.0          = Z:\Repack_RSW\WIHU\SOFT\ARHIVATOR\7zip\7z920.RePack.AIO.exe -gm2
…
command.1          = F:\WIHU\SOFT\INFO\Kulinar.exe /s

А с другими:

Код:

command.1          = FSOFT\PLAYERS\MPC-HomeCinema.1.5.2.3456.x86.exe /VERYSILENT
…
command.2          = WIHU\SOFT\INTERNET\MailRuAgent\Mail.RU Agent 6.0.5831.exe /VERYSILENT
…
command.4          = WIHU\SOFT\INTERNET\utorrent\utorrent.exe

— описки?

Пробуйте так:

читать дальше »

Код:

Option Explicit

Dim strIniFile

Dim objRegExp

Dim arrLines
Dim strLine
Dim strPath


If WScript.Arguments.Count = 1 Then
	strIniFile = WScript.Arguments.Item(0)
	
	Set objRegExp = WScript.CreateObject("VBScript.RegExp")
	
	With objRegExp
		.IgnoreCase = True
		.Pattern    = "^\s*command(?:\.\d+){1,2}\s*=\s*(.*(?:msi|exe))\s*.*$"
	End With
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		With .OpenTextFile(strIniFile)
			arrLines = Split(.ReadAll(), vbCrLf)
			.Close
		End With
		
		For Each strLine In arrLines
			If objRegExp.Test(strLine) Then
				strPath = .BuildPath(.GetParentFolderName(.GetParentFolderName(.GetAbsolutePathName(strIniFile))), objRegExp.Execute(strLine).Item(0).Submatches(0))
				
				If Not .FileExists(strPath) Then
					WScript.Echo strLine
				End If
			End If
		Next
	End With
	
	Set objRegExp = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo " & WScript.ScriptName & " <inifile>"
End If

WScript.Quit 0