[Foreigner]

intersk,

Код:

@echo off
setlocal

for %%i in ( .r01 .r16 ) do set "check%%i=1"
for /f "tokens=*" %%i in (' dir /b /s /a-d "c:\files" ') do (

    if not defined check%%~xi del "%%i"

)

[El Sanchez]

intersk, №2

Код:

For /R "C:\Files" %%A In (*) Do If /i "%%~xA" NEQ ".r01" If /i "%%~xA" NEQ ".r16" Del /F /Q "%%A" 2>nul

[amel27]

до кучи:

Код:

for /f "delims=" %%a in ('dir/b/s/a-d *^|findstr/eiv "\.r01 \.r16"') do del "%%a"

[ferget]

a-d *^|findstr/eirv "\.r01 \.r16"' »

не могли бы вы объяснить эту часть

[amel27]

ferget, так понятней?

Код:

findstr /e /i /r /v "\.r01 \.r16"

оставляет все строки кроме заканчивающихся на ".r01" или ".r16"

[ferget]

/a-d *^ »

спасибо, еще вот

[amel27]

ferget,

Код:

dir /b /s /a-d

ключ /a-d значит исключая каталоги

[intersk]

Уточню свой вопрос - Файлы в расширении имеют первую букву либо *.rxx либо *.hxx.
xx - это цифры. Они разные. Нужно оставить только с цифрами 01 и 16 (*.r01, *.r16, *.h01, *.h16). В папках ещё есть разные файлы. Остальные файлы в папках не удалять!!!!
PS. сработал только первый вариант...но почему то файл *.cmd удаляется после работы...(и удаляет все файлы - но теперь уточнил свою задачу)

[amel27]

Файлы в расширении имеют первую букву либо *.rxx либо *.hxx »

Код:

for /f "delims=" %%a in (
'dir/b/s/a-d^|findstr/eir "\.[rh][0-9][0-9]"^|findstr/eirv "\.[rh]01 \.[rh]16"'
) do del "%%a"