[madmasles]

---Zak---,
Честно говоря, я не совсем понял, что Вам надо, но попробуйте так, у меня работает:

читать дальше »

Код:

#NoTrayIcon
#include <ModernMenuRaw.au3>
$j = 0
$bPause = True
$hTrayIcon = _TrayIconCreate("Proba")

_TrayIconSetClick(-1, 16)
_TrayIconSetState()

$nTrayMenu = _TrayCreateContextMenu()

$Pause_TrayItem = _TrayCreateItem("Пауза")
_TrayItemSetIcon(-1, "shell32.dll", 321)

_TrayCreateItem("")
_TrayItemSetIcon(-1, "", 0)

$Notepad_TrayItem = _TrayCreateItem("Блокнот")
_TrayItemSetIcon(-1, "notepad.exe", 0)

_TrayCreateItem("")
_TrayItemSetIcon(-1, "", 0)

$Exit_TrayItem = _TrayCreateItem("Выход")
_TrayItemSetIcon(-1, "shell32.dll", 28)

_TrayIconSetToolTip(-1, 'Функции работают')
_SetTrayIconBkColor(0xC46200)
_SetTraySelectBkColor(0x087272)
_SetTraySelectTextColor(0xFFFFFF)

AdlibRegister("ReadFILE", 1000)
AdlibRegister("_MyPing", 1000)
While 1
    Switch GUIGetMsg()
        Case $Notepad_TrayItem
            Run("Notepad.exe офис.txt")
        Case $Pause_TrayItem
            $bPause = Not $bPause
            If $bPause Then
                AdlibRegister("ReadFILE", 1000)
                AdlibRegister("_MyPing", 1000)
                _TrayItemSetText($Pause_TrayItem, 'Пауза')
                _TrayItemSetIcon($Pause_TrayItem, "shell32.dll", 321)
                _TrayIconSetToolTip(-1, 'Функции работают')
            Else
                AdlibUnRegister("ReadFILE")
                AdlibUnRegister("_MyPing")
                _TrayItemSetText($Pause_TrayItem, 'Продолжить')
                _TrayItemSetIcon($Pause_TrayItem, "shell32.dll", 135)
                _TrayIconSetToolTip(-1, 'Пауза в работе функций')
            EndIf

        Case $Exit_TrayItem
            _TrayIconDelete($hTrayIcon)
            ExitLoop
    EndSwitch
WEnd

Func ReadFILE()
    $file = FileOpen("офис.txt", 0)
    While 1
        $line = FileReadLine($file)
        If @error = -1 Then ExitLoop
;~         ........
    WEnd
    FileClose($file)
    $j += 1
    ToolTip('Счетчик ' & $j, 0, 0)
EndFunc   ;==>ReadFILE
Func _MyPing()
    Local $iPing = Ping('google.com')
    If $iPing Then
        _TrayTip(-1, 'Ping', 'Ping google.com - ' & $iPing & ' ms' & @CRLF & $j, 0, 19)
    Else
        _TrayTip(-1, 'Ping', 'No Ping google.com - ' & $j, 0, 19)
    EndIf
EndFunc   ;==>_MyPing