[madmasles]

tarasov.evgeny,
Можно так попробовать:

Код:

#NoTrayIcon
#include <Timers.au3>

;список убиваемых процессов в массиве:
Dim $aProcesses[6] = [5, 'process1.exe', 'process2.exe', 'process3.exe', 'process4.exe', 'process5.exe']
;пауза между проверками в секундах
Global $iPouse = 30
Global $sRegRun = 'HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run'

;проверка записи себя в автозагрузку
If RegRead($sRegRun, @ScriptName) = '' Or RegRead($sRegRun, @ScriptName) <> @ScriptFullPath Then
    RegWrite($sRegRun, @ScriptName, "REG_SZ", @ScriptFullPath)
EndIf

While 1
    For $i = 1 To $aProcesses[0]
        If ProcessExists($aProcesses[$i]) Then
            _ToolTipEx('Нельзя запускать ' & $aProcesses[$i], 1, 1, 'Злой админ', 3, 5, 3000)
            ProcessClose($aProcesses[$i])
        EndIf
    Next
    Sleep($iPouse * 1000)
WEnd

Func _ToolTipEx($sText, $iX = Default, $iY = Default, $sTitle = Default, $iIcon = Default, $iOptions = Default, $iTimeOut = 0)
    ToolTip($sText, $iX, $iY, $sTitle, $iIcon, $iOptions)

    If $iTimeOut Then
        _Timer_SetTimer(0, $iTimeOut, "_ToolTipEx_Callback")
    EndIf
EndFunc   ;==>_ToolTipEx

Func _ToolTipEx_Callback($hWnd, $Msg, $iIDTimer, $dwTime)
    _Timer_KillTimer($hWnd, $iIDTimer)
    ToolTip("")
EndFunc   ;==>_ToolTipEx_Callback

Можно для надежности еще заблокировать Реестр и Диспетчер задач.