[Iska]

У меня — находит (VBScript):

Код:

Option Explicit

Const olFolderInbox = &H06

Dim objOutlook
Dim objNameSpace
Dim objMAPIFolder
Dim collItems
Dim objMailItem

Set objOutlook    = WScript.CreateObject("Outlook.Application")
Set objNameSpace  = objOutlook.GetNameSpace("MAPI")
Set objMAPIFolder = objNameSpace.GetDefaultFolder(olFolderInbox)
Set collItems     = objMAPIFolder.Items
Set objMailItem   = collItems.Find("[Subject] = 'Налоги_июнь_2011'")

Do Until objMailItem Is Nothing
	With objMailItem
		WScript.Echo "EntryID:", .EntryID
		WScript.Echo "==============="
		WScript.Echo "To:     ", .To
		WScript.Echo "Subject:", .Subject
		WScript.Echo "Body:"
		WScript.Echo "---------------"
		WScript.Echo .Body
		WScript.Echo "---------------"
		WScript.Echo
	End With
	
	Set objMailItem = collItems.FindNext
Loop

Set objMailItem   = Nothing
Set collItems     = Nothing
Set objMAPIFolder = Nothing
Set objNameSpace  = Nothing
Set objOutlook    = Nothing

WScript.Quit 0

Код: EntryID: 00000000FEECAA007BA93142AA08FBF8921FB867C4092000 =============== To: someuser1@mail.com Subject: Налоги_июнь_2011 Body: --------------- Hello1 --------------- EntryID: 00000000FEECAA007BA93142AA08FBF8921FB867040A2000 =============== To: someuser2@mail.com Subject: Налоги_июнь_2011 Body: --------------- Hello2 ---------------

Работаете по полному соответствию искомой строки полю «Тема»?