[hb860]

Тихая установка Opera 10.53 Скачать

[SamLab]

hb860, Не плохо было бы значок оперный для установки поставить и сделать такую же на базе билда 3381 SR1

[hb860]

Зачем значок?
И это, я принципиально собираю РТМки оперы. Исключение была 10.50 бета
Этот 3381 SR1 какой-то особенный?

[SamLab]

hb860, На то он и SR1 а не snapshot или beta т.к. в нем чсто фиксы предыдущего билда - а иконка чтобы отличать программы друг от друга в том же BS PostInst да и просто на жестком приятнее глазу

[hb860]

Сделаем

[tiylar]

Кто нибудь может выложить работающий скрипт авто установки но без скинов и флеш плеера?

[hb860]

Издеваетесь? Две секции не желаете стереть? Впрочем, держите:

Код:

!define PRODUCT_NAME "Opera"
!define PRODUCT_VERSION "10.51"
!define pkgdir "d:\package"

!include "MUI.nsh"
SetCompressor /SOLID lzma

!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
!define MUI_COMPONENTSPAGE_SMALLDESC 
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_LANGUAGE "Russian"

!define BRANDING "http://www.winreview.ru"

InstType "Полная"
InstType "Сокращенная"
InstType "Минимальная"


Var gMode
Var IniFile
Var WindowCaption
Var Opera
Var MultiUsers
Var Desk
Var QL
Var SM
Var Def
!include "WordFunc.nsh"
!include "FileFunc.nsh"

Function .onInit
	;
	; when /g switch specified and not present /s switch, then generate default config
	;
	;inifile definition
	;
	StrCpy $Opera 0
	StrCpy $Flash 0
	StrCpy $Skins 0
	StrCpy $MultiUsers 0
	StrCpy $Desk 0	
	StrCpy $QL 0		
	StrCpy $SM 0			
	StrCpy $WindowCaption "Установка ${PRODUCT_NAME} ${PRODUCT_VERSION}"
	${WordReplace} "$EXEFILE" ".exe" ".ini" "+" $IniFile
	StrCpy $IniFile "$EXEDIR\$IniFile"
	
	;gMode detection
	StrCpy $gMode 0
	${GetOptions} $CMDLINE "/G" $0
	IfErrors EndFunc
	IfSilent +4 0
	StrCpy $gMode 1
	Delete $IniFile
	StrCpy $WindowCaption "Генератор файла ответов ${PRODUCT_NAME}"
	EndFunc:
FunctionEnd


!macro ProcessSection secID
	;
	;if gMode=1 - generate default config. if 0 and not silent - reads the config
	StrCpy $R0 1
	StrCmp $gMode 1 WriteMode
	IfSilent 0 EndMarco
		IfFileExists $IniFile 0 EndMarco
		ReadINIStr $R0 $IniFile Sections ${secID}
		IfErrors 0 +2
		StrCpy $R0 0
		Goto EndMarco
	WriteMode:
		StrCpy $R0 0
		WriteINIStr $IniFile Sections ${secID} 1
	EndMarco:	
!macroend


Name "${PRODUCT_NAME}"
Caption "$WindowCaption"
OutFile "${PRODUCT_NAME}-${PRODUCT_VERSION}.exe"
InstallDir "$PROGRAMFILES\${PRODUCT_NAME}"
ShowInstDetails show
BrandingText "${BRANDING}"

Section "!${PRODUCT_NAME}" secOPERA
  SectionIn 1 2 3 RO
  !insertmacro ProcessSection "secOPERA"
  StrCmp $gMode 1	SectionEnd1
	StrCpy $Opera 1
  SectionEnd1:
SectionEnd

Section "Многопользовательский режим работы" secMultiUsers
	SectionIn 1 2 3
	!insertmacro ProcessSection "secMultiUsers"
	StrCmp $gMode 1	EndSection
		StrCpy $MultiUsers 1
	EndSection:	
SectionEnd

Section "Сделать браузером по умолчанию" secDef
	SectionIn 1 2 3
	!insertmacro ProcessSection "secDef"
	StrCmp $gMode 1	EndSection
		StrCpy $Def 1
	EndSection:	
SectionEnd

SectionGroup /e "Ярлыки"
	Section "Меню пуск" secSM
	SectionIn 1 2 3
		!insertmacro ProcessSection "secSM"
		StrCmp $gMode 1	EndSection
			StrCpy $SM 1
		EndSection:			
	SectionEnd

	Section "Рабочий стол" secDesk
	SectionIn 1 2 
		!insertmacro ProcessSection "secDesk"
		StrCmp $gMode 1	EndSection
			StrCpy $Desk 1
		EndSection:			
	SectionEnd

	Section "Панель быстрого запуска" secQL
	SectionIn 1 2 
		!insertmacro ProcessSection "secQL"
		StrCmp $gMode 1	EndSection
			StrCpy $QL 1
		EndSection:			
	SectionEnd
SectionGroupEnd

Section -Post
	StrCmp $Opera 0 SkipOpera
		SetOutPath "$TEMP"
		File  "${pkgdir}\opera\1049.MST"
		File  "${pkgdir}\opera\opera installer.msi"
		ExecWait "msiexec.exe /i $\"$TEMP\opera installer.msi$\" /qb SET_DEFAULT_BROWSER=$Def ALLUSERS=1 CREATE_DESKTOP_ICON_REG_USR=$Desk CREATE_QUICKLAUNCH_ICON_REG_USR=$QL CREATE_STARTMENU_ICONS_REG_USR=$SM MULTI_USER_SETTING=$MultiUsers TRANSFORMS=$\"$TEMP\1049.MST$\""
		Delete "$TEMP\opera installer.msi"
		Delete "$TEMP\1049.MST"
	SkipOpera:
SectionEnd

LangString DESC_OPERA ${LANG_RUSSIAN} "Браузер ${PRODUCT_NAME} ${PRODUCT_VERSION}"
LangString DESC_MULTIUSERS ${LANG_RUSSIAN} "Отдельный профиль настроек для каждого пользователя"

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${secOPERA} $(DESC_OPERA)
  !insertmacro MUI_DESCRIPTION_TEXT ${secMultiUsers} $(DESC_MULTIUSERS)
!insertmacro MUI_FUNCTION_DESCRIPTION_END

[tiylar]

спасибо помогло хотя и здесь ошибки были в 45 строке.

[hb860]

Да, я забыл потереть это:

Код:

	StrCpy $Flash 0
	StrCpy $Skins 0

[hb860]

Opera 10.54+Adobe Flash player 10.1.53.64
Всё в шапке.
Дистрибутив имеет красный официальный значок браузера, как просил SamLab