У меня есть собственное решение для поднятия резервного канала интернет с помощью простого bat-ника в случае отваливания основного, а потом возвращается основной шлюз в случае поднятия на нем и-нета.
Сеть построена на базе 2-х обычных маршрутизаторов, каждый из которых подключен к своему интернету.
IP-шники 192.168.1.100 - основной и 192.168.1.200 - резервный.
Маршрутизаторы соединены друг с другом LAN интерфейсами.
Для предотвращения отваливания части пользователей в случае зависания одного из маршрутизаторов, в LAN интерфейсы не подключен ни один пользователь, все только через коммутатор.
И-нет проверяетс каждые 10 секунд (при постоянном пинге, например i.ua, если отвалился основной канал, теряется 1-2 пакета, при возврате с резервного на основной не теряется ни одного пакета.
Реализуется через "Назначенные задания" в Винде с запуском от имени Администратора (должен быть пароль на учетку), что дает скрытие окна работы скрипта:
Код:
@ECHO OFF
rem # Прописываем статический постоянный маршрут для 194.87.0.50 (www.ru),
rem # чтобы все пинги на этот адрес ходили тольк через шлюз 192.168.1.100,
rem # даже если основным шлюзом в данный момент является резервный 192.168.1.200
route delete 194.87.0.50
rem # (нужно если планируется периодически менять основного провайдера)
route add -p 194.87.0.50 mask 255.255.255.255 192.168.1.100
rem # Запускаем бесконечный цикл проверки, работает ли основной канал интернет
rem # Если не работает, меняем (оставляем) основной шлюз на 192.168.1.200, т.е.
rem # на шлюз резервного канала интернет.
:start
ping 194.87.0.50 -n 2 > null
if ERRORLEVEL 1 (
route change 0.0.0.0 mask 0.0.0.0 192.168.1.200 metric 1
cls
color 47
ECHO -------------------------------------------------------------------
ECHO - -
ECHO - -
ECHO ----------------KITS опять упал, используем СтарИнет---------------
ECHO - -
ECHO - -
ECHO -------------------------------------------------------------------
) ELSE (
route change 0.0.0.0 mask 0.0.0.0 192.168.1.100 metric 1
cls
color 20
ECHO -------------------------------------------------------------------
ECHO - -
ECHO - -
ECHO -----------------------KITS поднят и работает----------------------
ECHO - -
ECHO - -
ECHO -------------------------------------------------------------------
)
rem # Пауза в 10 сек. хитрым извращенским способом по совету на одном из форумов :)
ping -n 10 127.0.0.1 > nul
goto :start
rem # Переходим к началу цикла
