[Iska]

sweetpleasure, WSH Вам подойдёт?

[Anonymоus]

Например, как-то так:

Код:

@Echo Off
SetLocal EnableDelayedExpansion

Set File1=source1.txt
Set File2=source2.txt
Set TargetLine=4
Set Output=out.txt

Set i=0
For /F "usebackq delims=" %%A In ("%File1%") Do (
	Set /A i+=1
	Echo.%%A>>"%Output%"
	If !i!==%TargetLine% (
		For /F "usebackq delims=" %%A In ("%File2%") Do (Echo.%%A>>"%Output%")
	)
)

После четвертой строки первого файла вставится построчно содержимое второго файла, а после - остаток первого. Недостатки - циклом For игнорируются пустые строки, из-за EnableDelayedExpansion игнорируются все восклицательные знаки в тексте.

[sweetpleasure]

После четвертой строки первого файла вставится построчно содержимое второго файла, а после - остаток первого. Недостатки - циклом For игнорируются пустые строки, из-за EnableDelayedExpansion игнорируются все восклицательные знаки в тексте.»

ой нет, восклицательные знаки там обязательны.

WSH Вам подойдёт? »

Подойдёт)

Я просто думала, что на ssed так же просто, как и удалить, можно вставить текст.

[Iska]

Я просто думала, что на ssed так же просто, как и удалить, можно вставить текст. »

Может быть. Я с ним не работал.

Подойдёт) »

Попробуйте так:

читать дальше »

Код:

Option Explicit

Dim strSourceFile
Dim strDestFile
Dim lngInsertPosition

Dim objFSO

Dim strSourceContent
Dim strDestContent

Dim strTempFile
Dim strBackupFile

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

If WScript.Arguments.Count <> 3 Then
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source file> <Destination file> <Line number for insert>"
	WScript.Quit 1
End If

With objFSO
	strSourceFile = WScript.Arguments.Item(0)
	
	If Not .FileExists(strSourceFile) Then
		WScript.Echo "Source file [" & strSourceFile & "] not found."
		WScript.Quit 2
	End If
	
	strDestFile = WScript.Arguments.Item(1)
	
	If Not .FileExists(strDestFile) Then
		WScript.Echo "Destination file [" & strDestFile & "] not found."
		WScript.Quit 3
	End If
	
	If Not IsNumeric(WScript.Arguments.Item(2)) Then
		WScript.Echo "Line number must be a numeric value."
		WScript.Quit 4
	End If
	
	lngInsertPosition = CLng(WScript.Arguments.Item(2))
	
	If lngInsertPosition < 0 Then
		WScript.Echo "Line number can't be less than zero."
		WScript.Quit 5
	End If
	
	With .OpenTextFile(strSourceFile)
		strSourceContent = .ReadAll()
		.Close
	End With
	
	With .OpenTextFile(strDestFile)
		strDestContent = ""
		
		Do Until .AtEndOfStream
			If .Line <> lngInsertPosition Then
				strDestContent = strDestContent & .ReadLine() & vbCrLf
			Else
				strDestContent = strDestContent & strSourceContent & .ReadLine() & vbCrLf
			End If
		Loop
		
		.Close
	End With
	
	strTempFile = GetTemporaryName()
	
	With .CreateTextFile(strTempFile)
		.Write strDestContent
		.Close
	End With
	
	strBackupFile = .BuildPath(.GetParentFolderName(strDestFile), .GetBaseName(strDestFile) & ".bak")
	
	If .FileExists(strBackupFile) Then
		.DeleteFile strBackupFile
	End If
	
	.MoveFile strDestFile, strBackupFile
	.CopyFile strTempFile, strDestFile
	.DeleteFile strTempFile
End With

WScript.Quit
'=============================================================================

'=============================================================================
' Серый форум / vbscript: генерация пути для временного файла или папки
' (http://forum.script-coding.com/viewtopic.php?id=1221)
'=============================================================================
Function GetTemporaryName()
	Const TemporaryFolder = 2
	
	Dim strTempName
	
	With WScript.CreateObject("Scripting.FileSystemObject")
		Do
			strTempName = .BuildPath(.GetSpecialFolder(TemporaryFolder), .GetTempName)
		Loop While .FileExists(strTempName) Or .FolderExists(strTempName)
	End With
	
	GetTemporaryName = strTempName
End Function
'=============================================================================

[sweetpleasure]

А где можно задать номер строки, с которой начинать, а также файл с которого берём и куда вставляем?
Я образно сказала с 4... а так таких вставок будет несколько. Я просто продублирую скрипт.

Если я правильно поняла, то вот эта строка

Код:

WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source file> <Destination file> <Line number for insert>"

А в каком формате туда вставлять?

Так?

Код:

WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ "D:\compilation\template\Web Site\put.xml" "D:\compilation\template\Web Site\output.xml" 4"

[Iska]

Запускаете командную строку, в ней пишете:

Код:

cscript.exe //nologo "<Путь\SomeScript.vbs" "Путь\Файл, содержимое которого надо вставить.xml>" "<Путь\Файл, в который надо вставить содержимое первого файла.xml>" <Номер строки, начиная с которой будет вставлено содержимое первого файла>

Например:

Код:

cscript.exe //nologo "c:\My Scripts\SomeScript.vbs" "C:\Песочница\0009\Source.xml" "C:\Песочница\0009\Destination.xml" 4

Для текущего каталога пути, разумеется, можно опускать.

P.S. Пример рассчитан на одну вставку за раз.

[sweetpleasure]

Огромное спасибо!
А можно же вставлять в середину bat?
т.е. выполняется bat, доходит до строки

Код:

cscript.exe //nologo "c:\My Scripts\SomeScript.vbs" "C:\Песочница\0009\Source.xml" "C:\Песочница\0009\Destination.xml" 4

останавливается, выполняет скрипт, а после продолжает выполняться bat. Так ведь будет работать?

[Iska]

sweetpleasure, можно. Работать будет.

[sweetpleasure]

Всё отлично работает!
Я хотела бы ещё уточнить, возможно ли запустить bat, перетащив на него файл (drag and drop)?

Я использую

Код:

7z x *.zip -oD:\compilation\template

он работает, когда только файл zip рядом с bat-файлом...конечно можно прописать путь и тогда он начнёт работать из прописанной директории и при этом будет распаковывать все zip в этой директории. Можно прописать название zip, но архивы имеют разные имена.

Пробовала даже в Bat To Exe Converter делать exe, но всё равно не получается перетаскиванием нужного файла на ярлык запустить его обработку.

Если я верно понимаю, то нужно вместо * вставить какое-то значение, которое будет передаваться при перетаскивании объекта.

Нашла вот такой код, но не знаю насколько он эффективен

Код:

Suddenly the drag-drop has stopped working. How to fix this problem?

Click Start, Run and type these commands:

    cmd /c ftype batfile="%1" %*
    cmd /c assoc .bat=batfile
    regsvr32 /i shell32.dll

не решилась экспериментировать с shell32.dll