VBS/WSH/JS - [решено] скрипт обработки лог файлов и отправки уведомлений по почте

Iska · Отправлено: **16:25, 02-12-2011** | #11

Например, так:

Код:

strLog = "E:\Песочница\0092\123.txt"
With WScript.CreateObject("Scripting.FileSystemObject")
	For Each strLog In Array("c:\My Log 01.txt", "c:\My Log 02.txt", "c:\My Log 0x.txt")
		If .FileExists(strLog) Then
			…
		End If
	Next
End With

Или в папке вовсе только логи и ничего кроме логов?

mrxMonster · Отправлено: **14:59, 03-12-2011** | #12

Цитата Iska:

Или в папке вовсе только логи и ничего кроме логов? »

Да, папка предназначена только для логов таких как образец, за исключением названия!

Iska · Отправлено: **19:35, 03-12-2011** | #13

mrxMonster, ясно. Тогда, возможно, будет удобнее перебором всего, что есть в указанной папке:

Код:

Option Explicit

Const ForReading       = 1

Const cdoSendUsingPort = 2
Const cdoBasic         = 1

Const strPartSchema    = "http://schemas.microsoft.com/cdo/configuration/"



Dim strLog
Dim strLine
Dim dtDateTime

strLogPath = "E:\Песочница\0092"

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists(strLogPath) Then
		For Each objFile In .GetFolder(strLogPath).Files
			With objFile.OpenAsTextStream(ForReading)
				Do Until .AtEndOfStream
					strLine = .ReadLine()
				Loop
				
				.Close
			End With
			
			dtDateTime = CDate(Split(strLine)(0) & " " & Split(strLine)(1))
			
			If DateDiff("d", dtDateTime, Now()) <= 1 Then
				If UCase(Split(strLine)(3)) = UCase("Warning") Then
					With WScript.CreateObject("CDO.Message")
						With .Configuration.Fields
							.Item(strPartSchema & "sendusing")        = cdoSendUsingPort
							.Item(strPartSchema & "smtpauthenticate") = cdoBasic
							.Item(strPartSchema & "smtpserver")       = "smtp.mail.ru"
							.Item(strPartSchema & "smtpserverport")   = 25
							.Item(strPartSchema & "sendusername")     = "login"
							.Item(strPartSchema & "sendpassword")     = "password"
							
							.Update
						End With
						
						.To            = "to@mail.com"
						.From          = "from@mail.com"
						.Subject       = "Subject"
						.TextBody      = strLine
						
						.Send
					End With
				End If
			End If
		Next
	Else
		WScript.Echo "Log Folder [" & strLogPath & "] not found"
	End If
End With

WScript.Quit 0

Если у всех лог-файлов одинаковое расширение — можно сделать условие, чтобы при переборе отбирались именно файлы с таким расширением (так сказать, некоторая защита от случайно попавших в папку файлов).

mrxMonster · Отправлено: **13:58, 06-12-2011** | #14

В моей папке логов четыре файла. Названия им raidGVA-XP002.log raidGVA-XP061.log raidGVA-XP068.log raidGVA-XP112.log.
В файле raidGVA-XP002.log есть запись, которая должна вызвать отправку сообщения на почту, но скрипт пишет:
Переменная не определена: 'strLogPath'
Что делать? Где править?

Iska · Отправлено: **16:01, 06-12-2011** | #15

Если речь про #13, то, очевидно, здесь:

Код:

Dim strLog
Dim strLogPath

mrxMonster · Отправлено: **09:49, 07-12-2011** | #16

Цитата Iska:

Если речь про #13, то, очевидно, здесь:
Код:
Dim strLog
Dim strLogPath »

Я тоже так сразу подумал, но после этого:
Переменная не определена: 'objFile'

В папке лежат файлы txt и log для верности. Или же тут в другом проблемма?

Iska · Отправлено: **12:26, 07-12-2011** | #17

Дело в том, что последний вариант скрипта (#13) я писал «на ощупь», не запуская его для проверки.

Добавить «Dim objFile» туда же, ниже «Dim strLogPath»:

Код:

Dim strLogPath

Dim objFile

P.S. Может быть, переделать для работы только с лог-файлами и по маске? Судя по приведённым Вами выше именам файлов, у них есть постоянная и переменная части в именах.

mrxMonster · Отправлено: **15:18, 07-12-2011** | #18

Я не смог справится ни с первой интеграцией ни со второй. У меня скрипт работает только с указанием на конкретный файл.
Если можно, покажите вариант с перебором всех логов в папке по маске GVA-XP***.log

Iska · Отправлено: **15:35, 07-12-2011** | #19

mrxMonster, лады. Только — либо вечером, либо ближе к утру.

Iska · Отправлено: **09:44, 08-12-2011** | #20

mrxMonster, пробуйте:

Код:

Option Explicit

Const ForReading       = 1

Const cdoSendUsingPort = 2
Const cdoBasic         = 1

Const strPartSchema    = "http://schemas.microsoft.com/cdo/configuration/"


Dim strLogPath
Dim objFile
Dim objRegExp

Dim strLine
Dim dtDateTime


strLogPath = "E:\Песочница\0098"

Set objRegExp = WScript.CreateObject("VBScript.RegExp")

With objRegExp
	.IgnoreCase = True
	.Pattern    = "GVA-XP\d{3}\.log"
End With

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FolderExists(strLogPath) Then
		For Each objFile In .GetFolder(strLogPath).Files
			If objRegExp.Test(objFile.Name) Then
				With objFile.OpenAsTextStream(ForReading)
					Do Until .AtEndOfStream
						strLine = .ReadLine()
					Loop
					
					.Close
				End With
				
				dtDateTime = CDate(Split(strLine)(0) & " " & Split(strLine)(1))
				
				If DateDiff("d", dtDateTime, Now()) <= 1 Then
					If UCase(Split(strLine)(3)) = UCase("Warning") Then
						With WScript.CreateObject("CDO.Message")
							With .Configuration.Fields
								.Item(strPartSchema & "sendusing")        = cdoSendUsingPort
								.Item(strPartSchema & "smtpauthenticate") = cdoBasic
								.Item(strPartSchema & "smtpserver")       = "smtp.mail.ru"
								.Item(strPartSchema & "smtpserverport")   = 25
								.Item(strPartSchema & "sendusername")     = "login"
								.Item(strPartSchema & "sendpassword")     = "password"
								
								.Update
							End With
							
							.To            = "to@mail.com"
							.From          = "from@mail.com"
							.Subject       = "Subject"
							.TextBody      = strLine
							
							.Send
						End With
					End If
				End If
			End If
		Next
	Else
		WScript.Echo "Log Folder [" & strLogPath & "] not found"
	End If
End With

WScript.Quit 0