[Iska]

В чём смысл попытки одновременного использования параметров «/s» и «/e»?

Copter, Вам, пожалуй, подойдёт код на AutoIt:

читать дальше »

Код:

AutoItSetOption("MustDeclareVars", 1)

Local $sSourceFolder = "\\server\programka"
Local $sDestFolder   = "c:\Program Files\programka"
; Local $sSourceFolder = "E:\Песочница\0131\Source"
; Local $sDestFolder   = "E:\Песочница\0131\Dest"

Local $bErrorCode = 0


OnAutoItExitRegister("OnExit")

BlockInput(1)

If FileExists($sSourceFolder) Then
	SplashTextOn("Обновление приложения «Programka»", "Идёт процесс обновления приложения «Programka»…", 480, 36, -1, -1, -1, "", 8)

	If DirCopy($sSourceFolder, $sDestFolder, 1) = 1 Then
		SplashTextOn("Обновление приложения «Programka»", "Обновление приложения «Programka» завершено.", 480, 36, -1, -1, -1, "", 8)
		Sleep(2000)
	Else
		ConsoleWriteError("There is an error while copying the source folder [" & $sSourceFolder & "] in destination folder [" & $sDestFolder & "]" & @CRLF)
		$bErrorCode = 2
	EndIf

	SplashOff()
Else
	ConsoleWriteError("Can't find source folder [" & $sSourceFolder & "]" & @CRLF)
	$bErrorCode = 1
EndIf

Exit($bErrorCode)

Func OnExit()
    BlockInput(0)
EndFunc

Проверять, запущено ли в этот момент само приложение «Programka», и завершать его, при необходимости — Вы не планировали?