[AlterEgoFS]

simon171078,

Код:

for %%i in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist %%i:\file set flash=%%i:

где file это папка/файл, лежащий только на этой флешке и нигде больше. используется для идентификации. я например создал в корне флешки пустой файл "flashdrive", у меня скрипт выглядит так

Код:

for %%i in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do if exist %%i:\flashdrive set flash=%%i:

можешь прям это и использовать. а дальше в батнике, используя новую переменную %flash%, делаешь что надо. взято из дистрибутива zverdvd )

пысы:если при использовании батника вылезет сообщение сообщение с тремя кнопками и у вас есть картридер встроенный, то тыкаем пропустить и всё. у меня так и было. батник натыкается на включенную флешку но физически она не подключена, хоть и висит в "моём компьютере" как подключенная. пропускать и всё

[megaloman]

Вот еще вариант. Идея решения - запускаем vbs-скрипт, который определяет сменные накопители в состоянии готовности в системе и запускает батник, для которого параметр - буква: сменного диска.
В VBS-скрипте я организовал подтверждение на выбор сменного диска (на случай, если их несколько)
Попутно выдаю информацию: метка тома, серийный номер, свободное место.
Если задача ставится - выбрать первый попавшийся накопитель, можно упростить скрипт (удалится более половины строк), чтобы он ничего не спрашивал.

Код:

' Скрипт находит сменные накопители на компьютере (кроме A:)
' Выдаёт диалог на выбор конкретного
' Запускает указанный батник с параметром - именем (путём) диска

Bat = "Batnik.bat"      '- батник, который запускаетcя скриптом
			'- если батник не рядом со скриптом-указать полный путь

Set WS = CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")
Set Disks = FSO.Drives

L = True
For Each Disk In Disks
    DPath = Disk.Path
    If Disk.DriveType = 1 And Disk.IsReady And UCase(DPath) <> "A:" Then
        Msg = "Сменный носитель  " + Disk.Path
        Msg = Msg + vbCrLf + vbCrLf + "Метка носителя:    " + Disk.VolumeName
        Msg = Msg + vbCrLf + "Серийный номер:    " + CStr(Disk.SerialNumber)
        Msg = Msg + vbCrLf + vbCrLf + "Свободное место:  " + CStr(Round(Disk.FreeSpace / 1024 / 1024, 1)) + " Mb"
        Msg = Msg + vbCrLf + vbCrLf + "Вы будете работать с этим носителем?"
        Ans = MsgBox(Msg, 35, "Выбор сменного носителя")
        If Ans = 2 Then Exit For
        If Ans = 6 Then
            L = False
            Ret = WS.Run("cmd /c " + Bat + " " + DPath, 1, False)
            Exit For
        End If
    End If
Next
If L Then MsgBox "Ни одного сменного носителя не выбрано"

Для примера использовал батник с именем Batnik.bat

Код:

@Echo Off
Echo %1
Pause

В прикреплённом файле - скрипт и пример батника

[sov44]

А как насчёт моего вопроса в формате cmd?

[megaloman]

sov44, Попробуйте вариант: Запускайте vbs-скрипт, он опросит имеющие сменные диски в состоянии готовности, запомнит их (если они есть), выдаст приглашение на подключение флэшки, определит появившуюся букву, запустит указанный Вами батник с параметром -буква диска: Пример батника в моём предыдущем посте

Код:

' Скрипт находит сменные накопители на компьютере (кроме A:)
' Выдаёт запрос на подключение нового, после подключения - опред его букву
' Запускает указанный батник с параметром - именем (путём) диска

Bat = "Batnik.bat"      '- батник, который запускаетcя скриптом
                        '- если батник не рядом со скриптом-указать полный путь

Set WS = CreateObject("WScript.Shell")
Set FSO = CreateObject("Scripting.FileSystemObject")
Set Disks = FSO.Drives

iOld = ""
For Each Disk In Disks
    DPath = UCase(Disk.Path)
    If Disk.DriveType = 1 And Disk.IsReady And DPath <> "A:" Then iOld = iOld + UCase(Disk.DriveLetter)
Next
        
L = True
Do While L
    Ans = MsgBox("Вставьте сменный носитель", 49)
    If Ans = 2 Then Exit Do
    If Ans = 1 Then
        Set Disks = FSO.Drives
        For Each Disk In Disks
            DPath = UCase(Disk.Path)
            If Disk.DriveType = 1 And Disk.IsReady And DPath <> "A:" Then
                If InStr(1, iOld, UCase(Disk.DriveLetter), 1) = 0 Then
                    L = False
                    Ret = WS.Run("cmd /c " + Bat + " " + DPath, 1, False)
                    Exit For
                End If
            End If
        Next
    End If
Loop

[Foreigner]

сложность такая узнать какая буква будет у usb брелка »

Букву можно определить так:

Код:

wmic logicaldisk where drivetype=2 get deviceid