[Mihail88]

толко readmi не показывать (сам редми показывает, толко файл не показывает) »

Elka80
{app} - папка установки
ReadmeFile.txt - имя файла, запускаемый ярлыком

возможно у вас Readme.txt

[Elka80]

возможно у вас Readme.txt »

Так и ест) Спс!

[Serega]

не мог бы вот это доделать? »

время будет по свободней - доделаю...

Скажите как это убрать? »

Я так понимаю, вы решили этот вопрос?

его единственная задача дополнить unins000.dat списком новых файлов, »

В скрипте в секции [Setup] запишите:
DirExistsWarning=no - не показывать сообщение о существовании папки;
UninstallLogMode=append - стоит по умолчанию, т.е. можно не указывать.
В секции [UninstallDelete]:
Name: {app}; Type: filesandordirs

Как заставить инсталяшку не оставлять след в установке-удалении программ »

В секции [Setup]:
Uninstallable=no

Встал вопрос с правами. При обновлении файла сбрасываются права на файл. Как их можно сохранить? »

Как понять обновление файла? В любом случае - это перезапись.

Нужно перед инсталляцией (обновлением) сделать бэкап файлов »

Не так давно этот вопрос уже обсуждался, поищите на предыдущих страницах...

[p3rf3ct1c]

Inno Setup 5.3.4

5.3.4 (2009-08-15) * On Windows 7 the Compiler IDE now displays a progress indicator on its taskbar button. * Pascal Scripting: Documented function IDispatchInvoke, which can be used to access a COM Automation property or method whose name is a reserved word. * Unicode Inno Setup fixes: o [Registry] section entries with ValueType set to binary did not set the correct value. o Pascal scripting: setting a COM Automation property or method parameter to a Unicode string variable caused an 'Invalid Type' error.

http://files.jrsoftware.org/ispack/ispack-5.3.4.exe

http://files.jrsoftware.org/ispack/i....4-unicode.exe

[A1EXXX]

Русификатор для Inno Setup 5.3.4

http://vadimsva.ucoz.org/Inno_Setup_5_rus.7z

Содержит версии: cтандарт, ISPP (для 2х версий один файл), стандарт unicode, ISPP unicode (для 2х версий один файл, лежит в папке unicode).

[aToVille]

есть ли restools (слева добавляется колонка и текст скрипта более нагляден) для новой версии? а то на их сайте по китайски ничего не понял

[heNch1g]

Доброго времени суток. Я опять с вопросами

Задача:

на странице дополнительных компонентов нужна кнопка "Подхватить конфиг", при нажатии на которую вылезе стандартное окно выбора файла *.cfg, который в последующем будет копироваться в папку с программой под именем config.cfg.
Как вариант - сделать чекбокс, при включении которого появляется это самое окно, так думаю даже будет проще.

Как еще один вариант, сделать новую страницу, на которой будет та самая кнопка, рядом на лабеле - имя выбранного файла (хотя зачем?), и внизу - выдержки из этого файла. По структуре он в виде:

Код:

name "myname"
commanda_primer "9"

Как по замыслам - чтобы параметры name и sensetivity вместе со значениями считывались из файла и писались на лабелах пониже кнопки. Наглядно это реализовано в инсталляторе любого продукта касперского в момент выбора ключа)

Надеюсь на вашу помощь, я по вашим постам уже молюсь на вас) первый вариант предпочтительней, но второй для общего развития было бы неплохо)

[Elka80]

Скажите, Что я не правильно сделал?

[p3rf3ct1c]

Elka80, в вашей Akella Games папке наверно нет файлов

[Serega]

есть ли restools ... для новой версии? »

Самая последняя - InnoCompiler090506_English.zip, сделана на основе Inno Setup 5.2.3, но возможностей больше.

на странице дополнительных компонентов нужна кнопка "Подхватить конфиг", при нажатии на которую вылезе стандартное окно выбора файла *.cfg, который в последующем будет копироваться в папку с программой под именем config.cfg. »

Пример

Код:

[Setup]
AppName=My Program
AppVerName=My Program v 1.5
DefaultDirName={pf}\My Program
OutputDir=.
Compression=lzma/ultra
InternalCompressLevel=ultra
SolidCompression=yes

[Languages]
Name: russian; MessagesFile: compiler:Languages\Russian.isl

[Tasks]
Name: cfg; Description: Использовать ваш файл настроек; GroupDescription: Дополнительно:; Flags: unchecked

[Files]
Source: compiler:Examples\MyProg.exe; DestDir: {app}; Tasks: cfg

[UninstallDelete]
Name: {app}; Type: filesandordirs

[Code]
var
  str: string;
  btn: TButton;
  edt: TEdit;
  text1, text2: TNewstatictext;

procedure TasksListOnClick(Sender: TObject);
begin
  if IsTaskSelected('cfg') then
    begin
      btn.Enabled:= True;
      edt.Enabled:= True;
      edt.Color:= clWindow;
    end
  else
    begin
      btn.Enabled:= False;
      edt.Enabled:= False;
      edt.Color:= clBtnFace;
      edt.Clear;
    end;
end;

procedure btnOnClick(Sender: TObject);
var
  S: TArrayOfString;
  i: Integer;
begin
  if GetOpenFileName('', str, ExpandConstant('{srcexe}'), 'Файл настроек (*.cfg)|*.cfg', '') then
  if str <> '' then
    begin
      edt.Text:= str;
      if LoadStringsFromFile(str, S) then
        begin
          for i:= 0 to GetArrayLength(S)-1 do
            begin
              if Pos('name "myname"', S[i]) > 0 then
                text1.Caption:= 'Строка № ' + IntToStr(i)+ ': ' + S[i];
              if Pos('commanda_primer "9"', S[i]) > 0 then
                text2.Caption:= 'Строка № ' + IntToStr(i)+ ': ' + S[i];
            end;
        end;
    end;
end;

procedure InitializeWizard();
begin
  btn:= TButton.Create(WizardForm);
  with btn do
    begin
      SetBounds(330, 83, 75, 25);
      Caption:= 'Обзор';
      OnClick:= @btnOnClick;
      Enabled:= False;
      Parent:= WizardForm.SelectTasksPage;
    end;

  edt:= TEdit.Create(WizardForm);
  with edt do
    begin
      SetBounds(20, 85, 300, 23);
      Enabled:= False;
      Color:= clBtnFace;
      Parent:= WizardForm.SelectTasksPage;
    end;

  text1:= TNewstatictext.Create(WizardForm);
  with text1 do
    begin
      SetBounds(20, 110, 300, 23);
      AutoSize:= True;
      Parent:= WizardForm.SelectTasksPage;
    end;

  text2:= TNewstatictext.Create(WizardForm);
  with text2 do
    begin
      SetBounds(20, 130, 300, 23);
      AutoSize:= True;
      Parent:= WizardForm.SelectTasksPage;
    end;

  WizardForm.TasksList.OnClickCheck:= @TasksListOnClick;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID > wpInstalling then
    begin
      if IsTaskSelected('cfg') then
      if str <> '' then
        FileCopy(str, ExpandConstant('{app}\config.cfg'), False);
    end;
end;

Наглядно это реализовано в инсталляторе любого продукта касперского в момент выбора ключа) »

К сожалению, не видел...