[amel27]

cause, примерно так, выделенные значения необходимо заменить на свои:

читать дальше »

Код:

Set WS = CreateObject("WScript.Shell")
Set FSO= CreateObject("Scripting.FileSystemObject")
sCompName = WS.ExpandEnvironmentStrings("%ComputerName%")
sUserName = WS.ExpandEnvironmentStrings("%UserName%")

sFile = "с:\хх\х.ехе"
sTo   = "adm@srv.com"
sFrom = "monitor@srv.com"
sSubj = "Monitor: "& sUserName &" ["& sCompName &"]"

If FSO.FileExists(sFile) Then
  If FSO.GetFileVersion(sFile) <> "1.1" Then
    SendMail sTo, sFrom, sSubj, "версии не совпадают"
  End If
Else
  SendMail sTo, sFrom, sSubj,"файл не найден"
End If

Sub SendMail(sTo, sFrom, sSubj, sText)
  Dim oEmail:Const sCfg = "http://schemas.microsoft.com/cdo/configuration/"
  Set oEmail = CreateObject("CDO.Message")

  oEmail.Configuration.Fields.Item(sCfg &"smtpserver")      = "smtp.dom.local"
  oEmail.Configuration.Fields.Item(sCfg &"sendusername")    = "monitor"
  oEmail.Configuration.Fields.Item(sCfg &"sendpassword")    = "password"
  oEmail.Configuration.Fields.Item(sCfg &"smtpserverport")  = 25
  oEmail.Configuration.Fields.Item(sCfg &"smtpauthenticate")= cdoBasic
  oEmail.Configuration.Fields.Item(sCfg &"sendusing")       = 2
  oEmail.Configuration.Fields.Update

  oEmail.To      = sTo  :oEmail.From    = sFrom
  oEmail.Subject = sSubj:oEmail.Textbody= sText

  oEmail.Send
End Sub