[Iska]

1. UTF-8 »

Скорее UTF-16LE. В UTF-8 ни разу не приходилось встречать файлы реестра.

Как-то так:

читать дальше »

Код:

Option Explicit

Const ForReading   = 1
Const ForWriting   = 2
Const TristateTrue = -1

Dim strSID
Dim strContent
Dim strTempFile

strSID = WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\cimv2" _
	).Get("Win32_UserAccount.Domain='DomainOrMachineName',Name='UserName'").SID

With WScript.CreateObject("Scripting.FileSystemObject")
	With .OpenTextFile("C:\Песочница\0002\Console2.reg", ForReading, False, TristateTrue)
		strContent = .ReadAll()
		.Close
	End With
	
	strTempFile = GetTemporaryName()
	
	With .OpenTextFile(strTempFile, ForWriting, True, TristateTrue)
		.Write Replace(strContent, "HKEY_CURRENT_USER", "HKEY_USERS\" & strSID)
		.Close
	End With
	
	With WScript.CreateObject("WScript.Shell")
		.Run "regedit.exe /s """ & strTempFile & """", 0, True
	End With
	
	.DeleteFile strTempFile, True
End With

WScript.Quit 0
'=============================================================================

'=============================================================================
' Серый форум / vbscript: генерация пути для временного файла или папки
' (http://forum.script-coding.com/viewtopic.php?id=1221)
'=============================================================================
Function GetTemporaryName()
    Const TemporaryFolder = 2
    
    Dim strTempName
    
    With WScript.CreateObject("Scripting.FileSystemObject")
        Do
            strTempName = .BuildPath(.GetSpecialFolder(TemporaryFolder), .GetTempName)
        Loop While .FileExists(strTempName) Or .FolderExists(strTempName)
    End With
    
    GetTemporaryName = strTempName
End Function
'=============================================================================

1. Откуда Вы будете брать «Domain\UserName»?
2. Какова Ваша конечная цель всего действа?