[amel27]

CMD/BAT - [решено] Замена строк конфига

[BigBoo]

Похожий вопрос, но задача несколько иная. К примеру, как в шапке, 1.txt:

Код:

...
aaa=1

[paste]
bbb=1
ccc=1
...

Задача: Нужен скрипт, изменяющий в секции [paste] значение ccc=1 на ccc=0, если параметра ccc не существует, добавить ccc=0 именно в эту секцию.

[amel27]

скрипт, изменяющий в секции [paste] значение ccc=1 на ccc=0, если параметра ccc не существует, добавить ccc=0 именно в эту секцию »

Код:

@echo off

CALL:INISET 1.ini paste ccc 0
EXIT

:INISET  %file_path% %section% %parm% %val%
::-----------------------------------------
SETLOCAL DisableDelayedExpansion
set $sn= & set $vf=0& set "$ft=%TEMP%\%RANDOM%%RANDOM%.tmp"
(for /f "tokens=1,2* delims==:" %%a in ('findstr /n "$" "%~1"') do (
 set "$b=%%b"& set "$c=%%c"
 SETLOCAL EnableDelayedExpansion
 if "!$b:~0,1!"=="[" set "$sn=!$b:~1,-1!"
 set $lf=_& if /i "!$sn!"=="%~2" if /i "!$b!"=="%~3" set "$lf="
 if defined $c set "$c==!$c!"
 if defined $lf echo/!$b!!$c!
 if "!$sn!"=="%~2" if "!$vf!"=="0" set $vf=1& echo %~3=%~4
 for /f "tokens=1,2 delims=:" %%i in ("!$sn!:!$vf!") do (
ENDLOCAL& set "$sn=%%i"& set "$vf=%%j")))>"%$ft%"
copy /y "%$ft%" "%~1">nul&& del "%$ft%"
::----------------
ENDLOCAL& GoTo:EOF

[BigBoo]

Попробовал Ваш скрипт, что-то не так. Он просто удаляет параметр "ссс" и ничего более не делает.

[Foreigner]

Код:

gsar "-s[paste]" "-rbbb" -o 1.txt

[amel27]

Он просто удаляет параметр "ссс" и ничего более не делает »

исправил, была ошибка в случае если файл начинался не с имени секции

[BigBoo]

amel27, всё работает, но в моём случае значение параметра содержит символы, в результате скрипт не срабатывает, то есть к примеру так:

Код:

CALL:INISET 1.ini paste ccc ""a 1","b 2","c 3""

Убираю внутренние кавычки - работает, но хотелось, чтоб они обрабатывались, а также возможна ли обработка символа | ?

[amel27]

значение параметра содержит символы »

придется передавать не по значению, а по ссылке на переменную, содержащую это значение:

Код:

@echo off

set "$val="a 1","b 2"|"c 3""
CALL:INISET 1.ini paste ccc $val
EXIT

:INISET  file_path section parm ByRef val
::---------------------------------------
SETLOCAL DisableDelayedExpansion
set $sn= & set $vf=0& set "$ft=%TEMP%\%RANDOM%%RANDOM%.tmp"
(for /f "tokens=1,2* delims==:" %%a in ('findstr /n "$" "%~1"') do (
 set "$b=%%b"& set "$c=%%c"
 SETLOCAL EnableDelayedExpansion
 if "!$b:~0,1!"=="[" set "$sn=!$b:~1,-1!"
 set $lf=_& if /i "!$sn!"=="%~2" if /i "!$b!"=="%~3" set "$lf="
 if defined $c set "$c==!$c!"
 if defined $lf echo/!$b!!$c!
 if defined %~4 (set $4=!%~4!) else set "$4=%~4"
 if "!$sn!"=="%~2" if "!$vf!"=="0" set $vf=1& echo %~3=!$4!
 for /f "tokens=1,2 delims=:" %%i in ("!$sn!:!$vf!") do (
ENDLOCAL& set "$sn=%%i"& set "$vf=%%j")))>"%$ft%"
copy /y "%$ft%" "%~1">nul&& del "%$ft%"
::----------------
ENDLOCAL& GoTo:EOF

[BigBoo]

amel27, Всё бы хорошо, но вот так работает:

Код:

set "$val="a 1","b 2"|"c 3""

А вот так - нет:

Код:

set "$val="a 1","b 2""|c 3""

[amel27]

А вот так - нет: Код: set "$val="a 1","b 2""|c 3"" »

для такой строки можно использовать код (намеренно заменил "," на "|"):

Код:

set $val="a 1"^|"b 2""|c 3"

Из этого примера видно, что спецсиволы вне кавычек нужно экранировать символом "^". Если мы теперь возьмём всю команду SET в кавычки, то произойдёт инверсия: всё что было в кавычках окажется за ними и наоборот, это нужно учесть при экранировании спецсимволов:

Код:

set "$val="a 1"|"b 2""^|c 3""