[Devils0411]

Доработал код, но есть одно "но":

Код:

@Echo off
SetLocal enabledelayedexpansion
if exist "%ProgramFiles(x86)%" (set bit=x64) else (set bit=x86)
Title Поиск отсутствующих обновлений для Windows %bit%
wmic qfe get HotFixID >temp.txt
.\iconv\iconv -c -f UTF-16LE -t CP866 temp.txt > CheckUpdates.txt
del /S /Q temp.txt >nul
for /f "Tokens=1 Delims=" %%a in ('FindStr /IB "KB" "CheckUpdates.txt"') do Call :files %%a
goto :EOF

:files
For /F "Tokens=2 Delims=-" %%b in ('Dir /B ".\%bit%\*.msu"') Do Call :matching %1 %%b

:matching
if "%1"=="%2" (echo Обновление %1 присутствует в папке %~dp0%bit%>>%~n0.log) 
if "%2"=="" (echo Обновление %1 отсутствует в папке %~dp0%bit%>>%~n0.log)

При %%a==%%b, должно происходить следующее сравнение значения переменной %%a с множеством значений переменной %%b, а получается так, что даже когда переменные %%a, и %%b равны, то сравнение %%a идет до тех пор, пока значения %%b не закончатся, и тогда выполняется условие ""=="".

[Devils0411]

Что-то ни как не получается довести до ума. Может кто подскажет, где ошибка?

[gora]

Devils0411, попробуйте так:

Код:

@Echo off
SetLocal enabledelayedexpansion
if exist "%ProgramFiles(x86)%" (set bit=x64) else (set bit=x86)
Title Поиск отсутствующих обновлений для Windows %bit%
wmic qfe get HotFixID >temp.txt
Type temp.txt >CheckUpdates.txt
del /S /Q temp.txt >nul
(for /f "Tokens=1 Delims=" %%a in ('FindStr /IB "KB" "CheckUpdates.txt"') do (
	Set kb=%%a
	Set kb=!kb: =!
	Call :files !kb!
	echo Обновление !kb! !flag! в папке %~dp0%bit%
))>%~n0.log
Pause>nul

:files
Set flag=отсутствует
For /F "Tokens=2 Delims=-" %%k in ('Dir /B "%bit%\*.msu"') Do If %%k==%1 Set flag=присутствует& goto :EOF
goto :EOF

[sov44]

В папке Office_Updates находятся два типа файлов *.msp (шестизначные КВ типа KB907417-OTKLOADR.msp, KB981716-MSACCESS.msp и семизначные КВ типа KB2535812-POWERPNT.msp, KB2598253-GDIPLUS.msp) Необходимо вывести в Echo в порядке возрастания номеров сначала шестизначные КВ9.., затем семизначные КВ2..

сделал немного криво, может есть более оптимальное решение:

Код:

@echo off
SetLocal EnableDelayedExpansion

for /f %%a in ('dir /b/on "Office_Updates\*.msp"') do (
set up1=%%a
if /i "!up1:~2,1!"=="9" (echo !up1!)
)
for /f %%a in ('dir /b/on "Office_Updates\*.msp"') do (
set up2=%%a
if /i "!up2:~2,1!"=="2" (echo !up2!)
)

pause
exit

[Iska]

Попробуйте так:

читать дальше »

Код:

Option Explicit

Const adInteger  =   3
Const adVarChar  = 200


Dim objRegExp
Dim objFile


Set objRegExp = WScript.CreateObject("VBScript.RegExp")

With objRegExp
	.IgnoreCase = True
	.Pattern = "KB(\d{6,7}).*\.msp"
End With

With WScript.CreateObject("ADOR.Recordset")
	With .Fields
		.Append "KB FileName",                  adVarChar, 2^8 - 1
		.Append "KB Number",                    adInteger
	End With
	
	.Open
	
	For Each objFile In WScript.CreateObject("Scripting.FileSystemObject").GetFolder(WScript.Arguments.Item(0)).Files
		If objRegExp.Test(objFile.Name) Then
			.AddNew
			
			.Fields.Item("KB FileName").Value = objFile.Name
			.Fields.Item("KB Number").Value   = CLng(objRegExp.Execute(objFile.Name).Item(0).SubMatches.Item(0))
		End If
	Next
	
	.Sort = "[KB Number]"
	
	.MoveFirst
	
	Do Until .EOF
		WScript.Echo .Fields.Item("KB FileName")
		.MoveNext
	Loop
	
	.Close
End With

Set objRegExp = Nothing

WScript.Quit 0

Путь к папке указывайте аргументом скрипта, наподобие:

Код:

cscript.exe //nologo "c:\Scripts\This Script.vbs" "c:\Projects\Office_Updates"

[sov44]

Iska, нужен именно батник, т.к. в дальнейшем Echo будет посылаться как аргумент для создания ini

[gora]

sov44, попробуйте так:

Код:

@Echo Off
SetLocal EnableDelayedExpansion
Set fldr=e:\Temp 1\Office_Updates

For /F %%a In ('Dir "%fldr%" /B /A:-D') Do (
	Set ta=%%~nxa
	If "!ta:~8,1!"=="-" (
		Set $!ta:~0,2!0!ta:~2,6!=%%~nxa
	) Else (
		Set $!ta:~0,9!=%%~nxa
	)
)
For /F "Tokens=2 Delims==" %%a In ('Set $KB') Do Echo %%a
Pause>nul

[Iska]

т.к. в дальнейшем Echo будет посылаться как аргумент для создания ini »

Посылайте:

читать дальше »

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=" %%i in (
	`cscript.exe //nologo "c:\Scripts\This Script.vbs" "c:\Projects\Office_Updates"`
) do echo %%i

endlocal
exit /b 0

кто мешает .

[sov44]

gora, поясните пожалуйста код. В частности не понятно, куда девается ноль после КВ и где идёт сортировка

[gora]

где идёт сортировка »

Сортировка выполняется командой Set $KB, которая выводит список всех переменных начинающихся с $KB в алфавитном порядке.

куда девается ноль после КВ »

Нуль есть в имени переменной, а выводится значение переменной, в котором сохранено имя и расширение файла без изменений. Пример:

Код:

$KB0907417=KB907417-OTKLOADR.msp
$KB0981716=KB981716-MSACCESS.msp
$KB2535812=KB2535812-POWERPNT.msp
$KB2598253=KB2598253-GDIPLUS.msp