[Creat0R]

Есть ещё вариант с обработкой файлов и построением списка FileInstall'ов:

Код:

$sRet_FI_Lines = _FileInstallGetFolder("C:\Temp", "D:\Dest", 0, "*.txt")
ConsoleWrite("+Return:" & @CRLF & $sRet_FI_Lines & @CRLF & @CRLF & "!Error = " & @error & @CRLF & @CRLF)

MsgBox(64, "Return #1:", $sRet_FI_Lines & @CRLF & @CRLF & "!Error = " & @error)

$sRet_FI_Lines = _FileInstallGetFolder(@ProgramFilesDir & "\AutoIt3", "$aDest[$i]", 1, "*.exe")
ConsoleWrite("+Return:" & @CRLF & $sRet_FI_Lines & @CRLF & @CRLF & "!Error = " & @error & @CRLF & @CRLF)

MsgBox(64, "Return #2:", $sRet_FI_Lines & @CRLF & @CRLF & "!Error = " & @error)

Func _FileInstallGetFolder($sSource, $sDest, $nFlag = 0, $sMask = "*", $nCompiled = False)
    Local $hSearch, $sNext_File, $sRet_FI_Lines = ""

    If (Not $nCompiled) Or ($nCompiled And @Compiled) Then
        $hSearch = FileFindFirstFile($sSource & "\" & $sMask)
        If $hSearch = -1 Then Return SetError(1, 0, "")

        ;Check if it's a $Var (or $Array[$i][N]...)
        Local $iAddAsVar = StringRegExp($sDest, "(?i)\A\$([0-9a-z_])+(\[(\$[0-9a-z_]+|\d+)+\]+|)+$")

        While 1
            $sNext_File = FileFindNextFile($hSearch)
            If @error Then ExitLoop ;No more files

            If $iAddAsVar Then
                $sRet_FI_Lines &= 'FileInstall("' & $sSource & '\' & $sNext_File & '", ' & _
                    $sDest & ' & "\' & $sNext_File & '", ' & $nFlag & ')' & @CRLF
            Else
                $sRet_FI_Lines &= 'FileInstall("' & $sSource & '\' & $sNext_File & '", "' & _
                    $sDest & '\' & $sNext_File & '", ' & $nFlag & ')' & @CRLF
            EndIf
        WEnd

        FileClose($hSearch)
    EndIf

    If $sRet_FI_Lines = "" Then Return SetError(2, 0, "")
    Return StringStripWS($sRet_FI_Lines, 3)
EndFunc