[Iska]

Snowmania, что-либо наподобие такого?!

читать дальше »

StartTwoIE.vbs

Код:

Option Explicit

With WScript.CreateObject("Shell.Application")
    .MinimizeAll
    
    ' URL, Left, Top, Width, Height
    StartIE "http://www.ya.ru",     100, 100, 400, 300
    StartIE "http://www.google.ru", 600, 100, 400, 300
    
    .TileVertically
End With

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub StartIE(strURL, intLeft, intTop, intWidth, intHeight)
    Const READYSTATE_COMPLETE = 4
    
    With WScript.CreateObject("InternetExplorer.Application")
        .Silent     = True
        
        .FullScreen = False
        '.Resizable  = False
        
        .MenuBar    = False
        .ToolBar    = False
        .AddressBar = False
        .StatusBar  = False
        
        .Left       = intLeft
        .Top        = intTop
        .Width      = intWidth
        .Height     = intHeight
        
        .Navigate strURL
            
        Do
            WScript.Sleep 100
        Loop Until Not .Busy And .ReadyState = READYSTATE_COMPLETE
            
        .Visible = True
    End With
End Sub