[deepred]

seriych,

примерно так (но с редакцией под себя):

Код:

Echo on&Chcp 866&Title S E T U P &cls

if "%~1"=="" (set /p LingID= Введите LingID: ) else (set LingID=%~1)

for /f "tokens=1,2* delims=$" %%a in ('^<"%~dpf0" Findstr /i "%LingID%"') do ^
if Exist "%~dp0%%a" ((start /b /wait "%~dp0%%a" %%b
%%c)) else Echo Error install %%a-application >> "%~dp0Errlog"
pause&goto :eof

:install

program-001$ /a /b /c$command1&command2&command3
program-002$ /a /b /c$command1&command2&command3&command4
program-003$ /a /b /c$command1&command2
program-004$ /a /b /c$command1&command2&command3&command4
program-005$ /a /b /c$command1
program-006$ /a /b /c$command1&command2&command3
program-007$ /a /b /c$command1&command2&command3&command4
program-008$ /a /b /c$command1&command2
program-009$ /a /b /c$command1

Пояснения:
Инсталяторы находяться в той dir-ии, что *.bat или же меняй пути
все setup'ы запускаются по очереди (или исключи /wait )
program-XXX - имя программы (например install_flash_player.exe)
LingID - идентификатор инсталятора, придумай сам (это должна быть часть имени проги).
/a /b /c - ключи запуска
Ошибки пишутся в файл "Errlog"

Запуск из CMD или WinRun, пример:

Код:

"Disk:\dir1\dir2\@setup.bat" "LingID  LingID  LingID"

[seriych]

deepred,
ээээ... Я несколько озадачен
А вот это start /b /wait "%~dp0%%a" подразумевает, что у меня запускается установщик приложения? Тогда мне это не подходит, потому что для каждой программы у меня помимо запуска инсталлятора еще и различные действия совершаются (где-то ярлыки переименовать, где-то настройки скопировать).
P.S. Делать отдельный батник для каждой программы не предлагать, тем более что они и так есть. Хочется как раз убрать эти батники.

[deepred]

seriych,

Включаем фантазию!!!!!!!!!!!!!!!!

"/a /b /c", а что тебе мешает включить сценарий в эту подстроку?

допустим: setup_programm_name.exe$ /silient$copy xxx\settings.ini yyy\yyy\ & ren xxx\name1.lnk name2.lnk

и получится
start /b /wait xxx\setup_programm_name.exe /silient
copy xxx\settings.ini yyy\yyy\ & ren xxx\name1.lnk name2.lnk

[seriych]

deepred,
Вот фантазии-то и не хватает, видимо

Для каждой программы этот дополнительный код сильно различается. Или я чего-то не понимаю в твоем коде...

[gora]

Так подойдет?

Код:

@echo off
Set list=%*
:: Список вариантов, которые могут быть обработаны в скрипте
Set Exilist=1 2 3 4 7 9 11 12 15 18 21 25
:: Список вариантов, которые будут обработаны в скрипте при его запуске без параметров
If "%list%"=="" Set list=1 2 4 7 9 11 21

For %%a In (%list%) Do For %%i In (%Exilist%) Do If %%a==%%i Call :M%%a
Exit

:M1
:: Здесь команды для варианта 1
...
GoTo :EOF

:M2
:: Здесь команды для варианта 2
...
GoTo :EOF

:M3
...
GoTo :EOF

:M4
...
GoTo :EOF

:M7
...
GoTo :EOF

...

[seriych]

Ладно, спасибо. С утра может мозг лучше будет соображать.

[amel27]

до кучи

Код:

@echo off

for %%i in (%*) do set $:M_%%i=:M_%%i
1>nul 2>&1 set $:||for /f %%i in ('findstr /bi ":M_" "%0"') do set $%%i=%%i
for /f "tokens=1* delims==" %%i in ('set $:') do call %%j %%j
exit /b

:M_01
 Echo Here code for %1 module.
GoTo :EOF

:M_10
 Echo Here code for %1 module.
GoTo :EOF

:M_99
 Echo Here code for %1 module.
GoTo :EOF

пример вызова:

Код:

start.cmd 99 01

[seriych]

Всем спасибо.

Скрипт deepred я так и не понял

Вариант gora самый простой для понимания. Правда ставит в порядке, в котором идут аргументы, а не в заранее определенном, но это не принципиально, да и с другой стороны так даже правильнее (более гибко получается).

Вариант amel27 пока не смотрел, ибо предыдущий устроил. Плюсик за содействие.

[gora]

Правда ставит в порядке, в котором идут аргументы, а не в заранее определенном »

Для этого достаточно поменять переменные в строке местами:

Код:

For %%a In (%Exilist%) Do For %%i In (%list%) Do If %%a==%%i echo Call :M%%a