[amel27]

Код:

Select
	Case $CmdLine[0]=1 And $CmdLine[1]="r"
		Run("regedit.exe", @WindowsDir)
	Case $CmdLine[0]=1 And $CmdLine[1]="t"
		Run("taskmgr.exe", @SystemDir)
	Case $CmdLine[0]=1 And $CmdLine[1]="s"
		Run("shutdown -r -f -t 0", @SystemDir)
	Case $CmdLine[0]=1 And $CmdLine[1]="x"
		Run("shutdown -s -f -t 0", @SystemDir)
	Case $CmdLine[0]=1 And $CmdLine[1]="p"
		Run("VSTPluginsPath.exe")
	Case Else
		Run("C:\I\Apps\Cubase\Cubase.exe "& $CmdLineRaw)
EndSelect

[Creat0R]

Или так:

Код:

If $CmdLine[0] = 0 Then Exit

Switch $CmdLine[1]
    Case "r"
        Run("regedit.exe", @WindowsDir)
    Case "t"
        Run("taskmgr.exe", @SystemDir)
    Case "s"
        Run("shutdown -r -f -t 0", @SystemDir)
    Case "x"
        Run("shutdown -s -f -t 0", @SystemDir)
    Case "p"
        Run("VSTPluginsPath.exe")
    Case Else
        Run("C:\I\Apps\Cubase\Cubase.exe "& $CmdLineRaw)
EndSwitch

[madmasles]

semiono,
$CmdLine[0] возвращает количество параметров. Честно говоря, я сам с ними долго разбирался. Попробуйте создать 2 скрипта. 1-ый:

Код:

#include <Constants.au3>

$mod = Run(@AutoItExe & ' /AutoIt3ExecuteScript Test.au3 Первый_параметр Второй_параметр Третий_параметр', @ScriptDir, @SW_HIDE, $STDOUT_CHILD)
$sLog = ''
While 1
    $sLog &= StdoutRead($mod)
    If @error Then ExitLoop
    Sleep(2)
WEnd
MsgBox(0, '', $sLog)

2-ой (назовите его Test.au3 и положите в ту же папку, где лежит 1-ый):

Код:

If Not $CmdLine[0] Then
    ConsoleWrite('Нет параметров' & @LF)
    Exit
EndIf
For $i = 1 To $CmdLine[0]
    ConsoleWrite($CmdLine[$i] & @LF)
    Sleep(100)
Next
ConsoleWrite(@LF & 'Все!' & @LF)

Теперь запускайте 1-ый скрипт и меняйте параметры. Я сам с этим игрался, чтобы разобраться. Кстати, если скомпилировать первый скрипт, то он будет запускать второй и на компьютере с неустановленным AutoIt`oм.

PS
Кажется, Yashied приводил примерно такой пример на autoit-script.ru, лень искать.

[semiono]

Очень изящные красивые примеры! Их хоть прямо в справку записывай, отлично!
amel27, Creat0R, madmasles, благодарю!

[Creat0R]

Ещё по теме: _CmdLineSetEvent - Обработчик командной строки

[semiono]

Всётаки эта тема безконечная.
Запускаю консольное приложение, ISCC.exe - кампилятор Inno Setup.
Задача просто передать ему управление.
Вот батник который работает:
\system32\ISCC.cmd

Код:

@"C:\I\Apps\Innosup\ISCC.exe" %*

Я уже все варианты перебрал наугад, в лучшм случае выдаёт справку, но на вход комманды не хочет воспринимать.

Код:

#Include <Constants.au3>

Run(@ProgramFilesDir & "\Innosup\ISCC.exe ", $CmdLineRaw, ".", $STDERR_CHILD & $STDIN_CHILD  & $STDOUT_CHILD)

Кампилю как "Create CUI instead of GUI.EXE", хотя может быть не надо?

Смысл флагов $STDIN_CHILD не очень понятен, но где-то что-то я улавливаю приблизительно. ))

[amel27]

уже все варианты перебрал наугад »

право, быстрей в справку глянуть:

Код:

Run(@ProgramFilesDir &"\Innosup\ISCC.exe "& $CmdLineRaw, @ScriptDir, @SW_HIDE, $STDERR_CHILD + $STDIN_CHILD + $STDOUT_CHILD)

[semiono]

А вот так правильно?

Код:

$pid = Run(@ProgramFilesDir & "\Innosup\ISCC.exe " & $CmdLineRaw, @WorkingDir, @SW_ENABLE, $STDIO_INHERIT_PARENT)
StdioClose($pid)

У меня не до конца прокрутка в консоли срабатывет, будто бы подвисает на одну строку.
Но работа ISCC.exe кампилятора выполняется.

[semiono]

Понял проблему!! Надо было RunWait() теперь не подвисает! Анологично батнику чётко работает.
Но что лучше $STDIO_INHERIT_PARENT или 0x1 + 0x2 ?? И надо ли закрывать процесс StdioClose($pid) ?