[Coutty]

Может просто создать дочернее окно, в котором будет только сообщение и кнопка? Скрипт при этом не должен останавливаться.

[andr_mozg]

так там будит то же цыкл, который будит следить не нажата ли кнопка, получится то же самое что и с MsgBox.

[Creat0R]

Код:

$iRet = _MsgBoxEx(36, "My Title", "Message", 10, 0, "_SetData")

MsgBox(64, "", "Returned Value is: " & $iRet)

Func _SetData($iCount)
    ConsoleWrite("The script is not paused " & $iCount & " second(s)" & @LF)
EndFunc

Func _MsgBoxEx($iType, $sTitle, $sText, $iTimeOut=0, $hWnd=0, $sCallBackFunc="")
    Local $sAu3Line = '"ConsoleWrite(MsgBox(' & $iType & ', ''' & $sTitle & ''', ''' &  $sText & ''', ' & _
        $iTimeOut & ', ' & $hWnd & '))"'
    Local $iAu3PID = Run(@AutoItExe & ' /AutoIt3ExecuteLine ' & $sAu3Line, '', @SW_SHOW, 6)

    Local $iStdOutRead
    Local $iTimerInit = TimerInit(), $iTimerDiff = Round(TimerDiff($iTimerInit)/1000, 0), $iLastTimer = $iTimerDiff
    Local $iOld_WWD_Opt = Opt("WinWaitDelay", 0)

    WinWait($sTitle, $sText)

    Opt("WinWaitDelay", $iOld_WWD_Opt)

    While 1
        $iStdOutRead &= StdoutRead($iAu3PID)
        If @error <> 0 Then ExitLoop

        If $sCallBackFunc <> "" Then
            $iTimerDiff = Round(TimerDiff($iTimerInit)/1000, 0)

            If $iLastTimer <> $iTimerDiff Then
                $iLastTimer = $iTimerDiff
                Call($sCallBackFunc, $iTimerDiff)
            EndIf
        EndIf

        Sleep(1)
    WEnd

    Return $iStdOutRead
EndFunc

[andr_mozg]

Спасибо

[snoitaleR]

andr_mozg
Я для этих целей использую функцию SplashTextOn()...
А когда надо убрать сообщение (в любом месте скрипта) вызываю SplashOff()...

[Creat0R]

Я для этих целей использую функцию SplashTextOn()... »

Для каких целей?

А когда надо убрать сообщение (в любом месте скрипта) вызываю SplashOff() »

А если нужно предоставить эту возможность пользователю?

[snoitaleR]

Creat0R
Тогда по-другому:

Код:

; НАЧАЛО

 $GUI1=GUICreate("",300,300)
 $EDIT=GUICtrlCreateEdit("",0,0,300,200,0x1000)
 $BUTTON1=GUICtrlCreateButton("MsgBox",0,200,300,50)
 $BUTTON2=GUICtrlCreateButton("GUI2",0,250,300,50)

 GUISetState(@SW_SHOW,$GUI1)

 $GUI2=GUICreate("Внимание!",200,100,-1,-1,0x00400000)
 $LABEL1=GUICtrlCreateLabel("Приложение продолжает работу"&@CRLF&"Нажмите OK, чтобы закрыть окно",10,10)
 $BUTTON0=GUICtrlCreateButton("Ok",-1,45,50,25)

 $R=""

 While true

  Switch GUIGetMsg()
   Case -3
    ExitLoop
   Case $BUTTON1
    MsgBox(0,"Внимание!","Приложение заблокировано"&@CRLF&"Нажмите OK, чтобы закрыть окно")
   Case $BUTTON2
    GUISetState(@SW_SHOW,$GUI2)
   Case $BUTTON0
    GUISetState(@SW_HIDE,$GUI2)
  EndSwitch

  $R=$R&Chr(Random(32,127,1))

  GUICtrlSetData($EDIT,$R)

  Sleep(50)

 Wend

; КОНЕЦ

[Creat0R]

Тогда по-другому »

Что подругому, разве мой пример не подходит?

[snoitaleR]

Creat0R
Не в этом дело...
Мой пример сначала не подходил, а теперь подходит...